MASM32编程获取系统服务列表及其状态

拼搏现实的明天。 2024-02-17 13:40 12阅读 0赞

;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<  
; FileName: List\_Svc2.asm  
; Function: Demo the way to list system services and their status  
; Author: Purple Endurer  
; DevEmv: Win XP SP2, MASM32  
;  
; LOG  
; ---------------------------------------------------  
; 2006-11-17 Created!  
;<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<<  
  
.386  
.model flat, stdcall  
option casemap: none  
include /masm32/ include/windows.inc  
  
include /masm32/ include/user32.inc  
includelib /masm32/ lib/user32.lib  
  
include /masm32/ include/kernel32.inc  
includelib /masm32/ lib/kernel32.lib  
  
include /masm32/ include/advapi32.inc  
includelib /masm32/ lib/advapi32.lib  
  
  
WinMain PROTO : DWORD, : DWORD, : DWORD, : DWORD  
ResizeConctrol PROTO  
ShowServiceInfo PROTO : dword, : dword, : dword  
ShowSvcStatusInfo PROTO : dword  
ShowSvcData PROTO : dword, : dword, : dword  
  
;.const  
IDC\_BtnEnum equ 103  
IDC\_EdtFileSpec equ 105  
IDC\_EdtVerInfo equ 107  
  
c\_GrpSvcTypeTop equ 5  
c\_GrpSvcTypeLeft equ 2  
  
c\_ChkBtnSvcWin32Top equ c\_GrpSvcTypeTop+15  
c\_ChkBtnSvcWin32Left equ c\_GrpSvcTypeLeft+5  
c\_ChkBtnSvcWin32Width equ 150  
c\_ChkBtnSvcWin32Height equ 15  
  
c\_ChkBtnSvcDrvTop equ c\_ChkBtnSvcWin32Top+c\_ChkBtnSvcWin32Height+5  
c\_ChkBtnSvcDrvLeft equ c\_ChkBtnSvcWin32Left  
c\_ChkBtnSvcDrvWidth equ c\_ChkBtnSvcWin32Width  
c\_ChkBtnSvcDrvHeight equ c\_ChkBtnSvcWin32Height  
  
c\_GrpSvcTypeWidth equ c\_ChkBtnSvcWin32Width+10  
c\_GrpSvcTypeHeight equ c\_ChkBtnSvcDrvTop+c\_ChkBtnSvcDrvHeight+5  
  
  
c\_GrpSvcStateTop equ c\_GrpSvcTypeTop  
c\_GrpSvcStateLeft equ c\_GrpSvcTypeLeft+c\_GrpSvcTypeWidth+10  
  
c\_ChkBtnSvcActTop equ c\_GrpSvcStateTop+15  
c\_ChkBtnSvcActLeft equ c\_GrpSvcStateLeft+5  
c\_ChkBtnSvcActWidth equ 150  
c\_ChkBtnSvcActHeight equ 15  
  
c\_ChkBtnSvcInActTop equ c\_ChkBtnSvcActTop+c\_ChkBtnSvcActHeight+5  
c\_ChkBtnSvcInActLeft equ c\_ChkBtnSvcActLeft  
c\_ChkBtnSvcInActWidth equ c\_ChkBtnSvcActWidth  
c\_ChkBtnSvcInActHeight equ c\_ChkBtnSvcActHeight  
  
c\_GrpSvcStateWidth equ c\_ChkBtnSvcActWidth+10  
c\_GrpSvcStateHeight equ c\_ChkBtnSvcInActTop+c\_ChkBtnSvcInActHeight+5  
  
c\_BtnShowTop equ c\_GrpSvcTypeTop  
c\_BtnShowLeft equ (c\_GrpSvcStateLeft+c\_GrpSvcStateWidth+10)  
c\_BtnShowWidth equ 70  
c\_BtnShowHeight equ 25  
  
c\_EdtSvrInfoLeft equ 2  
c\_EdtSvrInfoTop equ c\_GrpSvcTypeTop+c\_GrpSvcTypeHeight+5  
c\_EdtSvrInfoHeight equ 165  
  
c\_WinWidth equ c\_BtnShowLeft+c\_BtnShowWidth + 10 ;c\_EdtSvrInfoLeft + c\_EdtSvrInfoWidth + 2  
c\_WinHeight equ c\_EdtSvrInfoTop + c\_EdtSvrInfoHeight + 45  
  
c\_EdtSvrInfoWidth equ c\_WinWidth-8-c\_EdtSvrInfoLeft  
  
m\_CatStr MACRO szStr: REQ  
invoke SendMessage, g\_hEditSvrInfo, EM\_REPLACESEL, FALSE, szStr  
ENDM  
  
m\_GoNextLine MACRO  
invoke SendMessage, g\_hEditSvrInfo, EM\_REPLACESEL, FALSE, ADDR g\_szCR  
ENDM  
  
m\_MsgBox MACRO lpszMsg: REQ, dwIcon: REQ  
invoke MessageBox, g\_hWndMain, lpszMsg, OFFSET g\_szAppName\_cn, dwIcon  
ENDM  
  
  
.data  
g\_szClsName db "ListSvrCls", 0  
g\_szAppName\_cn db "系统服务列表", 0  
g\_szEditCls db "EDIT", 0  
g\_szBtnCls db "button", 0  
g\_szBtnEnumSvc\_cn db "&E 枚举", 0  
g\_szSERVICE\_WIN32 db "SERVICE\_WIN32", 0  
g\_szSERVICE\_DRIVER db "SERVICE\_DRIVER", 0  
g\_szSERVICE\_ACTIVE db "SERVICE\_ACTIVE", 0  
g\_szSERVICE\_INACTIVE db "SERVICE\_INACTIVE", 0  
g\_szChkSvrTypeFirst\_cn db "请先选择要枚举的"  
g\_szServiceType\_cn db "服务类型：", 0  
g\_szChkSvrStateFirst\_cn db "请先选择要枚举的"  
g\_szServiceState\_cn db "服务状态：", 0  
  
  
.data?  
g\_hInstance HINSTANCE ?  
g\_hWndMain HANDLE ?  
g\_hEditFileSpec HANDLE ?  
g\_hBtnShow HANDLE ?  
g\_hEditSvrInfo HANDLE ?  
g\_szFileSpec db 256 dup (?)  
g\_hGrpServiceType HANDLE ?  
g\_hChkBtnSvcWin32 HANDLE ?  
g\_hChkBtnSvcDrv HANDLE ?  
g\_hGrpServiceState HANDLE ?  
g\_hChkBtnSvcAct HANDLE ?  
g\_hChkBtnSvcInAct HANDLE ?  
g\_dwServiceType dword ?  
g\_dwServiceState dword ?  
  
  
.code  
start:  
invoke GetModuleHandle, NULL  
mov g\_hInstance, eax  
invoke WinMain, g\_hInstance, NULL, NULL, SW\_SHOWDEFAULT  
invoke ExitProcess, eax  
  
  
WinMain proc hInst: DWORD, hPrevInst: DWORD, CmdLine: DWORD, CmdShow: DWORD  
LOCAL wc: WNDCLASSEX  
LOCAL msg: MSG  
LOCAL hwnd: HWND  
  
mov wc.cbSize, SIZEOF WNDCLASSEX  
mov wc.style, CS\_HREDRAW or CS\_VREDRAW  
mov wc.lpfnWndProc, OFFSET WndProc  
mov wc.cbClsExtra, NULL  
mov wc.cbWndExtra, NULL  
mov eax, g\_hInstance  
mov wc.hInstance, eax  
mov wc.hbrBackground, COLOR\_APPWORKSPACE  
mov wc.lpszMenuName, NULL  
mov wc.lpszClassName, OFFSET g\_szClsName  
invoke LoadIcon, NULL, IDI\_APPLICATION  
mov wc.hIcon, eax  
mov wc.hIconSm, eax  
invoke LoadCursor, NULL, IDC\_ARROW  
mov wc.hCursor, eax  
invoke RegisterClassEx, addr wc  
invoke CreateWindowEx, WS\_EX\_TOPMOST, ADDR g\_szClsName,/  
ADDR g\_szAppName\_cn, WS\_OVERLAPPEDWINDOW+WS\_VISIBLE,/  
CW\_USEDEFAULT, CW\_USEDEFAULT, c\_WinWidth, c\_WinHeight,/  
NULL, NULL, hInst, NULL  
mov hwnd, eax  
.while TRUE  
invoke GetMessage, ADDR msg, NULL, 0, 0  
.BREAK .IF (! eax)  
  
;--- process keystrokes directly in the message loop  
.if msg.message == WM\_SYSKEYUP  
.if msg.wParam == VK\_E ; Alt + E  
invoke PostMessage, hwnd, WM\_COMMAND, IDC\_BtnEnum, BM\_CLICK  
.endif  
.endif  
; ------------------------------------------------  
invoke TranslateMessage, ADDR msg  
invoke DispatchMessage, ADDR msg  
.endw  
mov eax, msg.wParam  
ret  
WinMain endp  
  
  
WndProc proc hWnd: HWND, uMsg: UINT, wParam: WPARAM, lParam: LPARAM  
LOCAL rect: RECT  
LOCAL hdc: DWORD  
  
.if uMsg==WM\_CREATE  
mov eax, hWnd  
mov g\_hWndMain, eax  
  
;--- Create enum button  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, addr g\_szBtnEnumSvc\_cn,/  
WS\_CHILD+WS\_VISIBLE, c\_BtnShowLeft, c\_BtnShowTop, c\_BtnShowWidth, c\_BtnShowHeight,/  
hWnd, IDC\_BtnEnum, g\_hInstance, NULL  
mov g\_hBtnShow, eax  
  
;--- Create group  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, offset g\_szServiceType\_cn,/  
WS\_CHILD+WS\_VISIBLE+BS\_GROUPBOX, c\_GrpSvcTypeLeft, c\_GrpSvcTypeTop, /  
c\_GrpSvcTypeWidth, c\_GrpSvcTypeHeight,/  
hWnd, NULL, g\_hInstance, NULL  
mov g\_hGrpServiceType, eax  
  
;--- Create autocheck button  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, offset g\_szSERVICE\_WIN32,/  
WS\_CHILD+WS\_VISIBLE+BS\_AUTOCHECKBOX, c\_ChkBtnSvcWin32Left, c\_ChkBtnSvcWin32Top,/  
c\_ChkBtnSvcWin32Width, c\_ChkBtnSvcWin32Height,/  
hWnd, NULL, g\_hInstance, NULL  
mov g\_hChkBtnSvcWin32, eax  
  
;--- Create autocheck button  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, offset g\_szSERVICE\_DRIVER,/  
WS\_CHILD+WS\_VISIBLE+BS\_AUTOCHECKBOX, c\_ChkBtnSvcDrvLeft, c\_ChkBtnSvcDrvTop,/  
c\_ChkBtnSvcDrvWidth, c\_ChkBtnSvcDrvHeight,/  
hWnd, NULL, g\_hInstance, NULL  
mov g\_hChkBtnSvcDrv, eax  
  
;--- Create group  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, offset g\_szServiceState\_cn,/  
WS\_CHILD+WS\_VISIBLE+BS\_GROUPBOX, c\_GrpSvcStateLeft, c\_GrpSvcStateTop,/  
c\_GrpSvcStateWidth, c\_GrpSvcStateHeight,/  
hWnd, NULL, g\_hInstance, NULL  
mov g\_hGrpServiceState, eax  
  
;--- Create autocheck button  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, offset g\_szSERVICE\_ACTIVE,/  
WS\_CHILD+WS\_VISIBLE+BS\_AUTOCHECKBOX, c\_ChkBtnSvcActLeft, c\_ChkBtnSvcActTop,/  
c\_ChkBtnSvcActWidth, c\_ChkBtnSvcActHeight,/  
hWnd, NULL, g\_hInstance, NULL  
mov g\_hChkBtnSvcAct, eax  
  
;--- Create autocheck button  
invoke CreateWindowEx, NULL, addr g\_szBtnCls, offset g\_szSERVICE\_INACTIVE,/  
WS\_CHILD+WS\_VISIBLE+BS\_AUTOCHECKBOX, c\_ChkBtnSvcInActLeft, c\_ChkBtnSvcInActTop,/  
c\_ChkBtnSvcInActWidth, c\_ChkBtnSvcInActHeight,/  
hWnd, NULL, g\_hInstance, NULL  
mov g\_hChkBtnSvcInAct, eax  
  
;--- Create services info editbox  
invoke CreateWindowEx, NULL, addr g\_szEditCls, NULL,/  
WS\_CHILD+WS\_VISIBLE+ES\_MULTILINE+WS\_HSCROLL+WS\_VSCROLL,/  
c\_EdtSvrInfoLeft, c\_EdtSvrInfoTop, c\_EdtSvrInfoWidth, c\_EdtSvrInfoHeight,/  
hWnd, IDC\_EdtVerInfo, g\_hInstance, NULL  
mov g\_hEditSvrInfo, eax  
  
.elseif uMsg==WM\_COMMAND  
.if lParam!=0  
mov eax, wParam  
.IF ax==IDC\_BtnEnum  
shr eax, 16  
.if ax==BN\_CLICKED  
xor eax, eax  
mov g\_dwServiceType, eax  
invoke SendMessage, g\_hChkBtnSvcWin32, BM\_GETCHECK, eax, eax  
.if eax==BST\_CHECKED  
or g\_dwServiceType, SERVICE\_WIN32  
.endif  
xor eax, eax  
invoke SendMessage, g\_hChkBtnSvcDrv, BM\_GETCHECK, eax, eax  
.if eax==BST\_CHECKED  
or g\_dwServiceType, SERVICE\_DRIVER  
.endif  
cmp g\_dwServiceType, 0  
jne @F  
m\_MsgBox OFFSET g\_szChkSvrTypeFirst\_cn, NULL  
xor eax, eax  
jz @BtnClkEnd  
@@:  
xor eax, eax  
mov g\_dwServiceState, eax  
invoke SendMessage, g\_hChkBtnSvcAct, BM\_GETCHECK, eax, eax  
.if eax==BST\_CHECKED  
or g\_dwServiceState, SERVICE\_ACTIVE  
.endif  
xor eax, eax  
invoke SendMessage, g\_hChkBtnSvcInAct, BM\_GETCHECK, eax, eax  
.if eax==BST\_CHECKED  
or g\_dwServiceState, SERVICE\_INACTIVE  
.endif  
cmp g\_dwServiceState, 0  
jne @F  
m\_MsgBox OFFSET g\_szChkSvrStateFirst\_cn, NULL  
xor eax, eax  
jz @BtnClkEnd  
@@:  
invoke ShowServiceInfo, SC\_MANAGER\_ENUMERATE\_SERVICE, g\_dwServiceType, g\_dwServiceState  
@BtnClkEnd:  
.endif  
.ENDIF  
.endif  
.elseif uMsg==WM\_DESTROY  
invoke PostQuitMessage, NULL  
.elseif uMsg==WM\_SIZE  
invoke ResizeConctrol  
xor eax, eax  
jz @F  
.else  
@@:  
invoke DefWindowProc, hWnd, uMsg, wParam, lParam  
ret  
.endif  
xor eax, eax  
ret  
WndProc endp  
  
ResizeConctrol PROC  
LOCAL st\_Rect: RECT  
  
invoke GetClientRect, g\_hWndMain, ADDR st\_Rect  
  
;--- Resize the Enum button  
mov eax, st\_Rect.right  
sub eax, 5+c\_BtnShowWidth  
push eax  
invoke MoveWindow, g\_hBtnShow, eax, c\_BtnShowTop, c\_BtnShowWidth, c\_BtnShowHeight, TRUE  
  
;--- Resize the service editbox  
mov eax, st\_Rect.right  
sub eax, 5  
  
mov edi, st\_Rect.bottom  
sub edi, 70  
  
invoke MoveWindow, g\_hEditSvrInfo, c\_EdtSvrInfoLeft, c\_EdtSvrInfoTop, eax, edi, TRUE  
  
ret  
ResizeConctrol ENDP  
  
  
ShowServiceInfo PROC dwDesiredAccess: dword, dwServiceType: dword, dwServiceState: dword  
LOCAL hSCM, hResume, hMem: HANDLE  
LOCAL dwBytesNeeded, dwServiceNum: dword  
LOCAL lpstCurSvr: dword  
LOCAL Buf1\[22\]: byte  
  
xor eax, eax  
jz @F  
g\_szERROR\_ACCESS\_DENIED db "The requested access was denied.", 0  
g\_szERROR\_DATABASE\_DOES\_NOT\_EXIST db "The specified database does not exist.", 0  
g\_szERROR\_INVALID\_PARAMETER db "A parameter that was specified is invalid.", 0  
g\_szERROR\_INVALID\_HANDLE db "The specified handle is invalid.", 0  
g\_szERROR\_MORE\_DATA db "There are more service entries than would fit into the lpServices buffer.", 0  
g\_szFailGlobalAlloc db "Fail to GlobalAlloc", 0  
g\_szOpenSCManager db "Call OpenSCManager", 0  
g\_szEnumServicesStatus db "Call EnumServicesStatus", 0  
g\_szBlkOK db " OK!"  
g\_szCR db 0dh, 0ah, 0  
g\_sz3hyphens db "---", 0  
g\_szFmtTotal db "Total: %d", 0  
@@:  
; SC\_HANDLE OpenSCManager(  
; LPCTSTR lpMachineName, // pointer to machine name string   
; LPCTSTR lpDatabaseName, // pointer to database name string   
; DWORD dwDesiredAccess // type of access   
; );   
m\_CatStr OFFSET g\_szOpenSCManager  
invoke OpenSCManager, NULL, NULL, dwDesiredAccess  
cmp eax, NULL  
jne @F  
invoke GetLastError  
.if eax==ERROR\_ACCESS\_DENIED  
mov eax, OfFSET g\_szERROR\_ACCESS\_DENIED  
.elseif eax==ERROR\_DATABASE\_DOES\_NOT\_EXIST  
mov eax, OFFSET g\_szERROR\_DATABASE\_DOES\_NOT\_EXIST  
.elseif eax==ERROR\_INVALID\_PARAMETER  
mov eax, OFFSET g\_szERROR\_INVALID\_PARAMETER  
.else  
mov eax, NULL  
.endif  
m\_CatStr eax  
ret  
@@:  
mov hSCM, eax  
m\_CatStr OFFSET g\_szBlkOK  
m\_CatStr OFFSET g\_szEnumServicesStatus  
  
; BOOL EnumServicesStatus(  
; SC\_HANDLE hSCManager, // handle to service control manager database  
; DWORD dwServiceType, // type of services to enumerate  
; DWORD dwServiceState, // state of services to enumerate  
; LPENUM\_SERVICE\_STATUS lpServices, // pointer to service status buffer  
; DWORD cbBufSize, // size of service status buffer  
; LPDWORD pcbBytesNeeded, // pointer to variable for bytes needed  
; LPDWORD lpServicesReturned, // pointer to variable for number returned  
; LPDWORD lpResumeHandle // pointer to variable for next entry  
; );  
mov hResume, 0  
invoke EnumServicesStatus, hSCM, dwServiceType, dwServiceState,/  
NULL, NULL, ADDR dwBytesNeeded,/  
ADDR dwServiceNum, ADDR hResume  
invoke GetLastError  
cmp eax, ERROR\_MORE\_DATA  
je @F  
@EnumServicesStatusErr:  
.if eax==ERROR\_ACCESS\_DENIED  
mov eax, OfFSET g\_szERROR\_ACCESS\_DENIED  
.elseif eax==ERROR\_INVALID\_HANDLE  
mov eax, OFFSET g\_szERROR\_INVALID\_HANDLE  
.elseif eax==ERROR\_INVALID\_PARAMETER  
mov eax, OFFSET g\_szERROR\_INVALID\_PARAMETER  
.elseif eax==ERROR\_MORE\_DATA  
mov eax, OFFSET g\_szERROR\_MORE\_DATA  
.else  
mov eax, NULL  
.endif  
m\_CatStr eax  
invoke CloseServiceHandle, hSCM  
ret  
@@:  
m\_CatStr OFFSET g\_szBlkOK  
m\_CatStr OFFSET g\_szEnumServicesStatus  
invoke GlobalAlloc, GMEM\_ZEROINIT, dwBytesNeeded  
cmp eax, NULL  
jnz @F  
m\_CatStr OFFSET g\_szFailGlobalAlloc  
invoke CloseServiceHandle, hSCM  
ret  
@@:  
mov hMem, eax  
m\_CatStr OFFSET g\_szBlkOK  
mov hResume, 0  
invoke EnumServicesStatus, hSCM, dwServiceType, dwServiceState,/  
hMem, dwBytesNeeded, ADDR dwBytesNeeded,/  
ADDR dwServiceNum, ADDR hResume  
or eax, eax  
jnz @F  
invoke GetLastError  
push eax  
invoke GlobalFree, hMem  
pop eax  
jmp @EnumServicesStatusErr  
@@:  
m\_CatStr OFFSET g\_sz3hyphens  
m\_CatStr OFFSET g\_szAppName\_cn  
m\_CatStr OFFSET g\_sz3hyphens  
invoke wsprintf, ADDR Buf1, OFFSET g\_szFmtTotal, dwServiceNum  
m\_CatStr ADDR Buf1  
m\_GoNextLine  
;push edx  
mov edx, hMem  
xor eax, eax  
.while eax < dwServiceNum  
push eax  
mov lpstCurSvr, edx  
  
m\_CatStr (ENUM\_SERVICE\_STATUS ptr \[ edx\]).lpServiceName  
m\_CatStr OFFSET g\_sz3hyphens  
mov edx, lpstCurSvr  
m\_CatStr (ENUM\_SERVICE\_STATUS ptr \[ edx\]).lpDisplayName  
m\_GoNextLine  
mov edx, lpstCurSvr  
lea eax, (ENUM\_SERVICE\_STATUS ptr \[ edx\]).ServiceStatus  
invoke ShowSvcStatusInfo, eax  
m\_GoNextLine  
mov edx, lpstCurSvr  
add edx, SIZEOF ENUM\_SERVICE\_STATUS  
pop eax  
inc eax  
.endw  
;pop edx  
invoke GlobalFree, hMem  
invoke CloseServiceHandle, hSCM  
ret  
ShowServiceInfo ENDP  
  
  
ShowSvcStatusInfo PROC lpstSrvStatus: dword  
xor eax, eax  
jz @F  
;--- type  
g\_szSERVICE\_WIN32\_OWN\_PROCESS db "SERVICE\_WIN32\_OWN\_PROCESS", 0  
g\_szSERVICE\_WIN32\_SHARE\_PROCESS db "SERVICE\_WIN32\_SHARE\_PROCESS", 0  
g\_szSERVICE\_KERNEL\_DRIVER db "SERVICE\_KERNEL\_DRIVER", 0  
g\_szSERVICE\_FILE\_SYSTEM\_DRIVER db "SERVICE\_FILE\_SYSTEM\_DRIVER", 0  
g\_szSERVICE\_INTERACTIVE\_PROCESS db "SERVICE\_INTERACTIVE\_PROCESS", 0  
g\_szSvcTypeArr dword SERVICE\_WIN32\_OWN\_PROCESS, OFFSET g\_szSERVICE\_WIN32\_OWN\_PROCESS  
dword SERVICE\_WIN32\_SHARE\_PROCESS, OFFSET g\_szSERVICE\_WIN32\_SHARE\_PROCESS  
dword SERVICE\_KERNEL\_DRIVER, OFFSET g\_szSERVICE\_KERNEL\_DRIVER  
dword SERVICE\_FILE\_SYSTEM\_DRIVER, OFFSET g\_szSERVICE\_FILE\_SYSTEM\_DRIVER  
dword SERVICE\_INTERACTIVE\_PROCESS, OFFSET g\_szSERVICE\_INTERACTIVE\_PROCESS  
c\_SvcTypeArrLen equ ($ - ( offset g\_szSvcTypeArr)) / 8  
;--- status  
g\_szSERVICE\_STOPPED db "SERVICE\_STOPPED", 0  
g\_szSERVICE\_START\_PENDING db "SERVICE\_START\_PENDING", 0  
g\_szSERVICE\_STOP\_PENDING db "SERVICE\_STOP\_PENDING", 0  
g\_szSERVICE\_RUNNING db "SERVICE\_RUNNING", 0  
g\_szSERVICE\_CONTINUE\_PENDING db "SERVICE\_CONTINUE\_PENDING", 0  
g\_szSERVICE\_PAUSE\_PENDING db "SERVICE\_PAUSE\_PENDING", 0  
g\_szSERVICE\_PAUSED db "SERVICE\_PAUSED", 0  
  
g\_szSvcStatusArr dword SERVICE\_STOPPED, OFFSET g\_szSERVICE\_STOPPED  
dword SERVICE\_START\_PENDING, OFFSET g\_szSERVICE\_START\_PENDING  
dword SERVICE\_STOP\_PENDING, OFFSET g\_szSERVICE\_STOP\_PENDING  
dword SERVICE\_RUNNING, OFFSET g\_szSERVICE\_RUNNING  
dword SERVICE\_CONTINUE\_PENDING, OFFSET g\_szSERVICE\_CONTINUE\_PENDING  
dword SERVICE\_PAUSE\_PENDING, OFFSET g\_szSERVICE\_PAUSE\_PENDING  
dword SERVICE\_PAUSED, OFFSET g\_szSERVICE\_PAUSED  
c\_SvcStatusArrLen equ ($ - ( offset g\_szSvcStatusArr)) / 8  
  
;---  
g\_szControlsAccepted\_cn db "可受控制：", 0  
g\_szSERVICE\_ACCEPT\_STOP db "SERVICE\_ACCEPT\_STOP", 0  
g\_szSERVICE\_ACCEPT\_PAUSE\_CONTINUE db "SERVICE\_ACCEPT\_PAUSE\_CONTINUE", 0  
g\_szSERVICE\_ACCEPT\_SHUTDOWN db "SERVICE\_ACCEPT\_SHUTDOWN", 0  
g\_szSvcAccCtlArr dword SERVICE\_ACCEPT\_STOP, OFFSET g\_szSERVICE\_ACCEPT\_STOP  
dword SERVICE\_ACCEPT\_PAUSE\_CONTINUE, OFFSET g\_szSERVICE\_ACCEPT\_PAUSE\_CONTINUE  
dword SERVICE\_ACCEPT\_SHUTDOWN, OFFSET g\_szSERVICE\_ACCEPT\_SHUTDOWN  
c\_SvcAccCtlArrLen equ ($ - ( offset g\_szSvcAccCtlArr)) / 8  
@@:  
  
; typedef struct \_SERVICE\_STATUS \{ // ss   
; DWORD dwServiceType;   
; DWORD dwCurrentState;   
; DWORD dwControlsAccepted;   
; DWORD dwWin32ExitCode;   
; DWORD dwServiceSpecificExitCode;   
; DWORD dwCheckPoint;   
; DWORD dwWaitHint;   
; \} SERVICE\_STATUS, \*LPSERVICE\_STATUS;   
;--- ServiceType  
m\_CatStr OFFSET g\_szServiceType\_cn  
mov eax, lpstSrvStatus  
mov eax, (SERVICE\_STATUS ptr \[ eax\]).dwServiceType  
invoke ShowSvcData, eax, OFFSET g\_szSvcTypeArr, c\_SvcTypeArrLen  
m\_GoNextLine  
  
;--- Service State  
m\_CatStr OFFSET g\_szServiceState\_cn  
mov eax, lpstSrvStatus  
mov eax, (SERVICE\_STATUS ptr \[ eax\]).dwCurrentState  
invoke ShowSvcData, eax, OFFSET g\_szSvcStatusArr, c\_SvcStatusArrLen  
m\_GoNextLine  
  
;--- ControlsAccepted  
m\_CatStr OFFSET g\_szControlsAccepted\_cn  
mov eax, lpstSrvStatus  
mov eax, (SERVICE\_STATUS ptr \[ eax\]).dwControlsAccepted  
invoke ShowSvcData, eax, OFFSET g\_szSvcAccCtlArr, c\_SvcAccCtlArrLen  
m\_GoNextLine  
  
ret  
ShowSvcStatusInfo ENDP  
  
  
ShowSvcData PROC dwSvcData: DWORD, lpSvcDataArr: DWORD, dwDataArrLen: DWORD  
LOCAL lpPos: dword  
LOCAL dwIndex: dword  
  
mov eax, lpSvcDataArr  
mov dwIndex, 0  
@ShowSvcDataLoop1:  
mov edx, dwIndex  
cmp edx, dwDataArrLen  
je @ShowSvcDataRet  
mov lpPos, eax  
mov eax, \[ eax\]  
cmp dwSvcData, eax  
jne @F  
mov eax, lpPos  
add eax, 4  
mov eax, \[ eax\]  
or eax, eax  
jnz @ShowSvcData  
;jmp @ShowSvcData  
@@:  
inc dwIndex  
mov eax, lpPos  
add eax, 8  
or eax, eax  
jnz @ShowSvcDataLoop1  
@ShowSvcData:  
m\_CatStr eax  
@ShowSvcDataRet:  
ret  
ShowSvcData ENDP  
  
end start