Arduino SSD1306 OLED显示

╰+哭是因爲堅強的太久メ 2022-04-11 13:59 472阅读 0赞

## 本教程的硬件环境为： ##

**Arduino UNO**  
**0.96寸 OLED-128X64 SPI 接口**

U8glib库链接：链接：[https://pan.baidu.com/s/1KpoHd4kXtMAzbrmMjHM7aw][https_pan.baidu.com_s_1KpoHd4kXtMAzbrmMjHM7aw] 密码：5ffl  
取模软件：链接：[https://pan.baidu.com/s/1vWB0sEvODR9X5cWlBBQArg][https_pan.baidu.com_s_1vWB0sEvODR9X5cWlBBQArg] 密码：sepr

## U8glib库函数介绍 ##

函数：  
> firstPage 图像显示  
> nextPage  
> drawPixe 点  
> drawLine 线  
> drawHLine 水平线  
> drawVLine 垂直线  
> drawTriangle 三角(实心)  
> drawFrame 矩形框  
> drawRFrame 圆角矩形框  
> drawBox 矩形(实心)  
> drawRBox 圆角矩形(实心)  
> drawCircle 圆  
> drawDisc 圆形(实心)  
> drawEllipse 圆弧  
> drawFilledEllipse 扇形(实心)  
> drawStr 显示字符串  
> print 输出  
> drawBitmapP 画位图  
> drawXMBP 画大尺寸位图  
> getHeight 获得显示器高度  
> getWidth 获得显示器宽度  
> getStrWidth 获得字符串宽度  
> setFont 设置字体  
> setPrintPos 设置输出位置  
> setColorIndex 设置显示与否  
> setRot90 /180 /270 显示内容旋转  
> setFontPosTop

**接线**

<table> 
 <thead> 
  <tr> 
   <th>OLED屏</th> 
   <th>arduino开发板</th> 
  </tr> 
 </thead> 
 <tbody> 
  <tr> 
   <td>GND</td> 
   <td>GND</td> 
  </tr> 
  <tr> 
   <td>VCC</td> 
   <td>3.3V 或 5V</td> 
  </tr> 
  <tr> 
   <td>SCL / D0</td> 
   <td>10</td> 
  </tr> 
  <tr> 
   <td>GND</td> 
   <td>GND</td> 
  </tr> 
  <tr> 
   <td>SDA / D1</td> 
   <td>9</td> 
  </tr> 
  <tr> 
   <td>RES</td> 
   <td>13</td> 
  </tr> 
  <tr> 
   <td>DC</td> 
   <td>11</td> 
  </tr> 
  <tr> 
   <td>CS</td> 
   <td>12 七针模块有cs脚；直接连接就好了；如果是用六针的CS默认已经接地；不接就可以了</td> 
  </tr> 
 </tbody> 
</table>

案例程序一（显示字符）：

#include "stdio.h"
    #include "stdlib.h"
    #include "U8glib.h"
    
    //U8GLIB_SH1106_128X64 u8g(U8G_I2C_OPT_NONE);        // I2C / TWI 
    U8GLIB_SSD1306_128X64 u8g(10, 9, 12, 11);  // SW SPI Com: SCL = 10, SDA = 9, CS = 12, DC = 11,RES=RESET
    
    void draw(void) {
      u8g.setFont(u8g_font_osb18);//设置要显示字符的字体
      u8g.drawStr(0, 20, "123");//显示字符ABC
      u8g.setColorIndex(1);//显示对象为不透明
    }
    
    void setup(void) {
    
    }
    
    void loop(void) {
    
      u8g.firstPage();  
      do {
        draw();
      } while( u8g.nextPage() );
    
    }

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70]

案例程序二（显示汉字）：  
下载取模软件后打开  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 1]

设置好选项  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 2]

输入汉字，选择字体和大小，点击生成字模，拷贝到程序即可  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 3]

#include "stdio.h"
    #include "stdlib.h"
    #include "U8glib.h"
    
    //U8GLIB_SH1106_128X64 u8g(U8G_I2C_OPT_NONE);        // I2C / TWI 
    U8GLIB_SSD1306_128X64 u8g(10, 9, 12, 11);  // SW SPI Com: SCL = 10, SDA = 9, CS = 12, DC = 11,RES=RESET
    
    static const unsigned char wendu[2][32] PROGMEM={
    {0x00,0x00,0xC4,0x1F,0x48,0x10,0x48,0x10,0xC1,0x1F,0x42,0x10,0x42,0x10,0xC8,0x1F,
    0x08,0x00,0xE4,0x3F,0x27,0x25,0x24,0x25,0x24,0x25,0x24,0x25,0xF4,0x7F,0x00,0x00},/*"温",0*/
    /* (16 X 16 , 宋体 )*/
    
    {0x80,0x00,0x00,0x01,0xFC,0x7F,0x44,0x04,0x44,0x04,0xFC,0x3F,0x44,0x04,0x44,0x04,
    0xC4,0x07,0x04,0x00,0xF4,0x0F,0x24,0x08,0x42,0x04,0x82,0x03,0x61,0x0C,0x1C,0x70},/*"度",1*/
    /* (16 X 16 , 宋体 )*/
    };
    void draw(void) {
    //画出温度16*16
     u8g.drawXBMP( 0, 0,16, 16, wendu[0]);
     u8g.drawXBMP( 16, 0,16, 16, wendu[1]);
     u8g.drawXBMP( 0, 16,16, 16, wendu[0]);
     u8g.drawXBMP( 16, 16,16, 16, wendu[1]);
    }
    
    void setup(void) {
    
    }
    
    void loop(void) {
    
      u8g.firstPage();  
      do {
        draw();
      } while( u8g.nextPage() );
    
    }

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 4]

案例程序三（画图，动态）：

/*********************************************************************
    This is an example for our Monochrome OLEDs based on SSD1306 drivers
    
      Pick one up today in the adafruit shop!
      ------> http://www.adafruit.com/category/63_98
    
    This example is for a 128x64 size display using SPI to communicate
    4 or 5 pins are required to interface
    
    Adafruit invests time and resources providing this open source code, 
    please support Adafruit and open-source hardware by purchasing 
    products from Adafruit!
    
    Written by Limor Fried/Ladyada  for Adafruit Industries.  
    BSD license, check license.txt for more information
    All text above, and the splash screen must be included in any redistribution
    *********************************************************************/
    
    #include <Wire.h>
    #include <Adafruit_GFX.h>
    #include <Adafruit_SSD1306.h>
    
    #define OLED_DC 11
    #define OLED_CS 12
    #define OLED_CLK 10
    #define OLED_MOSI 9
    #define OLED_RESET 13
    Adafruit_SSD1306 display(OLED_MOSI, OLED_CLK, OLED_DC, OLED_RESET, OLED_CS);
    
    #define NUMFLAKES 10
    #define XPOS 0
    #define YPOS 1
    #define DELTAY 2
    
    #define LOGO16_GLCD_HEIGHT 16 
    #define LOGO16_GLCD_WIDTH  16 
    const static unsigned char PROGMEM logo16_glcd_bmp[] =
    { B00000000, B11000000,
      B00000001, B11000000,
      B00000001, B11000000,
      B00000011, B11100000,
      B11110011, B11100000,
      B11111110, B11111000,
      B01111110, B11111111,
      B00110011, B10011111,
      B00011111, B11111100,
      B00001101, B01110000,
      B00011011, B10100000,
      B00111111, B11100000,
      B00111111, B11110000,
      B01111100, B11110000,
      B01110000, B01110000,
      B00000000, B00110000 };
    
    #if (SSD1306_LCDHEIGHT != 64)
    #error("Height incorrect, please fix Adafruit_SSD1306.h!");
    #endif
    
    void setup()   {                
      Serial.begin(9600);
      
      // by default, we'll generate the high voltage from the 3.3v line internally! (neat!)
      display.begin(SSD1306_SWITCHCAPVCC);
      // init done
      
      display.display(); // show splashscreen
      delay(2000);
      display.clearDisplay();   // clears the screen and buffer
    
      // draw a single pixel
      display.drawPixel(10, 10, WHITE);
      display.display();
      delay(2000);
      display.clearDisplay();
    
      // draw many lines
      testdrawline();
      display.display();
      delay(2000);
      display.clearDisplay();
    
      // draw rectangles
      testdrawrect();
      display.display();
      delay(2000);
      display.clearDisplay();
    
      // draw multiple rectangles
      testfillrect();
      display.display();
      delay(2000);
      display.clearDisplay();
    
      // draw mulitple circles
      testdrawcircle();
      display.display();
      delay(2000);
      display.clearDisplay();
    
      // draw a white circle, 10 pixel radius
      display.fillCircle(display.width()/2, display.height()/2, 10, WHITE);
      display.display();
      delay(2000);
      display.clearDisplay();
    
      testdrawroundrect();
      delay(2000);
      display.clearDisplay();
    
      testfillroundrect();
      delay(2000);
      display.clearDisplay();
    
      testdrawtriangle();
      delay(2000);
      display.clearDisplay();
       
      testfilltriangle();
      delay(2000);
      display.clearDisplay();
    
      // draw the first ~12 characters in the font
      testdrawchar();
      display.display();
      delay(2000);
      display.clearDisplay();
    
      // draw scrolling text
      testscrolltext();
      delay(2000);
      display.clearDisplay();
      
      // text display tests
      display.setTextSize(1);
      display.setTextColor(WHITE);
      display.setCursor(0,0);
      display.println("Hello, world!");
      display.setTextColor(BLACK, WHITE); // 'inverted' text
      display.println(3.141592);
      display.setTextSize(2);
      display.setTextColor(WHITE);
      display.print("0x"); display.println(0xDEADBEEF, HEX);
      display.display();
      delay(2000);
    
      // miniature bitmap display
      display.clearDisplay();
      display.drawBitmap(30, 16,  logo16_glcd_bmp, 16, 16, 1);
      display.display();
    
      // invert the display
      display.invertDisplay(true);
      delay(1000); 
      display.invertDisplay(false);
      delay(1000); 
    
      // draw a bitmap icon and 'animate' movement
      testdrawbitmap(logo16_glcd_bmp, LOGO16_GLCD_HEIGHT, LOGO16_GLCD_WIDTH);
    }
    
    
    void loop() {
      
    }
    
    
    void testdrawbitmap(const uint8_t *bitmap, uint8_t w, uint8_t h) {
      uint8_t icons[NUMFLAKES][3];
      srandom(666);     // whatever seed
     
      // initialize
      for (uint8_t f=0; f< NUMFLAKES; f++) {
        icons[f][XPOS] = random() % display.width();
        icons[f][YPOS] = 0;
        icons[f][DELTAY] = random() % 5 + 1;
        
        Serial.print("x: ");
        Serial.print(icons[f][XPOS], DEC);
        Serial.print(" y: ");
        Serial.print(icons[f][YPOS], DEC);
        Serial.print(" dy: ");
        Serial.println(icons[f][DELTAY], DEC);
      }
    
      while (1) {
        // draw each icon
        for (uint8_t f=0; f< NUMFLAKES; f++) {
          display.drawBitmap(icons[f][XPOS], icons[f][YPOS], logo16_glcd_bmp, w, h, WHITE);
        }
        display.display();
        delay(200);
        
        // then erase it + move it
        for (uint8_t f=0; f< NUMFLAKES; f++) {
          display.drawBitmap(icons[f][XPOS], icons[f][YPOS],  logo16_glcd_bmp, w, h, BLACK);
          // move it
          icons[f][YPOS] += icons[f][DELTAY];
          // if its gone, reinit
          if (icons[f][YPOS] > display.height()) {
    	icons[f][XPOS] = random() % display.width();
    	icons[f][YPOS] = 0;
    	icons[f][DELTAY] = random() % 5 + 1;
          }
        }
       }
    }
    
    
    void testdrawchar(void) {
      display.setTextSize(1);
      display.setTextColor(WHITE);
      display.setCursor(0,0);
    
      for (uint8_t i=0; i < 168; i++) {
        if (i == '\n') continue;
        display.write(i);
        if ((i > 0) && (i % 21 == 0))
          display.println();
      }    
      display.display();
    }
    
    void testdrawcircle(void) {
      for (int16_t i=0; i<display.height(); i+=2) {
        display.drawCircle(display.width()/2, display.height()/2, i, WHITE);
        display.display();
      }
    }
    
    void testfillrect(void) {
      uint8_t color = 1;
      for (int16_t i=0; i<display.height()/2; i+=3) {
        // alternate colors
        display.fillRect(i, i, display.width()-i*2, display.height()-i*2, color%2);
        display.display();
        color++;
      }
    }
    
    void testdrawtriangle(void) {
      for (int16_t i=0; i<min(display.width(),display.height())/2; i+=5) {
        display.drawTriangle(display.width()/2, display.height()/2-i,
                         display.width()/2-i, display.height()/2+i,
                         display.width()/2+i, display.height()/2+i, WHITE);
        display.display();
      }
    }
    
    void testfilltriangle(void) {
      uint8_t color = WHITE;
      for (int16_t i=min(display.width(),display.height())/2; i>0; i-=5) {
        display.fillTriangle(display.width()/2, display.height()/2-i,
                         display.width()/2-i, display.height()/2+i,
                         display.width()/2+i, display.height()/2+i, WHITE);
        if (color == WHITE) color = BLACK;
        else color = WHITE;
        display.display();
      }
    }
    
    void testdrawroundrect(void) {
      for (int16_t i=0; i<display.height()/2-2; i+=2) {
        display.drawRoundRect(i, i, display.width()-2*i, display.height()-2*i, display.height()/4, WHITE);
        display.display();
      }
    }
    
    void testfillroundrect(void) {
      uint8_t color = WHITE;
      for (int16_t i=0; i<display.height()/2-2; i+=2) {
        display.fillRoundRect(i, i, display.width()-2*i, display.height()-2*i, display.height()/4, color);
        if (color == WHITE) color = BLACK;
        else color = WHITE;
        display.display();
      }
    }
       
    void testdrawrect(void) {
      for (int16_t i=0; i<display.height()/2; i+=2) {
        display.drawRect(i, i, display.width()-2*i, display.height()-2*i, WHITE);
        display.display();
      }
    }
    
    void testdrawline() {  
      for (int16_t i=0; i<display.width(); i+=4) {
        display.drawLine(0, 0, i, display.height()-1, WHITE);
        display.display();
      }
      for (int16_t i=0; i<display.height(); i+=4) {
        display.drawLine(0, 0, display.width()-1, i, WHITE);
        display.display();
      }
      delay(250);
      
      display.clearDisplay();
      for (int16_t i=0; i<display.width(); i+=4) {
        display.drawLine(0, display.height()-1, i, 0, WHITE);
        display.display();
      }
      for (int16_t i=display.height()-1; i>=0; i-=4) {
        display.drawLine(0, display.height()-1, display.width()-1, i, WHITE);
        display.display();
      }
      delay(250);
      
      display.clearDisplay();
      for (int16_t i=display.width()-1; i>=0; i-=4) {
        display.drawLine(display.width()-1, display.height()-1, i, 0, WHITE);
        display.display();
      }
      for (int16_t i=display.height()-1; i>=0; i-=4) {
        display.drawLine(display.width()-1, display.height()-1, 0, i, WHITE);
        display.display();
      }
      delay(250);
    
      display.clearDisplay();
      for (int16_t i=0; i<display.height(); i+=4) {
        display.drawLine(display.width()-1, 0, 0, i, WHITE);
        display.display();
      }
      for (int16_t i=0; i<display.width(); i+=4) {
        display.drawLine(display.width()-1, 0, i, display.height()-1, WHITE); 
        display.display();
      }
      delay(250);
    }
    
    void testscrolltext(void) {
      display.setTextSize(2);
      display.setTextColor(WHITE);
      display.setCursor(10,0);
      display.clearDisplay();
      display.println("scroll");
      display.display();
     
      display.startscrollright(0x00, 0x0F);
      delay(2000);
      display.stopscroll();
      delay(1000);
      display.startscrollleft(0x00, 0x0F);
      delay(2000);
      display.stopscroll();
      delay(1000);    
      display.startscrolldiagright(0x00, 0x07);
      delay(2000);
      display.startscrolldiagleft(0x00, 0x07);
      delay(2000);
      display.stopscroll();
    }

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 5]

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 6]  
视频链接：[https://v.youku.com/v\_show/id\_XMzk1MjQyODkwNA==.html?spm=a2hzp.8244740.0.0][https_v.youku.com_v_show_id_XMzk1MjQyODkwNA_.html_spm_a2hzp.8244740.0.0]

[https_pan.baidu.com_s_1KpoHd4kXtMAzbrmMjHM7aw]: https://pan.baidu.com/s/1KpoHd4kXtMAzbrmMjHM7aw
[https_pan.baidu.com_s_1vWB0sEvODR9X5cWlBBQArg]: https://pan.baidu.com/s/1vWB0sEvODR9X5cWlBBQArg
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70]: /images/20220411/807de76364644ece88ba7864643cf89c.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 1]: /images/20220411/f52d0a18ccd94a9db14c2d1efc1cbe83.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 2]: /images/20220411/30e1606531484f9d8b27cba408b30195.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 3]: /images/20220411/7673897842d546569e690822ebaded1f.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 4]: /images/20220411/eae0e4fd6f664b0eb4ede31cae131e02.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 5]: /images/20220411/f2e60890c6144a87a0779ca5b1a81d49.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L20wXzM3NzM4ODM4_size_16_color_FFFFFF_t_70 6]: /images/20220411/0f8f25acc44d4a26b1cdcb678e4be060.png
[https_v.youku.com_v_show_id_XMzk1MjQyODkwNA_.html_spm_a2hzp.8244740.0.0]: https://v.youku.com/v_show/id_XMzk1MjQyODkwNA==.html?spm=a2hzp.8244740.0.0