Arduino智能小车——小车测速

灰太狼 2022-06-09 06:21 1413阅读 0赞

# Arduino智能小车——小车测速 #

Arduino智能小车系列教程时空门：

1.  Arduino智能小车——拼装篇 [点击跳转][Link 1]
2.  Arduino智能小车——测试篇 [点击跳转][Link 2]
3.  Arduino智能小车——调速篇 [点击跳转][Link 3]
4.  Arduino智能小车——超声波避障 [点击跳转][Link 4]
5.  Arduino智能小车——蓝牙小车 [点击跳转][Link 5]
6.  Arduino智能小车——循迹篇 [点击跳转][Link 6]
7.  Arduino智能小车——小车测速 [点击跳转][Link 7]

### 文章目录 ###

*  Arduino智能小车——小车测速
 *   *  测速模块的安装
     *  测速模块讲解
     *  测试代码如下
     *  测速效果

可以用于测速的模块很多，比如加速度计、激光、超声波、编码器等等，由于我们对小车速度的测量精度要求不高，因此我们可以借助小车套件里面的码盘配上测速模块对其速度进行测量。  
\#\#准备材料  
**测速模块**  
  网上的测速模块有很多种外观，但是其工作原理类似，下面列出来了几种常见的测速模块，这些测速模块接线类似。

![SouthEast][]![SouthEast 1][]

以上两种模块只能对一路电机的速度进行测量，下面这个可以同时测量两路电机，但是由于其间距固定，在安装时可能不兼容不同小车底盘，因此为了安装方便，在此篇教程中使用第一种模块。

![SouthEast 2][]

**固定铜柱**

建议铜柱长度30CM，大小为M3

![SouthEast 3][]

由于铜柱导电，有些电路板如果固定孔设计不当的话很容易导致电路板烧坏，尤其是在以后的项目中可能会用到更高的电压，因此在这里我建议大家可以准备一些尼龙柱来固定电路板。尼龙柱的尺寸跟铜柱尺寸相同M3，30CM。大家也可以顺便买一点尼龙螺丝。

![SouthEast 4][]

除此之外还需要准备杜邦线

## 测速模块的安装 ##

驱动模块的安装需要由尼龙柱支撑

![SouthEast 5][]

驱动模块安装时需要注意，不能影响轮子的正常工作，不能触碰到轮轴上的码盘。  
  编码器上有三个引脚分别是“VCC”,“GND”,“OUT”。左右两边两个测速模块的“VCC”引脚接电源或开发板的“5V”或“3.3V”引脚,“GND”接电源或开发板的“GND”引脚，左边测速模块“OUT”接开发板的“3”引脚，右边测速模块“OUT”接开发板的“2”引脚。引脚接错的话可以再随后调试过程中换过来，也可以在代码里更改。  
  最终接线图如下：

![SouthEast 6][]

## 测速模块讲解 ##

测速模块的工作原理比较简单，如下图所示，在于电机同轴的码盘上有很多开孔（光栅），编码器相当于光敏元件。码盘随着小车轮子的运动转动时，码盘（光栅）会不断遮挡光敏元件发出的光波，这时候编码器就会根据光栅的遮挡不断的产生方波信号，方波信号会从“OUT”引脚输出，我们只需不断检测“OUT”引脚的输出，根据方波信号的周期简介计算出小车运行的速度。小车上使用的码盘（光栅）精度不高，在某些高精度的编码器上光栅会更加密集，测量效果会更好。

![SouthEast 7][]   由于要不断检测编码器输出端的输出，因此我们需要借助Arduino的外部中断来读取编码器的输出。Arduino开发板外部中断对应的引脚如下：

<table> 
 <thead> 
  <tr> 
   <th align="center">型号</th> 
   <th align="center">int0</th> 
   <th align="center">int1</th> 
   <th align="center">int2</th> 
   <th align="center">int3</th> 
   <th align="right">int4</th> 
   <th align="right">int5</th> 
  </tr> 
 </thead> 
 <tbody> 
  <tr> 
   <td align="center">UNO\Ethernet</td> 
   <td align="center">2</td> 
   <td align="center">3</td> 
   <td align="center"></td> 
   <td align="center"></td> 
   <td align="right"></td> 
   <td align="right"></td> 
  </tr> 
  <tr> 
   <td align="center">Mega2560</td> 
   <td align="center">2</td> 
   <td align="center">3</td> 
   <td align="center">21</td> 
   <td align="center">20</td> 
   <td align="right">19</td> 
   <td align="right">18</td> 
  </tr> 
  <tr> 
   <td align="center">Leonardo</td> 
   <td align="center">3</td> 
   <td align="center">2</td> 
   <td align="center">0</td> 
   <td align="center">1</td> 
   <td align="right"></td> 
   <td align="right"></td> 
  </tr> 
  <tr> 
   <td align="center">Due</td> 
   <td align="center">All</td> 
   <td align="center">All</td> 
   <td align="center">All</td> 
   <td align="center">All</td> 
   <td align="right">All</td> 
   <td align="right">All</td> 
  </tr> 
 </tbody> 
</table>

由表中可以知道在此我们使用的Arduino UNO只有“2”，“3”引脚可以触发外部中断，因此在接线的时候我们便将左右两边的输出“OUT”引脚分别接在“2”“3”引脚上。  
  在程序初始化阶段中调用函数`attachInterrupt(interrupt, function, mode)`可以对中断引脚初始化，其中  
**interrupt：** 要初始化的外部中断编号，由上表可知我们Arduino UNO只能使用外部中断0和外部中断1；  
**function：** 中断服务函数的名字，即当外部中断被触发时，将会自动调用这个函数；  
**mode：** 中断触发的方式，可选方式如下

<table> 
 <thead> 
  <tr> 
   <th align="left">mode</th> 
   <th align="left">含义</th> 
  </tr> 
 </thead> 
 <tbody> 
  <tr> 
   <td align="left">LOW</td> 
   <td align="left">低电平触发</td> 
  </tr> 
  <tr> 
   <td align="left">CHANGE</td> 
   <td align="left">电平变化，高电平变低电平、低电平变高电平</td> 
  </tr> 
  <tr> 
   <td align="left">RISING</td> 
   <td align="left">上升沿触发</td> 
  </tr> 
  <tr> 
   <td align="left">FALLING</td> 
   <td align="left">下降沿触发</td> 
  </tr> 
  <tr> 
   <td align="left">HIGH</td> 
   <td align="left">高电平触发(该中断模式仅适用于Arduino due)</td> 
  </tr> 
 </tbody> 
</table>

## 测试代码如下 ##

int leftCounter=0,  rightCounter=0;
    unsigned long time = 0, old_time = 0; // 时间标记
    unsigned long time1 = 0; // 时间标记
    float lv,rv;//左、右轮速度
    
    #define STOP 0
    #define FORWARD 1
    #define BACKWARD 2
    #define TURNLEFT 3
    #define TURNRIGHT 4
    
    int leftMotor1 = 4;
    int leftMotor2 = 5;
    int rightMotor1 = 6;
    int rightMotor2 = 7;
    
    void setup() { 
      // put your setup code here, to run once:
      Serial.begin(9600); 
      attachInterrupt(0,RightCount_CallBack, FALLING);
      attachInterrupt(1,LeftCount_CallBack, FALLING);
    
      pinMode(leftMotor1, OUTPUT);
      pinMode(leftMotor2, OUTPUT);
      pinMode(rightMotor1, OUTPUT);
      pinMode(rightMotor2, OUTPUT);
    }
    
    void loop() { 
      // put your main code here, to run repeatedly:
      SpeedDetection();
      if(Serial.available()>0)
      { 
        char cmd = Serial.read();
      
        Serial.print(cmd);
        motorRun(cmd);
          
      }  
    }
    /* * *速度计算 */
    bool SpeedDetection()
    { 
      time = millis();//以毫秒为单位，计算当前时间 
      if(abs(time - old_time) >= 1000) // 如果计时时间已达1秒
      {   
        detachInterrupt(0); // 关闭外部中断0
        detachInterrupt(1); // 关闭外部中断1
        //把每一秒钟编码器码盘计得的脉冲数，换算为当前转速值
        //转速单位是每分钟多少转，即r/min。这个编码器码盘为20个空洞。
        lv =(float)leftCounter*60/20;//小车车轮电机转速
        rv =(float)rightCounter*60/20;//小车车轮电机转速
        Serial.print("left:");
        Serial.print(lv);//向上位计算机上传左车轮电机当前转速的高、低字节
        Serial.print(" right:");
        Serial.println(rv);//向上位计算机上传左车轮电机当前转速的高、低字节
        //恢复到编码器测速的初始状态
        leftCounter = 0;   //把脉冲计数值清零，以便计算下一秒的脉冲计数
        rightCounter = 0;
        old_time=  millis();     // 记录每秒测速时的时间节点 
        attachInterrupt(0, RightCount_CallBack,FALLING); // 重新开放外部中断0
        attachInterrupt(1, LeftCount_CallBack,FALLING); // 重新开放外部中断0
        return 1;
      }
      else
        return 0;
    }
    /* * *右轮编码器中断服务函数 */
    void RightCount_CallBack()
    { 
      rightCounter++;
    }
    /* * *左轮编码器中断服务函数 */
    void LeftCount_CallBack()
    { 
      leftCounter++;
    }
    /* * *小车运动控制函数 */
    void motorRun(int cmd)
    { 
      switch(cmd){ 
        case FORWARD:
          Serial.println("FORWARD"); //输出状态
          digitalWrite(leftMotor1, HIGH);
          digitalWrite(leftMotor2, LOW);
          digitalWrite(rightMotor1, HIGH);
          digitalWrite(rightMotor2, LOW);
          break;
         case BACKWARD:
          Serial.println("BACKWARD"); //输出状态
          digitalWrite(leftMotor1, LOW);
          digitalWrite(leftMotor2, HIGH);
          digitalWrite(rightMotor1, LOW);
          digitalWrite(rightMotor2, HIGH);
          break;
         case TURNLEFT:
          Serial.println("TURN LEFT"); //输出状态
          digitalWrite(leftMotor1, HIGH);
          digitalWrite(leftMotor2, LOW);
          digitalWrite(rightMotor1, LOW);
          digitalWrite(rightMotor2, HIGH);
          break;
         case TURNRIGHT:
          Serial.println("TURN RIGHT"); //输出状态
          digitalWrite(leftMotor1, LOW);
          digitalWrite(leftMotor2, HIGH);
          digitalWrite(rightMotor1, HIGH);
          digitalWrite(rightMotor2, LOW);
          break;
         default:
          Serial.println("STOP"); //输出状态
          digitalWrite(leftMotor1, LOW);
          digitalWrite(leftMotor2, LOW);
          digitalWrite(rightMotor1, LOW);
          digitalWrite(rightMotor2, LOW);
      }
    }

看了这个代码大家应该就明白为什么之前我建议大家将每个功能都封装成函数了，封装成函数很利于程序的移植。

## 测速效果 ##

借助于蓝牙串口助手我们可以清楚的看到小车左右轮的转速如图，由于电机自身的误差和摩擦力的作用，因此两个轮子的转速不相等，但是差别不是很大。

![SouthEast 8][]

**欢迎各位有兴趣的朋友加入Q群1：789127261点评、交流**

[Link 1]: https://blog.csdn.net/qq_16775293/article/details/77427060
[Link 2]: https://blog.csdn.net/qq_16775293/article/details/77438499
[Link 3]: https://blog.csdn.net/qq_16775293/article/details/77744682
[Link 4]: https://blog.csdn.net/qq_16775293/article/details/77777988
[Link 5]: https://blog.csdn.net/qq_16775293/article/details/77489166
[Link 6]: https://blog.csdn.net/qq_16775293/article/details/77836020
[Link 7]: https://blog.csdn.net/qq_16775293/article/details/77688784
[SouthEast]: https://img-blog.csdn.net/20170829215736496?watermark/2/text/aHR0cDovL2Jsb2cuY3Nkbi5uZXQvcXFfMTY3NzUyOTM=/font/5a6L5L2T/fontsize/400/fill/I0JBQkFCMA==/dissolve/70/gravity/SouthEast
[SouthEast 1]: /images/20220609/95dab27de6334495b17941de7b8b000c.png
[SouthEast 2]: /images/20220609/72dc49ae8a1b4455afc51c9985524e7c.png
[SouthEast 3]: /images/20220609/4d6f9c0ade594a8bb4b140f0037b35fa.png
[SouthEast 4]: /images/20220609/ce33817bf6a24d32905260d61b5f64a8.png
[SouthEast 5]: /images/20220609/2587c1cfb6e4444c8d3ceb0b921e1a13.png
[SouthEast 6]: /images/20220609/07ea30a3789946e4852b37e5556c7455.png
[SouthEast 7]: /images/20220609/fa97d6375824410eade1b12748441b72.png
[SouthEast 8]: /images/20220609/14679e52088a4ccf9958880984e48398.png