soapui 自动化教程（三）

超、凢脫俗 2022-08-05 11:15 158阅读 0赞

## soapui 之 groovy 进阶 ##

上一节讲到如何使用groovy脚本执行用例。

def testStep = TEST_SUITE.getTestCaseByName('TestSuite').getTestStepByName('login')
    def testStepContext = new WsdlTestRunContext(testStep)
    def result = testStep.run(testRunner, testStepContext)

显然，如果执行的用例较多，这样将用例名写到代码中是不行的。

--------------------

**接下来讲如何通过加载任务文件执行需要测试的用例。**  
**本节将介绍 groovy加载任务文件->执行用例->验证结果**

### 加载任务 ###

配置任务文件路径：  
![这里写图片描述][20150914205352187]  
**任务文件内容：**

[{
        "comment": "登录接口 status=1 登录成功。reqName格式为：TestCaseName-TestStepName；expect为期望值；extParams的属性可以动态设置值并覆盖用例的默认参数",
        "reqName": "TestSuite-login",
        "extParams": {
            "account": "lj745280746",
            "password": "123456"
        },
        "expect": {
            "status": "1"
        }
    },{
        "comment": "测试接口A",
        "reqName": "TestSuite-testA",
        "expect": {
            "data": {
                "staus": "1"
            }
        }
    },{
        "comment": "测试接口B",
        "reqName": "TestSuite-testB",
        "expect": {
            "data": {
                "result": "abc"
            }
        }
    }]

以下代码读取、解析任务文件：

import com.eviware.soapui.impl.wsdl.testcase.WsdlTestRunContext
    import groovy.json.JsonSlurper
    
    JSON = new JsonSlurper()
    CURRENT_TESTCASE = testRunner.testCase
    TEST_SUITE = CURRENT_TESTCASE.parent
    
    //加载任务
    def taskFile = new File(CURRENT_TESTCASE.properties.task_file.value)
    log.info JSON.parseText(taskFile.getText())

![这里写图片描述][20150914210034606]

--------------------

### 执行用例 ###

任务文件按规则定义成数组，只需遍历数组执行相关用例：

import com.eviware.soapui.impl.wsdl.testcase.WsdlTestRunContext
    import groovy.json.JsonSlurper
    
    JSON = new JsonSlurper()
    
    CURRENT_TESTCASE = testRunner.testCase
    TEST_SUITE = CURRENT_TESTCASE.parent
    
    //============================================= RUN =======================================================
    ({
        //加载任务
        def taskFile = new File(CURRENT_TESTCASE.properties.task_file.value)
        def tasks = JSON.parseText(taskFile.getText())
    
        //执行任务
        tasks.each {
            def caseName = it.reqName.split("-")[0]
            def stepName = it.reqName.split("-")[1]
    
            def testStep = TEST_SUITE.getTestCaseByName(caseName).getTestStepByName(stepName)
    
            def testStepContext = new WsdlTestRunContext(testStep)
            def result = testStep.run(testRunner, testStepContext)
            //打印返回结果
            log.info "【result data】" + result.responseContent
        }
    }())
    
    return

已新增两个接口testA、testB 返回值如下：

Tue Sep 15 11:38:55 CST 2015:INFO:【result data】{
       "token":"e020fe6e-62f1-4b42-bd33-83eaaf108fa8","status":"1"}
    Tue Sep 15 11:38:55 CST 2015:INFO:【result data】{
       "data":"A"}
    Tue Sep 15 11:38:55 CST 2015:INFO:【result data】{
       "data":"Bdd"}

### 验证结果 ###

比如任务文件描述testA期望返回值中data下的status属性值为1；tsetB接口期望返回值中data下的result属性值为abc。（例子都默认接口返回json类型数据，如果返回的是字符串类型校验步骤更简单）  
写一个独立方法校验结果，这是教程唯一稍微复杂一点的函数。需要了解一点**java类型判断**，及**匿名函数、递归**。

//递归    深度比较返回值与期望是否匹配
    def verifyExcept(actual, expect) {
        def rs = true
    
       //类型判断 java Collection 与 Map 不同的遍历方式
        if (expect instanceof Collection) {
            expect.eachWithIndex {
       it, i ->
               //log.info "i:" + i + " it:" + it
                if (it instanceof Map || it instanceof Collection) {
                    return rs = verifyExcept(actual[i], it)
                } else {
                    if (actual[i] != it) {
                        log.error "expect: $index:${i}=${it} actual:${actual[i]}"
                        return rs = false
                    }
                }
            }
        } else if (expect instanceof Map) {
            expect.each {k, v ->
               //log.info "k:" + k + " v:" + v
                if (v instanceof Map || v instanceof Collection) {
                    return rs = verifyExcept(actual[k], v)
                } else {
                    if (actual[k] != v) {
                        log.error "expect: ${k}=${v} actual:${actual[k]}"
                        return rs = false
                    }
                }
            }
        } else {
            log.error "expect is not Object!"
            rs = false
        }
    
        return rs
    }

在脚本中打印返回值后添加一下代码，调用`verifyExcept`函数校验返回值：

def rsJson = JSON.parseText(result.responseContent)
            if (verifyExcept(rsJson, it.expect)) {
                    log.info "【${it.reqName}】success!"
                    assert true
            } else {
                log.error "【${it.reqName}】fail!"
                assert false
            }

执行结果，testB接口失败，期望result=abc，实际值为Bdd。  
![这里写图片描述][20150915140727207]

至此，已基本达到目标，通过文件配置任务，校验返回结果，实现接口自动化。下一节将介绍更“高级”的功能，体现这种方式的优势，如**动态参数、参数回传、参数加密、soapui引入第三方jar包、生成随机参数（绕过业务逻辑中的一些唯一校验阻碍自动化）**，以适应更真实、复杂的场景。

**ps:`verifyExcept`函数能校验任意层数json结构数据的返回值某属性是否相等，或数组是否包含某个值。但不能校验不等、不包含的情况。在本例将不支持，各位如有需要请自行扩展。[下一节][Link 1]会讲到类似实现。**

[20150914205352187]: /images/20220731/2d2146c2e3524254adae69ca35aab416.png
[20150914210034606]: /images/20220731/c1730b22090d4c89acd54a096a8c9015.png
[20150915140727207]: /images/20220731/8cda299b1a914dc183d41fd540a25b4e.png
[Link 1]: http://blog.csdn.net/lj745280746/article/details/48471961