Groovy Xml解析

客官°小女子只卖身不卖艺 2023-02-12 06:19 1阅读 0赞

### 生成XML： ###

*  `MarkupBuilder`方式:

import groovy.xml.MarkupBuilder
    import groovy.xml.StreamingMarkupBuilder
    
    
    def stream = new ByteArrayOutputStream(200)
    
    def osw = new OutputStreamWriter(stream)
    
    
    def builder = new MarkupBuilder(osw)
    
    builder.asd {
    
        book {
            //mkp是MarkupBuilder其内部属性，comment函数生成注释
            mkp.comment("这是一个水浒传注释")
            //生成一个节点，可以传入两个参数一个是map，另一个是其他类型，map放入标签内，其他类型放入标签的数值中
            name("水浒传", id: 23, other: "无") {
    
            }
            prise(2323) {
    
            }
        }
    }
    
    stream.close()
    println stream.toString()

输出：

*  StreamingMarkupBuilder方式

import groovy.xml.MarkupBuilder
    import groovy.xml.StreamingMarkupBuilder
    
    
    import groovy.xml.StreamingMarkupBuilder
    import groovy.xml.XmlUtil
    
    def xmlBuilder = new StreamingMarkupBuilder()
    
    //bind方法标识方法开始，然后返回一个Writable对象，
    def writer = xmlBuilder.bind {
        //声明一个命名空间
        mkp.declareNamespace( register: "http://www.test.ch/register/1" )
        mkp.declareNamespace( structure: "http://test.ch/structure/1" )
        mkp.comment("hello world")
    
        'structure:structuralDataRoot' {
            'structure:tester'( 'ZH' ,'structure:name':'XiaoMing')
            'structure:surveyYear'( 2001 )
            'structure:surfaceData' {
                'structure:houseSurfaceData' {
                    'structure:creationDate'( '2001-01-01' )
                    'structure:localFarmId' {
                        'register:houseIdCategory'( 'token' )
                        'register:houseId'( 'token' )
                    }
                }
            }
        }
    }
    
    
    //XmlUtil 用于格式化输出Writable的字符串
    println XmlUtil.serialize( writer )

输出

<?xml version="1.0" encoding="UTF-8"?><structure:structuralDataRoot xmlns:structure="http://test.ch/structure/1" xmlns:register="http://www.test.ch/register/1">
      <structure:tester structure:name="XiaoMing">ZH</structure:tester>
      <structure:surveyYear>2001</structure:surveyYear>
      <structure:surfaceData>
        <structure:houseSurfaceData>
          <structure:creationDate>2001-01-01</structure:creationDate>
          <structure:localFarmId>
            <register:houseIdCategory>token</register:houseIdCategory>
            <register:houseId>token</register:houseId>
          </structure:localFarmId>
        </structure:houseSurfaceData>
      </structure:surfaceData>
    </structure:structuralDataRoot>

### 解析XML： ###

假设我们解析如下文件：

<?xml version="1.0" encoding="utf-8"?>
    <manifest xmlns:android="http://schemas.android.com/apk/res/android"
              package="com.example.administrator.androidprotobuf">
    
        <application
                android:allowBackup="true"
                android:icon="@mipmap/ic_launcher"
                android:label="@string/app_name"
                android:supportsRtl="true"
                android:theme="@style/AppTheme">
    
            <meta-data android:name="hello" android:value="1"/>
            <activity android:name=".MainActivity">
                <intent-filter>
                    <action android:name="android.intent.action.MAIN"/>
    
                    <category android:name="android.intent.category.LAUNCHER"/>
                </intent-filter>
            </activity>
        </application>
    
    </manifest>

我们第一个目标拿到所有`activity`标签的`name`数值

import groovy.xml.Namespace
    import groovy.xml.QName
    
    def parser = new XmlParser()
    
    //解析文件
    Node node = parser.parse(new File("/Users/fmy/IdeaProjects/groovy2/src/main/resources/AndroidManifest.xml"))
    
    //当前node是manifest
    assert node.name() =~ /manifest/
    
    
    //拿到所有 manifest下的所有application标签然后返回一个List
    assert node.application instanceof List
    
    //我们这里取出第一个application标签下所有的activity
    NodeList activities = node.application[0].activity
    activities.forEach { Node activity ->
    
        //得到所有属性这里返回一个Map
        def attributes = activity.attributes()
        //由于属性存在命名空间 我们需要构建一个QName才拿拿到
        def qName = new QName("http://schemas.android.com/apk/res/android", "name", "android")
        //输出结果
        println attributes.get(qName)
    }

输出：

.MainActivity
    .ScondMainActivity

在上面的例子我们构建了QName拿到了对应命名空间的数值。我们现在用另一个方式去创建一个QName。

import groovy.xml.Namespace
    import groovy.xml.QName
    
    def parser = new XmlParser()
    
    //解析文件
    Node node = parser.parse(new File("/Users/fmy/IdeaProjects/groovy2/src/main/resources/AndroidManifest.xml"))
    
    //当前node是manifest
    assert node.name() =~ /manifest/
    
    def ns = new Namespace("http://schemas.android.com/apk/res/android", "android")
    
    //ns.xxx建创建一个 如后文所示类 new QName("http://schemas.android.com/apk/res/android", "xxx", "android")
    //ns.name建创建一个 new QName("http://schemas.android.com/apk/res/android", "name", "android")
    
    
    
    //拿到所有 manifest下的所有application标签然后返回一个List
    assert node.application instanceof List
    
    //我们这里取出第一个application标签下所有的activity
    NodeList activities = node.application[0].activity
    activities.forEach { Node activity ->
    
        //得到所有属性这里返回一个Map
        def attributes = activity.attributes()
        //由于属性存在命名空间 我们需要构建一个QName才拿拿到
        //输出结果
        println attributes.get(ns.name)
    }

当然我们还可以在遍历的时候修改某些数值。假设我们这里修改activity所有name为ILove

import com.sun.xml.internal.bind.v2.runtime.output.XmlOutput
    import groovy.xml.Namespace
    import groovy.xml.QName
    
    def parser = new XmlParser()
    
    //解析文件
    Node node = parser.parse(new File("/Users/fmy/IdeaProjects/groovy2/src/main/resources/AndroidManifest.xml"))
    
    //当前node是manifest
    assert node.name() =~ /manifest/
    
    def ns = new Namespace("http://schemas.android.com/apk/res/android", "android")
    
    //ns.xxx建创建一个 如后文所示类 new QName("http://schemas.android.com/apk/res/android", "xxx", "android")
    //ns.name建创建一个 new QName("http://schemas.android.com/apk/res/android", "name", "android")
    
    
    //拿到所有 manifest下的所有application标签然后返回一个List
    assert node.application instanceof List
    
    //我们这里取出第一个application标签下所有的activity
    NodeList activities = node.application[0].activity
    activities.forEach { Node activity ->
    
        //得到所有属性这里返回一个Map
        def attributes = activity.attributes()
        attributes[ns.name] = "ILove"
    
    }
    
    
    def byteArray = new ByteArrayOutputStream()
    def d = new PrintWriter(byteArray)
    new XmlNodePrinter(d).print(node)
    
    println(new String(byteArray.toByteArray()))

输出：