汇编运行地址，链接地址，加载地址，存储地址位置无关码、位置有关码

刺骨的言语ヽ痛彻心扉 2022-08-10 16:46 135阅读 0赞

转载自:http://blog.csdn.net/linux\_103/article/details/8888427

搞[ARM][]开发时，在连接目标代码会提到运行地址和加载地址。这两者有什么区别呢?其次，网上也有说链接地址和存储地址，那么这四个地址之间有什么区别？

1、运行地址<--->链接地址：他们两个是等价的，只是两种不同的说法。

2、加载地址<--->存储地址：他们两个是等价的，也是两种不同的说法。

运行地址：程序在SRAM、SDRAM中执行时的地址。就是执行这条指令时，PC应该等于这个地址，换句话说，PC等于这个地址时，这条指令应该保存在这个地址内。

加载地址：程序保存在Nand flash中的地址。

位置无关码：B、BL、MOV都是位置位置无关码。

位置有关码：LDR PC,=LABEL等类似的代码都是位置有关码。

下面我们来看看一个Makefile文件

sdram.bin : head.S  leds.c  
    arm-linux-gcc  -c -o head.o head.S  
    arm-linux-gcc -c -o leds.o leds.c  
    arm-linux-ld -Ttext 0x30000000 head.o leds.o -o sdram\_elf  
    arm-linux-objcopy -O binary -S sdram\_elf sdram.bin  
    arm-linux-objdump -D -m arm  sdram\_elf > sdram.dis  
clean:  
 rm -f   sdram.dis sdram.bin sdram\_elf \*.o

我们可以看到sdram\_elf的代码段是从0x30000000地址开始存放，这个地址我们称之为运行地址。为什么从这个地址开始存放，因为SDRAM的起始地址是0x30000000.

下面来看看一个启动代码

.equ        MEM\_CTL\_BASE,       0x48000000  
.equ        SDRAM\_BASE,         0x30000000

.text  
.global \_start  
\_start:  
    bl  disable\_watch\_dog               @ 关闭WATCHDOG，否则CPU会不断重启  
    bl  memsetup                        @ 设置存储控制器  
    bl  copy\_steppingstone\_to\_sdram     @ 复制代码到SDRAM中  
    ldr pc, =on\_sdram                   @ 跳到SDRAM中继续执行  
on\_sdram:  
    ldr sp, =0x34000000                 @ 设置堆栈  
    bl  main  
halt\_loop:  
    b   halt\_loop

disable\_watch\_dog:  
    @ 往WATCHDOG寄存器写0即可  
    mov r1,     \#0x53000000  
    mov r2,     \#0x0  
    str r2,     \[r1\]  
    mov pc,     lr      @ 返回

copy\_steppingstone\_to\_sdram:  
    @ 将Steppingstone的4K数据全部复制到SDRAM中去  
    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000  
      
    mov r1, \#0  
    ldr r2, =SDRAM\_BASE  
    mov r3, \#4\*1024  
1:    
    ldr r4, \[r1\],\#4     @ 从Steppingstone读取4字节的数据，并让源地址加4  
    str r4, \[r2\],\#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4  
    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？  
    bne 1b              @ 若没有复制完，继续  
    mov pc,     lr      @ 返回

memsetup:  
    @ 设置存储控制器以便使用SDRAM等外设

mov r1,     \#MEM\_CTL\_BASE       @ 存储控制器的13个寄存器的开始地址  
    adrl    r2, mem\_cfg\_val         @ 这13个值的起始存储地址  
    add r3,     r1, \#52             @ 13\*4 = 54  
1:    
    ldr r4,     \[r2\], \#4            @ 读取设置值，并让r2加4  
    str r4,     \[r1\], \#4            @ 将此值写入寄存器，并让r1加4  
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器  
    bne 1b                          @ 若没有写成，继续  
    mov pc,     lr                  @ 返回

.align 4  
mem\_cfg\_val:  
    @ 存储控制器13个寄存器的设置值  
    .long   0x22011110      @ BWSCON  
    .long   0x00000700      @ BANKCON0  
    .long   0x00000700      @ BANKCON1  
    .long   0x00000700      @ BANKCON2  
    .long   0x00000700      @ BANKCON3    
    .long   0x00000700      @ BANKCON4  
    .long   0x00000700      @ BANKCON5  
    .long   0x00018005      @ BANKCON6  
    .long   0x00018005      @ BANKCON7  
    .long   0x008C07A3      @ REFRESH  
    .long   0x000000B1      @ BANKSIZE  
    .long   0x00000030      @ MRSRB6  
    .long   0x00000030      @ MRSRB7

下面来看看反汇编代码

sdram\_elf:     file format elf32-littlearm  
  
  
Disassembly of section .text:  
  
30000000 <\_start>:  
30000000:    eb000005     bl    3000001c <disable\_watch\_dog>  
30000004:    eb000010     bl    3000004c <memsetup>  
30000008:    eb000007     bl    3000002c <copy\_steppingstone\_to\_sdram>  
3000000c:    e59ff090     ldr    pc, \[pc, \#144\]    ; 300000a4 <mem\_cfg\_val+0x34>  
  
30000010 <on\_sdram>:  
30000010:    e3a0d30d     mov    sp, \#872415232    ; 0x34000000  
30000014:    eb000033     bl    300000e8 <main>  
  
30000018 <halt\_loop>:  
30000018:    eafffffe     b    30000018 <halt\_loop>  
  
3000001c <disable\_watch\_dog>:  
3000001c:    e3a01453     mov    r1, \#1392508928    ; 0x53000000  
30000020:    e3a02000     mov    r2, \#0  
30000024:    e5812000     str    r2, \[r1\]  
30000028:    e1a0f00e     mov    pc, lr  
  
3000002c <copy\_steppingstone\_to\_sdram>:  
3000002c:    e3a01000     mov    r1, \#0  
30000030:    e3a02203     mov    r2, \#805306368    ; 0x30000000  
30000034:    e3a03a01     mov    r3, \#4096    ; 0x1000  
30000038:    e4914004     ldr    r4, \[r1\], \#4  
3000003c:    e4824004     str    r4, \[r2\], \#4  
30000040:    e1510003     cmp    r1, r3  
30000044:    1afffffb     bne    30000038 <copy\_steppingstone\_to\_sdram+0xc>  
30000048:    e1a0f00e     mov    pc, lr  
  
3000004c <memsetup>:  
3000004c:    e3a01312     mov    r1, \#1207959552    ; 0x48000000  
30000050:    e28f2018     add    r2, pc, \#24  
30000054:    e1a00000     nop            ; (mov r0, r0)  
30000058:    e2813034     add    r3, r1, \#52    ; 0x34  
3000005c:    e4924004     ldr    r4, \[r2\], \#4  
30000060:    e4814004     str    r4, \[r1\], \#4  
30000064:    e1510003     cmp    r1, r3  
30000068:    1afffffb     bne    3000005c <memsetup+0x10>  
3000006c:    e1a0f00e     mov    pc, lr  
  
30000070 <mem\_cfg\_val>:  
30000070:    22011110     andcs    r1, r1, \#4  
30000074:    00000700     andeq    r0, r0, r0, lsl \#14  
30000078:    00000700     andeq    r0, r0, r0, lsl \#14  
3000007c:    00000700     andeq    r0, r0, r0, lsl \#14  
30000080:    00000700     andeq    r0, r0, r0, lsl \#14  
30000084:    00000700     andeq    r0, r0, r0, lsl \#14  
30000088:    00000700     andeq    r0, r0, r0, lsl \#14  
3000008c:    00018005     andeq    r8, r1, r5  
30000090:    00018005     andeq    r8, r1, r5  
30000094:    008c07a3     addeq    r0, ip, r3, lsr \#15  
30000098:    000000b1     strheq    r0, \[r0\], -r1  
3000009c:    00000030     andeq    r0, r0, r0, lsr r0  
300000a0:    00000030     andeq    r0, r0, r0, lsr r0  
300000a4:    30000010     andcc    r0, r0, r0, lsl r0  
300000a8:    e1a00000     nop            ; (mov r0, r0)  
300000ac:    e1a00000     nop            ; (mov r0, r0)  
  
300000b0 <wait>:  
300000b0:    e52db004     push    \{fp\}        ; (str fp, \[sp, \#-4\]!)  
300000b4:    e28db000     add    fp, sp, \#0  
300000b8:    e24dd00c     sub    sp, sp, \#12  
300000bc:    e50b0008     str    r0, \[fp, \#-8\]  
300000c0:    ea000002     b    300000d0 <wait+0x20>  
300000c4:    e51b3008     ldr    r3, \[fp, \#-8\]  
300000c8:    e2433001     sub    r3, r3, \#1  
300000cc:    e50b3008     str    r3, \[fp, \#-8\]  
300000d0:    e51b3008     ldr    r3, \[fp, \#-8\]  
300000d4:    e3530000     cmp    r3, \#0  
300000d8:    1afffff9     bne    300000c4 <wait+0x14>  
300000dc:    e28bd000     add    sp, fp, \#0  
300000e0:    e8bd0800     pop    \{fp\}  
300000e4:    e12fff1e     bx    lr  
  
300000e8 <main>:  
300000e8:    e92d4800     push    \{fp, lr\}  
300000ec:    e28db004     add    fp, sp, \#4  
300000f0:    e24dd008     sub    sp, sp, \#8  
300000f4:    e3a03000     mov    r3, \#0  
300000f8:    e50b3008     str    r3, \[fp, \#-8\]  
300000fc:    e59f3030     ldr    r3, \[pc, \#48\]    ; 30000134 <main+0x4c>  
30000100:    e3a02b55     mov    r2, \#87040    ; 0x15400  
30000104:    e5832000     str    r2, \[r3\]  
30000108:    e59f0028     ldr    r0, \[pc, \#40\]    ; 30000138 <main+0x50>  
3000010c:    ebffffe7     bl    300000b0 <wait>  
30000110:    e59f3024     ldr    r3, \[pc, \#36\]    ; 3000013c <main+0x54>  
30000114:    e3a02000     mov    r2, \#0  
30000118:    e5832000     str    r2, \[r3\]  
3000011c:    e59f0014     ldr    r0, \[pc, \#20\]    ; 30000138 <main+0x50>  
30000120:    ebffffe2     bl    300000b0 <wait>  
30000124:    e59f3010     ldr    r3, \[pc, \#16\]    ; 3000013c <main+0x54>  
30000128:    e3a02e1e     mov    r2, \#480    ; 0x1e0  
3000012c:    e5832000     str    r2, \[r3\]  
30000130:    eafffff4     b    30000108 <main+0x20>  
30000134:    56000010     undefined instruction 0x56000010  
30000138:    00007530     andeq    r7, r0, r0, lsr r5  
3000013c:    56000014     undefined instruction 0x56000014  
  
Disassembly of section .ARM.attributes:  
  
00000000 <.ARM.attributes>:  
   0:    00002541     andeq    r2, r0, r1, asr \#10  
   4:    61656100     cmnvs    r5, r0, lsl \#2  
   8:    01006962     tsteq    r0, r2, ror \#18  
   c:    0000001b     andeq    r0, r0, fp, lsl r0  
  10:    00543405     subseq    r3, r4, r5, lsl \#8  
  14:    01080206     tsteq    r8, r6, lsl \#4  
  18:    04120109     ldreq    r0, \[r2\], \#-265    ; 0x109  
  1c:    01150114     tsteq    r5, r4, lsl r1  
  20:    01180317     tsteq    r8, r7, lsl r3  
  24:    Address 0x00000024 is out of bounds.  
  
  
Disassembly of section .comment:  
  
00000000 <.comment>:  
   0:    3a434347     bcc    10d0d24 <SDRAM\_BASE-0x2ef2f2dc>  
   4:    74632820     strbtvc    r2, \[r3\], \#-2080    ; 0x820  
   8:    312d676e     teqcc    sp, lr, ror \#14  
   c:    312e362e     teqcc    lr, lr, lsr \#12  
  10:    2e342029     cdpcs    0, 3, cr2, cr4, cr9, \{1\}  
  14:    00332e34     eorseq    r2, r3, r4, lsr lr

当我们从Nand flash启动时，硬件会自动将Nand flash前4kB代码拷贝到片内SRAM中，然后CPU从SRAM的0x00000000地址处开始执行程序。在这里我想纠正一个错误的观点，网上很多人都说是CPU自动把Nand flash前4kB代码拷贝到片内SRAM中，其实不然，是Nand flash控制器完成的，这个过程中CPU根本就没有参与 。

通过上面的Makefile文件，我们可以知道 bl  disable\_watch\_dog   这条指令的运行地址是0x30000000，但是它现在保存在SRAM的0x00000000的地址处，那么这条指令能够正确执行吗？of course，why？

因为这条指令 bl  disable\_watch\_dog   是位置无关码，虽然它的运行地址是在SDRAM中的0x30000000，但是它可以在Steppingstone中执行。这条指令的功能是跳转到标号disable\_watch\_dog  处执行，它是一个相对跳转，PC=当前PC的值+偏移量OFFSET。其中当前PC的值等于下两条指令的地址，通过反汇编可以看到下两条指令的地址为0x0000 0008，而不是0x3000 0008.因为现在指令是保存在SRAM中。

这条指令的机器码为eb00 0005，将机器码低24位按符号位扩展成32位得到0x0000 00005.然后将0x0000 0005左移2位得到0x0000 0014。这个值就是偏移量OFFSET=0X0000 0014。所以PC=0X0000 0008+0X0000 0014=0X0000 001c.那么CPU就会到SRAM中的0x0000 001c地址处执行程序。

可以发现bl指令依赖当前PC的值，这个特性使得bl指令不依赖指令的运行地址。所以接下来的bl mensetup ,bl cope\_steppingstone\_to\_sdram都能够执行。

接下来的ldr pc,=on\_sdram是一条位置有关码，经过反汇编可以看到，它是当前pc的值+偏移量，得到一个地址Addr，然后从内存中的这个地址去取数据Data赋给pc。现在我们计算一下Addr这个地址。

Addr=当前PC的值+144。当前PC的值等于下两条指令的地址0x0000 0014,而不是0x3000 0014,因为现在程序是保存在SRAM中。所以Addr=0x0000 0014+144=0x0000 0014+0x0000 0090=0x0000 00a4.那么这个地址0x0000 00a4中保存了什么数据。通过反汇编可以看到SRAM中的0x0000 00a4这个地址保存的机器码为30000010，所以cpu会跳转到0x30000010这个地址处执行程序。这个地址0x30000010

是在SDRAM中，这样程序就跳到SDRAM中去了。因为我们前面的指令 bl cope\_stepping\_to\_sdram 已经把SRAM中4kB的程序拷贝到了SDRAM中，所以现在SDRAM中有程序了。

但是如果在程序的开头放置一条这样的指令：ldr pc,=disable\_watch\_dog ,那么整个程序就不能够正确执行了。why？

我们先来看看启动代码

@\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
@ File：head.S  
@ 功能：设置SDRAM，将程序复制到SDRAM，然后跳到SDRAM继续执行  
@\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*         
  
.equ        MEM\_CTL\_BASE,       0x48000000  
.equ        SDRAM\_BASE,         0x30000000  
  
.text  
.global \_start  
\_start:  
    @bl  disable\_watch\_dog               @ 关闭WATCHDOG，否则CPU会不断重启  
    ldr pc, =disable\_watch\_dog             
    bl  memsetup                        @ 设置存储控制器  
    bl  copy\_steppingstone\_to\_sdram     @ 复制代码到SDRAM中  
    ldr pc, =on\_sdram                   @ 跳到SDRAM中继续执行  
on\_sdram:  
    ldr sp, =0x34000000                 @ 设置堆栈  
    bl  main  
halt\_loop:  
    b   halt\_loop  
  
disable\_watch\_dog:  
    @ 往WATCHDOG寄存器写0即可  
    mov r1,     \#0x53000000  
    mov r2,     \#0x0  
    str r2,     \[r1\]  
    mov pc,     lr      @ 返回  
  
copy\_steppingstone\_to\_sdram:  
    @ 将Steppingstone的4K数据全部复制到SDRAM中去  
    @ Steppingstone起始地址为0x00000000，SDRAM中起始地址为0x30000000  
      
    mov r1, \#0  
    ldr r2, =SDRAM\_BASE  
    mov r3, \#4\*1024  
1:    
    ldr r4, \[r1\],\#4     @ 从Steppingstone读取4字节的数据，并让源地址加4  
    str r4, \[r2\],\#4     @ 将此4字节的数据复制到SDRAM中，并让目地地址加4  
    cmp r1, r3          @ 判断是否完成：源地址等于Steppingstone的未地址？  
    bne 1b              @ 若没有复制完，继续  
    mov pc,     lr      @ 返回  
  
memsetup:  
    @ 设置存储控制器以便使用SDRAM等外设  
  
    mov r1,     \#MEM\_CTL\_BASE       @ 存储控制器的13个寄存器的开始地址  
    adrl    r2, mem\_cfg\_val         @ 这13个值的起始存储地址  
    add r3,     r1, \#52             @ 13\*4 = 54  
1:    
    ldr r4,     \[r2\], \#4            @ 读取设置值，并让r2加4  
    str r4,     \[r1\], \#4            @ 将此值写入寄存器，并让r1加4  
    cmp r1,     r3                  @ 判断是否设置完所有13个寄存器  
    bne 1b                          @ 若没有写成，继续  
    mov pc,     lr                  @ 返回  
  
  
.align 4  
mem\_cfg\_val:  
    @ 存储控制器13个寄存器的设置值  
    .long   0x22011110      @ BWSCON  
    .long   0x00000700      @ BANKCON0  
    .long   0x00000700      @ BANKCON1  
    .long   0x00000700      @ BANKCON2  
    .long   0x00000700      @ BANKCON3    
    .long   0x00000700      @ BANKCON4  
    .long   0x00000700      @ BANKCON5  
    .long   0x00018005      @ BANKCON6  
    .long   0x00018005      @ BANKCON7  
    .long   0x008C07A3      @ REFRESH  
    .long   0x000000B1      @ BANKSIZE  
    .long   0x00000030      @ MRSRB6  
    .long   0x00000030      @ MRSRB7

对应的反汇编代码

sdram\_elf:     file format elf32-littlearm  
  
  
Disassembly of section .text:  
  
30000000 <\_start>:  
30000000:    e59ff09c     ldr    pc, \[pc, \#156\]    ; 300000a4 <mem\_cfg\_val+0x34>  
30000004:    eb000010     bl    3000004c <memsetup>  
30000008:    eb000007     bl    3000002c <copy\_steppingstone\_to\_sdram>  
3000000c:    e59ff094     ldr    pc, \[pc, \#148\]    ; 300000a8 <mem\_cfg\_val+0x38>  
  
30000010 <on\_sdram>:  
30000010:    e3a0d30d     mov    sp, \#872415232    ; 0x34000000  
30000014:    eb000033     bl    300000e8 <main>  
  
30000018 <halt\_loop>:  
30000018:    eafffffe     b    30000018 <halt\_loop>  
  
3000001c <disable\_watch\_dog>:  
3000001c:    e3a01453     mov    r1, \#1392508928    ; 0x53000000  
30000020:    e3a02000     mov    r2, \#0  
30000024:    e5812000     str    r2, \[r1\]  
30000028:    e1a0f00e     mov    pc, lr  
  
3000002c <copy\_steppingstone\_to\_sdram>:  
3000002c:    e3a01000     mov    r1, \#0  
30000030:    e3a02203     mov    r2, \#805306368    ; 0x30000000  
30000034:    e3a03a01     mov    r3, \#4096    ; 0x1000  
30000038:    e4914004     ldr    r4, \[r1\], \#4  
3000003c:    e4824004     str    r4, \[r2\], \#4  
30000040:    e1510003     cmp    r1, r3  
30000044:    1afffffb     bne    30000038 <copy\_steppingstone\_to\_sdram+0xc>  
30000048:    e1a0f00e     mov    pc, lr  
  
3000004c <memsetup>:  
3000004c:    e3a01312     mov    r1, \#1207959552    ; 0x48000000  
30000050:    e28f2018     add    r2, pc, \#24  
30000054:    e1a00000     nop            ; (mov r0, r0)  
30000058:    e2813034     add    r3, r1, \#52    ; 0x34  
3000005c:    e4924004     ldr    r4, \[r2\], \#4  
30000060:    e4814004     str    r4, \[r1\], \#4  
30000064:    e1510003     cmp    r1, r3  
30000068:    1afffffb     bne    3000005c <memsetup+0x10>  
3000006c:    e1a0f00e     mov    pc, lr  
  
30000070 <mem\_cfg\_val>:  
30000070:    22011110     andcs    r1, r1, \#4  
30000074:    00000700     andeq    r0, r0, r0, lsl \#14  
30000078:    00000700     andeq    r0, r0, r0, lsl \#14  
3000007c:    00000700     andeq    r0, r0, r0, lsl \#14  
30000080:    00000700     andeq    r0, r0, r0, lsl \#14  
30000084:    00000700     andeq    r0, r0, r0, lsl \#14  
30000088:    00000700     andeq    r0, r0, r0, lsl \#14  
3000008c:    00018005     andeq    r8, r1, r5  
30000090:    00018005     andeq    r8, r1, r5  
30000094:    008c07a3     addeq    r0, ip, r3, lsr \#15  
30000098:    000000b1     strheq    r0, \[r0\], -r1  
3000009c:    00000030     andeq    r0, r0, r0, lsr r0  
300000a0:    00000030     andeq    r0, r0, r0, lsr r0  
300000a4:    3000001c     andcc    r0, r0, ip, lsl r0  
300000a8:    30000010     andcc    r0, r0, r0, lsl r0  
300000ac:    e1a00000     nop            ; (mov r0, r0)  
  
300000b0 <wait>:  
300000b0:    e52db004     push    \{fp\}        ; (str fp, \[sp, \#-4\]!)  
300000b4:    e28db000     add    fp, sp, \#0  
300000b8:    e24dd00c     sub    sp, sp, \#12  
300000bc:    e50b0008     str    r0, \[fp, \#-8\]  
300000c0:    ea000002     b    300000d0 <wait+0x20>  
300000c4:    e51b3008     ldr    r3, \[fp, \#-8\]  
300000c8:    e2433001     sub    r3, r3, \#1  
300000cc:    e50b3008     str    r3, \[fp, \#-8\]  
300000d0:    e51b3008     ldr    r3, \[fp, \#-8\]  
300000d4:    e3530000     cmp    r3, \#0  
300000d8:    1afffff9     bne    300000c4 <wait+0x14>  
300000dc:    e28bd000     add    sp, fp, \#0  
300000e0:    e8bd0800     pop    \{fp\}  
300000e4:    e12fff1e     bx    lr  
  
300000e8 <main>:  
300000e8:    e92d4800     push    \{fp, lr\}  
300000ec:    e28db004     add    fp, sp, \#4  
300000f0:    e24dd008     sub    sp, sp, \#8  
300000f4:    e3a03000     mov    r3, \#0  
300000f8:    e50b3008     str    r3, \[fp, \#-8\]  
300000fc:    e59f3030     ldr    r3, \[pc, \#48\]    ; 30000134 <main+0x4c>  
30000100:    e3a02b55     mov    r2, \#87040    ; 0x15400  
30000104:    e5832000     str    r2, \[r3\]  
30000108:    e59f0028     ldr    r0, \[pc, \#40\]    ; 30000138 <main+0x50>  
3000010c:    ebffffe7     bl    300000b0 <wait>  
30000110:    e59f3024     ldr    r3, \[pc, \#36\]    ; 3000013c <main+0x54>  
30000114:    e3a02000     mov    r2, \#0  
30000118:    e5832000     str    r2, \[r3\]  
3000011c:    e59f0014     ldr    r0, \[pc, \#20\]    ; 30000138 <main+0x50>  
30000120:    ebffffe2     bl    300000b0 <wait>  
30000124:    e59f3010     ldr    r3, \[pc, \#16\]    ; 3000013c <main+0x54>  
30000128:    e3a02e1e     mov    r2, \#480    ; 0x1e0  
3000012c:    e5832000     str    r2, \[r3\]  
30000130:    eafffff4     b    30000108 <main+0x20>  
30000134:    56000010     undefined instruction 0x56000010  
30000138:    00007530     andeq    r7, r0, r0, lsr r5  
3000013c:    56000014     undefined instruction 0x56000014  
  
Disassembly of section .ARM.attributes:  
  
00000000 <.ARM.attributes>:  
   0:    00002541     andeq    r2, r0, r1, asr \#10  
   4:    61656100     cmnvs    r5, r0, lsl \#2  
   8:    01006962     tsteq    r0, r2, ror \#18  
   c:    0000001b     andeq    r0, r0, fp, lsl r0  
  10:    00543405     subseq    r3, r4, r5, lsl \#8  
  14:    01080206     tsteq    r8, r6, lsl \#4  
  18:    04120109     ldreq    r0, \[r2\], \#-265    ; 0x109  
  1c:    01150114     tsteq    r5, r4, lsl r1  
  20:    01180317     tsteq    r8, r7, lsl r3  
  24:    Address 0x00000024 is out of bounds.  
  
  
Disassembly of section .comment:  
  
00000000 <.comment>:  
   0:    3a434347     bcc    10d0d24 <SDRAM\_BASE-0x2ef2f2dc>  
   4:    74632820     strbtvc    r2, \[r3\], \#-2080    ; 0x820  
   8:    312d676e     teqcc    sp, lr, ror \#14  
   c:    312e362e     teqcc    lr, lr, lsr \#12  
  10:    2e342029     cdpcs    0, 3, cr2, cr4, cr9, \{1\}  
  14:    00332e34     eorseq    r2, r3, r4, lsr lr

通过反汇编代码我们可以看到：第一条指令

ldr pc,=disable\_watch\_dog 对应的反汇编代码为30000000:    e59ff09c     ldr    pc, \[pc, \#156\]    ; 300000a4 <mem\_cfg\_val+0x34>

其中pc=下两条指令的地址=0x0000 0008，立即数156对应的16进制为为0x0000 009c，0x0000 0008+0x0000 009c=0x0000 00a4.而SRAM中的0x0000 00a4这个地址中保存的机器码为3000001c，所以执行完这条指令后pc=0x3000 001c，0x3000 001c这个地址是SDRAM中的，而现在SDRAM中什么都没有，所以程序不能正确执行。

[ARM]: http://blog.csdn.net/shanzhizi/article/category/1277259