arm9_存储控制器

拼搏现实的明天。 2023-06-01 06:19 7阅读 0赞

1.作为stm32f103VET6来讲，有4G的寻址空间；ram:64KB; rom:512KB; 内部寄存器：若干；可从flash，ram,系统存储器启动

2.作为S3C2440来讲，理论上也有4G的寻址空间；存储控制器可访问8个大小为128MB的BANK;内部寄存器：若干；可从norflash和nandflash启动

看代码如下：

@*************************************************************************
    @ File：head.S
    @ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行
    @*************************************************************************       
    
    .equ        MEM_CTL_BASE,       0x48000000
    .equ        SDRAM_BASE,         0x30000000
    
    .text
    .global _start
    _start:
        bl  disable_watch_dog               @ 关闭WATCHDOG，否则CPU会不断重启
        bl  memsetup                        @ 设置存储控制器
        bl  copy_steppingstone_to_sdram     @ 复制代码到SDRAM中
        ldr pc, =on_sdram                   @ 跳到SDRAM中继续执行
    on_sdram:
        ldr sp, =0x34000000                 @ 设置堆栈
        bl  main
    halt_loop:
        b   halt_loop
    
    disable_watch_dog:
        @ 往WATCHDOG寄存器写0即可
        mov r1,     #0x53000000
        mov r2,     #0x0
        str r2,     [r1]
        mov pc,     lr      @ 返回
    
    copy_steppingstone_to_sdram:
        @ 将Steppingstone的4K数据全部复制到SDRAM中去
        @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000
        
        mov r1, #0
        ldr r2, =SDRAM_BASE
        mov r3, #4*1024
    1:  
        ldr r4, [r1],#4     @ 从Steppingstone读取4字节的数据，并让源地址加4
        str r4, [r2],#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4
        cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？
        bne 1b              @ 若没有复制完，继续
        mov pc,     lr      @ 返回
    
    memsetup:
        @ 设置存储控制器以便使用SDRAM等外设
    
        mov r1,     #MEM_CTL_BASE       @ 存储控制器的13个寄存器的开始地址
        adrl    r2, mem_cfg_val         @ 这13个值的起始存储地址
        add r3,     r1, #52             @ 13*4 = 54
    1:  
        ldr r4,     [r2], #4            @ 读取设置值，并让r2加4
        str r4,     [r1], #4            @ 将此值写入寄存器，并让r1加4
        cmp r1,     r3                  @ 判断是否设置完所有13个寄存器
        bne 1b                          @ 若没有写成，继续
        mov pc,     lr                  @ 返回
    
    
    .align 4
    mem_cfg_val:
        @ 存储控制器13个寄存器的设置值
        .long   0x22011110      @ BWSCON
        .long   0x00000700      @ BANKCON0
        .long   0x00000700      @ BANKCON1
        .long   0x00000700      @ BANKCON2
        .long   0x00000700      @ BANKCON3  
        .long   0x00000700      @ BANKCON4
        .long   0x00000700      @ BANKCON5
        .long   0x00018005      @ BANKCON6
        .long   0x00018005      @ BANKCON7
        .long   0x008C07A3      @ REFRESH
        .long   0x000000B1      @ BANKSIZE
        .long   0x00000030      @ MRSRB6
        .long   0x00000030      @ MRSRB7

sdram.bin : head.S  leds.c
        arm-linux-gcc  -c -o head.o head.S
        arm-linux-gcc -c -o leds.o leds.c
        arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram_elf
        arm-linux-objcopy -O binary -S sdram_elf sdram.bin
        arm-linux-objdump -D -m arm  sdram_elf > sdram.dis
    clean:
        rm -f   sdram.dis sdram.bin sdram_elf *.o

其实以上就这句ldr pc, =on\_sdram，稍微难理解一点点，其实在makefile中的-Ttext 0x30000000设定了程序的代码段的起始位置，所以bl disable\_watch\_dog这个第一条指令的地址为0x30000000，那么真正在sdram中执行的第一条指令ldr sp, =0x34000000（也即第五条指令）的地址为0x30000010；而且因为bl是与位置无关的指令，可以在steppingstone执行，但ldr是地址相关执行，必须在对应地址处执行，所以在程序被复制到sdram后，就可以从steppingstone跳转到sdram去执行了。

转载于:https://www.cnblogs.com/lzd626/p/10506438.html