js验证开始日期不能大于结束日期_15个日期时间计算套路，快快拿走不用谢

缺乏、安全感 2023-01-04 13:14 286阅读 0赞

## 小伙伴们好啊，今天老祝和大家一起学习日期时间计算的套路，掌握这些套路，工作效率可以再高一点点。 ##

**1、合并日期和时间**

如下图，如何将A列日期和B列的时间合并到一起，变成既有日期又带有时间的数据呢？哈哈哈，只要把日期和时间相加即可。

![27e082baae8a52a153fcf6c1021c7498.gif][]

**2、拆分日期和时间**

如果要将日期和时间合并在一起的数据拆分开，需要怎么处理呢？

别着急，使用以下公式就可以得到日期：

=INT(A2)

然后再用日期时间数据减去日期即可。

![7ff4e7d6eefd286f95054285e725726a.gif][]

**3、计算间隔几小时**

如何计算两个时间之间有多少个小时呢？

很简单，用结束时间减去开始时间，然后乘以24即可。

![3a2d60e6ef647fb295b112ddc006dd08.gif][]

**4、计算间隔多少分钟**

如何计算两个时间之间有多少个分钟呢？

小意思，用结束时间减去开始时间，然后乘以1440即可。

![a5ab83c63206fa33b640353c126ca5c1.gif][]

**5、突出显示周末日期**

1、选中A3:F7单元格区域，新建格式规则

2、使用公式为：

=WEEKDAY(A$3,2)>5

3、设置突出显示的格式

![32c61e6007c24312156af6e745f25533.gif][]

提示：

1、WEEKDAY函数返回某日期为星期几。第二参数使用2，表示以1~7表示星期一到星期日。

2、对第三行中的日期进行判断后，如果数值大于5，即表示该日期为周六或是周日。

**6、指定日期所在月有几天**

=DAY(EOMONTH(A2,0))

![15387047159ebdd2e2d62b3358b1ad0f.png][]

EOMONTH函数返回在某个日期之后指定月份后的最后一天，EOMONTH(A2,0)函数得到日期所在月最后一天的日期，DAY函数返回该日期是几号。

**7、区分指定日期是上中下旬**

Excel中没有直接判断上中下旬的函数，但是咱们可以使用LOOKUP函数变通一下判断出结果：

=LOOKUP(DAY(A2),\{0,11,21\},\{"上旬","中旬","下旬"\})

![b7a480641866a3a91f8ee81d2557bb16.png][]

先用DAY函数，判断A2单元格的日期是几号，然后用LOOKUP函数近似匹配，如果在0~10之间就是上旬，在11~20之间就是中旬，其他就是下旬。

**8、根据身份证号计算出生年月**

计算公式为：

=1\*TEXT(MID(B2,7,8),"0-00-00")

![570ca7e886eb340393561ca0ae50f181.png][]

首先使用MID函数从B2单元格的第7位开始，提取出表示出生年月的8个字符，结果为：

"19780215"

再使用TEXT函数将字符串转换为日期样式：

"1978-02-15"

然后通过\*1计算，将其转换为真正的日期。最后设置为日期格式即可。

**9、计算转正时间**

如下图，要根据B列的员工入职日期和C列的试用期月数，计算员工转正日期。

D2单元格公式为：

=EDATE(B2,C2)

![5c95749df1ec83e45077a1f4c0f80dd3.png][]

EDATE函数用于指定某个日期N月之后或是N月之前的日期。

用法为：

=EDATE(开始日期,指定月份)

**10、按年月汇总**

如下图，有几百行数据，要按年月汇总各个区域的销售总额。

使用数据透视表，分分钟搞定：

![dde9025eab6dad25b9417ec31cc0fb97.gif][]

**11、计算工龄年月**

如下图，要根据员工入职日期，按月计算工龄。

C2单元格公式为：

=DATEDIF(B2,"2017-5-30","m")

![eb28af59fc01446d814b3c08ba23d61e.png][]

DATEDIF函数用于计算两个日期之间的间隔，第二参数使用**m**，表示计算间隔的整月数。

如果第二参数使用**y**，则表示计算间隔的整年数。

**12、有多少个工作日**

如下图，使用函数可以计算两个日期之间，去除周末和法定节假日的工作日天数。

=NETWORKDAYS(A2,B2,A6:A8)

![78d9231514c91e1d1f1583b5cb51e73a.gif][]

NETWORKDAYS函数的用法为：

=NETWORKDAYS(开始日期,结束日期,需要从工作日历中排除的法定节假日)

**13、带调休的工作日天数**

实际工作中，要计算工作日时，除了要考虑去除周末和法定节假日的工作日天数，还要加上调休日。对于这种情况，咱们需要先建立一个调休和法定节假日的对照表。

如下图所示，F列是放假时间，G列是调休上班时间。

![8894e0703e4250e3f3ef41f9da463dbc.png][]

接下来，咱们就可以在C2单元格中写公式了：

=NETWORKDAYS(A2,B2,F$2:F$28)+COUNTIFS(G$2:G$28,">="&A2,G$2:G$28,"<="&B2)

![3f4b3ee75a255d7eb1851bde37bf4c00.png][]

先使用NETWORKDAYS函数计算出去除法定节假日后的工作日天数，然后用COUNTIFS函数计算从开始日期到结束日期这个阶段中，有几天是需要调休上班的。把这部分调休的天数加上，就是最终的工作日天数了。

**14、n个工作日之后是哪天**

如下图，使用函数可以计算n个工作日之后是哪天。公式为：

=WORKDAY(A2,B2,A6:A8)

![50166c7009048a971ad9de1ac579dc54.gif][]

WORKDAY函数的用法为：

=WORKDAY(开始日期,工作日数,需要从工作日历中排除的法定节假日)

**15、调休下的n个工作日之后的日期**

如果要在调休的前提下，计算N个工作日之后的日期是哪天，该怎么办呢？

同样，先要准备一个法定节假日和调休的对照表，咱们仍然使用例子13中的对照表。

C2单元格公式为：

=MATCH(B2,NETWORKDAYS(A2,A2+ROW($1:$999),F$2:F$28)+COUNTIFS(G$2:G$28,">="&A2,G$2:G$28,"<="&A2+ROW($1:$999)),)+A2

![e6e8b88f3edb25eb5d7c0b303c416bc3.png][]

公式看起来比较长，但是原理并不复杂，先使用ROW($1:$999)得到1到999的序号，然后与A2的开始日期相加，这样就分别得到从开始日期之后第一天到第999天的日期了。

然后，用NETWORKDAYS函数结合COUNTIFS函数，以A2日期为开始日期，分别计算出从4月23日到4月24日、4月23日到4月25日、4月23日到4月26日、……4月23日到12月31日……，这些期间分别有多少个工作日，返回一个内存数组结果：

\{2;2;3;4;5;6;7;7;7;7;7;7;8;9;10;11;11;12;13;14;15;16;……;707;708\}

再使用MATCH函数，在这个内存数组中查找B2单元格中的工作日天数所处的位置，得到的结果，就是从A2开始N多天之后才会有15个工作日。

最后使用这个位置信息加上A2的起始日期，就得到最终需要的结果了。

好了，今天的分享就是这些吧，祝各位小伙伴们一天好心情！

图文制作：老祝

[27e082baae8a52a153fcf6c1021c7498.gif]: /images/20221119/f6460a3f0b144d02bca945fa5911c24f.png
[7ff4e7d6eefd286f95054285e725726a.gif]: /images/20221119/3739043a7bd34bb79906f2e0d541e501.png
[3a2d60e6ef647fb295b112ddc006dd08.gif]: https://img-blog.csdnimg.cn/img_convert/3a2d60e6ef647fb295b112ddc006dd08.gif
[a5ab83c63206fa33b640353c126ca5c1.gif]: https://img-blog.csdnimg.cn/img_convert/a5ab83c63206fa33b640353c126ca5c1.gif
[32c61e6007c24312156af6e745f25533.gif]: https://img-blog.csdnimg.cn/img_convert/32c61e6007c24312156af6e745f25533.gif
[15387047159ebdd2e2d62b3358b1ad0f.png]: https://img-blog.csdnimg.cn/img_convert/15387047159ebdd2e2d62b3358b1ad0f.png
[b7a480641866a3a91f8ee81d2557bb16.png]: https://img-blog.csdnimg.cn/img_convert/b7a480641866a3a91f8ee81d2557bb16.png
[570ca7e886eb340393561ca0ae50f181.png]: https://img-blog.csdnimg.cn/img_convert/570ca7e886eb340393561ca0ae50f181.png
[5c95749df1ec83e45077a1f4c0f80dd3.png]: https://img-blog.csdnimg.cn/img_convert/5c95749df1ec83e45077a1f4c0f80dd3.png
[dde9025eab6dad25b9417ec31cc0fb97.gif]: https://img-blog.csdnimg.cn/img_convert/dde9025eab6dad25b9417ec31cc0fb97.gif
[eb28af59fc01446d814b3c08ba23d61e.png]: https://img-blog.csdnimg.cn/img_convert/eb28af59fc01446d814b3c08ba23d61e.png
[78d9231514c91e1d1f1583b5cb51e73a.gif]: https://img-blog.csdnimg.cn/img_convert/78d9231514c91e1d1f1583b5cb51e73a.gif
[8894e0703e4250e3f3ef41f9da463dbc.png]: https://img-blog.csdnimg.cn/img_convert/8894e0703e4250e3f3ef41f9da463dbc.png
[3f4b3ee75a255d7eb1851bde37bf4c00.png]: https://img-blog.csdnimg.cn/img_convert/3f4b3ee75a255d7eb1851bde37bf4c00.png
[50166c7009048a971ad9de1ac579dc54.gif]: https://img-blog.csdnimg.cn/img_convert/50166c7009048a971ad9de1ac579dc54.gif
[e6e8b88f3edb25eb5d7c0b303c416bc3.png]: https://img-blog.csdnimg.cn/img_convert/e6e8b88f3edb25eb5d7c0b303c416bc3.png