C语言函数调用过程的汇编分析

「爱情、让人受尽委屈。」 2022-04-11 14:53 329阅读 0赞

转自： [http://www.cnblogs.com/xiaojianliu/articles/8733560.html][http_www.cnblogs.com_xiaojianliu_articles_8733560.html]

下面一段C程序：

![复制代码][copycode.gif]

int bar(int c, int d)
    {
    int e = c + d;
    return e;
    }
    
    int foo(int a, int b)
    {
    return bar(a, b);
    }
    
    int main(void)
    {
    foo(2, 3);
    return 0;
    }

![复制代码][copycode.gif]

如果在编译时加上-g选项，那么用objdump反汇编时可以把C代码和汇编代码穿插起来显示，这样C代码和汇编代码的对应关系看得更清楚。反汇编的结果很长，以下只列出我们关心的部分。

![复制代码][copycode.gif]

$ gcc main.c -g
    $ objdump -dS a.out
    ...
    08048394 <bar>:
    int bar(int c, int d)
    {
    8048394: 55 push %ebp
    8048395: 89 e5 mov %esp,%ebp
    8048397: 83 ec 10 sub $0x10,%esp
    int e = c + d;
    804839a: 8b 55 0c mov 0xc(%ebp),%edx
    804839d: 8b 45 08 mov 0x8(%ebp),%eax
    80483a0: 01 d0 add %edx,%eax
    80483a2: 89 45 fc mov %eax,-0x4(%ebp)
    return e;
    80483a5: 8b 45 fc mov -0x4(%ebp),%eax
    }
    
    80483a8: c9 leave
    80483a9: c3 ret
    080483aa <foo>:
    294int foo(int a, int b)
    {
    80483aa: 55 push %ebp
    80483ab: 89 e5 mov %esp,%ebp
    80483ad: 83 ec 08 sub $0x8,%esp
    return bar(a, b);
    80483b0: 8b 45 0c mov 0xc(%ebp),%eax
    80483b3: 89 44 24 04 mov %eax,0x4(%esp)
    80483b7: 8b 45 08 mov 0x8(%ebp),%eax
    80483ba: 89 04 24 mov %eax,(%esp)
    80483bd: e8 d2 ff ff ff call 8048394 <bar>
    }
    
    80483c2: c9 leave
    80483c3: c3 ret
    080483c4 <main>:
    int main(void)
    {
    80483c4: 8d 4c 24 04 lea 0x4(%esp),%ecx
    80483c8: 83 e4 f0 and $0xfffffff0,%esp
    80483cb: ff 71 fc pushl -0x4(%ecx)
    80483ce: 55 push %ebp
    80483cf: 89 e5 mov %esp,%ebp
    80483d1: 51 push %ecx
    80483d2: 83 ec 08 sub $0x8,%esp
    foo(2, 3);
    80483d5: c7 44 24 04 03 00 00 movl $0x3,0x4(%esp)
    80483dc: 00
    80483dd: c7 04 24 02 00 00 00 movl $0x2,(%esp)
    80483e4: e8 c1 ff ff ff call 80483aa <foo>
    return 0;
    80483e9: b8 00 00 00 00 mov $0x0,%eax
    }
    
    80483ee: 83 c4 08 add $0x8,%esp
    80483f1: 59 pop %ecx
    80483f2: 5d pop %ebp
    80483f3: 8d 61 fc lea -0x4(%ecx),%esp
    80483f6: c3 ret
    ...

![复制代码][copycode.gif]

要查看编译后的汇编代码，其实还有一种办法是gcc -S main.c，这样只生成汇编代码main.s，而不生成二进制的目标文件。

disassemble可以反汇编当前函数或者指定的函数，单独用disassemble命令是反汇编当前函数，如果disassemble命令后面跟函数名或地址则反汇编指定的函数。

在执行程序时，操作系统为进程分配一块栈空间来保存函数栈帧， esp寄存器总是指向栈顶，在x86平台上这个栈是从高地址向低地址增长的，我们知道每次调用一个函数都要分配一个栈帧来保存参数和局部变量，现在我们详细分析这些数据在栈空间的布局：

![1150378-20180326082957852-2093183031.png][]

图中每个小方格表示4个字节的内存单元，例如b: 3这个小方格占的内存地址是0xbff1c420~0xbff1c423。

从main函数的这里开始看起：

![复制代码][copycode.gif]

foo(2, 3);
    80483d5: c7 44 24 04 03 00 00 movl $0x3,0x4(%esp)
    80483dc: 00
    80483dd: c7 04 24 02 00 00 00 movl $0x2,(%esp)
    80483e4: e8 c1 ff ff ff call 80483aa <foo>
    return 0;
    80483e9: b8 00 00 00 00 mov $0x0,%eax

![复制代码][copycode.gif]

要调用函数foo先要把参数准备好，第二个参数保存在esp+4指向的内存位置，第一个参数保存在esp指向的内存位置，可见参数是从右向左依次压栈的。然后执行call指令，这个指令有两个作用：

1. foo函数调用完之后要返回到call的下一条指令继续执行，所以把call的下一条指令的地

址0x80483e9压栈，同时把esp的值减4，esp的值现在是0xbff1c418。

2. 修改程序计数器eip，跳转到foo函数的开头执行。

现在看foo函数的汇编代码：

int foo(int a, int b)
    {
    80483aa: 55 push %ebp
    80483ab: 89 e5 mov %esp,%ebp
    80483ad: 83 ec 08 sub $0x8,%esp

push %ebp指令把ebp寄存器的值压栈，同时把esp的值减4。 esp的值现在是0xbff1c414，下一条指令把这个值传送给ebp寄存器。这两条指令合起来是把原来ebp的值保存在栈上，然后又给ebp赋了新值。在每个函数的栈帧中， ebp指向栈底，而esp指向栈顶，在函数执行过程中esp随着压栈和出栈操作随时变化，而ebp是不动的，函数的参数和局部变量都是通过ebp的值加上一个偏移量来访问，例如foo函数的参数a和b分别通过ebp+8和ebp+12来访问。所以下面的指令把参数a和b再次压

栈，为调用bar函数做准备，然后把返回地址压栈，调用bar函数：

![复制代码][copycode.gif]

return bar(a, b);
    80483b0: 8b 45 0c mov 0xc(%ebp),%eax
    80483b3: 89 44 24 04 mov %eax,0x4(%esp)
    80483b7: 8b 45 08 mov 0x8(%ebp),%eax
    80483ba: 89 04 24 mov %eax,(%esp)
    80483bd: e8 d2 ff ff ff call 8048394 <bar>

![复制代码][copycode.gif]

现在看bar函数的指令：

![复制代码][copycode.gif]

int bar(int c, int d)
    {
    8048394: 55 push %ebp
    8048395: 89 e5 mov %esp,%ebp
    8048397: 83 ec 10 sub $0x10,%esp
    int e = c + d;
    804839a: 8b 55 0c mov 0xc(%ebp),%edx
    804839d: 8b 45 08 mov 0x8(%ebp),%eax
    80483a0: 01 d0 add %edx,%eax
    80483a2: 89 45 fc mov %eax,-0x4(%ebp)

![复制代码][copycode.gif]

这次又把foo函数的ebp压栈保存，然后给ebp赋了新值，指向bar函数栈帧的栈底，通过ebp+8和ebp+12分别可以访问参数c和d。 bar函数还有一个局部变量e，可以通过ebp-4来访问。所以后面几条指令的意思是把参数c和d取出来存在寄存器中做加法，计算结果保存在eax寄存器中，再把eax寄存器存回局部变量e的内存单元。

在gdb中可以用bt命令和frame命令查看每层栈帧上的参数和局部变量，现在可以解释它的工作原理了：如果我当前在bar函数中，我可以通过ebp找到bar函数的参数和局部变量，也可以找到foo函数的ebp保存在栈上的值，有了foo函数的ebp，又可以找到它的参数和局部变量，也可以找到main函数的ebp保存在栈上的值，因此各层函数栈帧通过保存在栈上的ebp的值串起来了。

现在看bar函数的返回指令：

return e;
    80483a5: 8b 45 fc mov -0x4(%ebp),%eax
    }
    80483a8: c9 leave
    80483a9: c3 ret

bar函数有一个int型的返回值，这个返回值是通过eax寄存器传递的，所以首先把e的值读到eax寄存器中。然后执行leave指令，这个指令是函数开头的push %ebp和mov %esp,%ebp的逆操作：

1. 把ebp的值赋给esp，现在esp的值是0xbff1c404。

2. 现在esp所指向的栈顶保存着foo函数栈帧的ebp，把这个值恢复给ebp，同时esp增加4， esp的值变成0xbff1c408。

最后是ret指令，它是call指令的逆操作：

1. 现在esp所指向的栈顶保存着返回地址，把这个值恢复给eip，同时esp增加4， esp的值变成0xbff1c40c。

2. 修改了程序计数器eip，因此跳转到返回地址0x80483c2继续执行。

地址0x80483c2处是foo函数的返回指令：

80483c2: c9 leave
    80483c3: c3 ret

重复同样的过程，又返回到了main函数。注意函数调用和返回过程中的这些规则：

1. 参数压栈传递，并且是从右向左依次压栈。

2. ebp总是指向当前栈帧的栈底。

3. 返回值通过eax寄存器传递。

这些规则并不是体系结构所强加的， ebp寄存器并不是必须这么用，函数的参数和返回值也不是必须这么传，只是操作系统和编译器选择了以这样的方式实现C代码中的函数调用，这称为Calling Convention， Calling Convention是操作系统二进制接口规范（ABI， Application BinaryInterface）的一部分。

[http_www.cnblogs.com_xiaojianliu_articles_8733560.html]: http://www.cnblogs.com/xiaojianliu/articles/8733560.html
[copycode.gif]: /images/20220411/d94053ea2da34dbe95458030e003c8e9.png
[1150378-20180326082957852-2093183031.png]: /images/20220411/f067bc854d084a1ea4af3b281bb3adb6.png