执行任意d代码的模板

ゝ一纸荒年。 2022-08-28 07:59 8阅读 0赞

[原文][Link 1]  
我们来搞`编译时`运行`d代码`.`定义`外部`模板文件`有时有用.如`脚手架/超文本模板`等等.我们用`模板`执行`d代码`来决定`值`.

# 基本格式 #

`dub init`,并创建`views`文件夹.允许模板`定义变量`,这样`程序`最后来填充它.为了简单,变量只是`文本串`.`views/template.txt`中内容如下:

DECLARE
        $NAME
        $AGE
        $HOBBIES
    START
    我叫$NAME,年龄$AGE,爱好为:$HOBBIES.

在`source/app.d`中编辑初始结构:

import std;
    
    struct Document
    { 
        string[] declaredVariables;
        string templateText;
    }//用文档来建模文件.
    //现在仅简单变量名及要解析文本.
    string resolve(string templateName)(string[string] variables)
    { //用该函数来`解析`.
        Appender!(char[]) output;
        return output.data.assumeUnique;
    }//`templateName`模板名为编译时参数.变量为运行时.
    
    Document parseDocument(string contents)
    { //解析模板为文本构.
        Document doc;
        return doc;
    }
    
    void main()
    { 
    //使用解析函数.
        writeln(resolve!"template.txt"(
        [
            "$NAME":    "Bradley",
            "$AGE":     "22",
            "$HOBBIES": "programming, complaining, 和 long walks at night."
        ]));
    }

用`import std;`,可访问`整个标准库`,但会降低`编译速度`及增加大小.

# 解析文档 #

Document parseDocument(string contents)
    { 
        enum Mode
        { 
            none,
            declare,
            start
        }
    
        Document doc;
        Mode mode;
    
        foreach(line; contents.lineSplitter())
        { 
        switch(mode) with(Mode)
        { 
            case none:
                enforce(line == "DECLARE", "要按'DECLARE'开头");
                mode = declare;
                break;
    
            case declare:
    //声明模式,去左边空格,加入变量
                if(line == "START")
                { 
                    mode = start;
                    continue;
                }
    
                doc.declaredVariables ~= line.strip(' ');
                break;
    
            case start://开始了.
                if(doc.templateText.length > 0)
                    doc.templateText ~= '\n';
                doc.templateText ~= line;//合并行.
                break;
    
            default: assert(false);
        }
        }
    
        return doc;
    }

用根据当前`模式`决定的简单的状态机来解析,`D`允许函数有自己的`类,结构,枚举`等.  
`with(Mode)`,用来简化书写.与`switch`配对用.

# 实现解析 #

string resolve(string templateName)(string[string] variables)
    { 
        // 为了方便用户,显式声明类型,`D`可自动推导
        const string TEMPLATE_CONTENTS = import(templateName);
        enum Document Doc = parseDocument(TEMPLATE_CONTENTS);
        enforce(
            Doc.declaredVariables.all!(varName => varName in variables), 
            "有些变量无值".
        );
    
        Appender!(char[]) output;
    
        string text = Doc.templateText;
        while(text.length > 0)
        { 
            const nextVarStart = text.indexOf('$');
            if(nextVarStart < 0)
            { 
                output.put(text);
                break;
            }
    
            output.put(text[0..nextVarStart]);
            text = text[nextVarStart..$];
    
            const nextSpace = text.indexOfAny(" \r\n");
            const varName   = (nextSpace < 0) ? text : text[0..nextSpace];
            text            = (nextSpace < 0) ? null : text[nextSpace..$];
            output.put(variables[varName]);
        }
    
        return output.data.assumeUnique;
    }

这里,

const string TEMPLATE_CONTENTS = import(templateName);

`views`目录,为`dub`自动告诉`编译器`的`导入串`目录.以`template.txt`为`编译时`参数.`import(string)`导入`文件`为`串`变量.  
用`resolve!"template.txt"`导入`该文件`.然后:

enum Document Doc = parseDocument(TEMPLATE_CONTENTS);.

解析文档.`枚举值`为`清单常量`,`exe`中无物理地址,仅在`编译时`存在.使用时`复制`,类似`C++`中的`#define`.解析后放在`文档`中.这是`ctfe`,编译时执行函数.剩下是用`变量[值]`中值替换`值`.  
`dub run`运行.

# 最终格式 #

DECLARE
        $NAME
        $AGE
        $HOBBIES
    COMPUTE
        $HOBBIES_LOUD : variables["$HOBBIES"].splitter(',').map!(str => "!!!"~str.strip(' ').toUpper~"!!!").fold!((a,b) => a~", "~b)
    //,分割.等等
    START

加了个包含`D`代码`计算`的值的节.现在更新代码:

struct Document
    { 
        string[] declaredVariables;
        string templateText;
    
        // 键为名,值为`D代码`
        string[string] computedVariables;
    }
    
    Document parseDocument(string contents)
    { 
        enum Mode
        { 
            none,
            declare,
            start,
    
            ///
            compute
            ///
        }
    
        Document doc;
        Mode mode;
    
        foreach(line; contents.lineSplitter())
        { 
        switch(mode) with(Mode)
        { 
            case none:
                enforce(line == "DECLARE", "必须按'DECLARE'开头");
                mode = declare;
                break;
            case declare:
                if(line == "START")
                { 
                    mode = start;
                    continue;
                }
                //
                else if(line == "COMPUTE")
                { 
                    mode = compute;
                    continue;
                }
                //
    
                doc.declaredVariables ~= line.strip(' ');
                break;
    
            
            case compute:
                if(line == "START")
                { 
                    mode = start;
                    continue;
                }
    
                const colon   = line.indexOf(':');
                const varName = line[0..colon].strip(' ');
                const code  = line[colon+1..$].strip(' ');
                doc.computedVariables[varName] = code;//加代码.
                break;
            
    
            case start:
                if(doc.templateText.length > 0)
                    doc.templateText ~= '\n';
                doc.templateText ~= line;
                break;
    
            default: assert(false);
        }
        }
    
        return doc;
    }

现在,文档为`键/代码的字典`,加个`计算`模式,`计算`区用`首个:`来分割`键/代码`.  
现在来`解析`,你不必自己写`词法/语法`解析器.

string resolve(string templateName)(string[string] variables)
    { 
        const string TEMPLATE_CONTENTS = import(templateName);
        enum Document Doc = parseDocument(TEMPLATE_CONTENTS);
        enforce(
            Doc.declaredVariables.all!(varName => varName in variables), 
            "不是所有变量都有值"
        );
    
        static foreach(varName, code; Doc.computedVariables)
            variables[varName] = mixin(code);
        //插件就完了.
    
        Appender!(char[]) output;
    
        string text = Doc.templateText;
        while(text.length > 0)
        { 
            const nextVarStart = text.indexOf('$');
            if(nextVarStart < 0)
            { 
                output.put(text);
                break;
            }
    
            output.put(text[0..nextVarStart]);
            text = text[nextVarStart..$];
    
            const nextSpace = text.indexOfAny(" \r\n");
            const varName   = (nextSpace < 0) ? text : text[0..nextSpace];
            text            = (nextSpace < 0) ? null : text[nextSpace..$];
            output.put(variables[varName]);
        }
    
        return output.data.assumeUnique;
    }

`staticforeach`编译时的`每一`.每行`插件`就完成`求值`了.`或者`叫`展开`.`插件(代码)`是`串插件`.可在`static foreach和mixin`中直接用`枚`中编译时变量.  
`dub run`.现在,你可用`pegged`库来`翻译`你的`dsl`至`d`.你只需要翻译至`D`,然后`插件`它.

# 解析其他文件 #

在`views/other.txt`中写入:

DECLARE
        $HOWDY
    START
    HOWDY $HOWDY

`views/template.txt`中:

DECLARE
        $NAME
        $AGE
        $HOBBIES
    COMPUTE
        $HOBBIES_LOUD : variables["$HOBBIES"].splitter(',').map!(str => "!!!"~str.strip(' ').toUpper~"!!!").fold!((a,b) => a~", "~b)
        $MYSELF  : readText("views/template.txt")
        $OTHER   : resolve!("other.txt")(["$HOWDY": "Y'ALL"])
    START
    My name is $NAME I am $AGE years old and my hobbies are: $HOBBIES
    爱好大写版: $HOBBIES_LOUD
    打印自己!
    $MYSELF
    其他模板:
    $OTHER

剩下,就是`自由发挥`了.

[Link 1]: https://bradley.chatha.dev/blog/dlang-compile-time-text-templates