ARM 软中断指令SWI

r囧r小猫 2022-04-01 08:14 607阅读 0赞

出处：[https://blog.csdn.net/zqixiao\_09/article/details/50776191][https_blog.csdn.net_zqixiao_09_article_details_50776191]

前面我们学习ARM工作模式中，处理器模式切换可以通过软件控制进行切换，即修改CPSR模式位，但这是在特权模式下，当我们处于用户模式下，是没有权限实现模式转换的。若想实现模式切换，只能由另一种方法来实现，即通过外部中断或是异常处理过程进行切换。于是ARM指令集中提供了两条产生异常的指令，通过这两条指令可以用软件的方法实现异常，其中一个就是中断指令SWI 。

一、软件中断

软中断是利用硬件中断的概念，用软件方式进行模拟，实现从用户模式切换到特权模式并执行特权程序的机制。

硬件中断是由电平的物理特性决定，在电平变化时引发中断操作，而软中断是通过一条具体指令SWI，引发中断操作，也就是说用户程序里可以通过写入SWI指令来切换到特权模式，当CPU执行到SWI指令时会从用户模式切换到管理模式下，执行软件中断处理。由于SWI指令由操作系统提供的API封装起来，并且软件中断处理程序也是操作系统编写者提前写好的，因此用户程序调用API时就是将操作权限交给了操作系统，所以用户程序还是不能随意访问硬件。

软件中断指令（Software Interrupt, SWI）用于产生软中断，实现从用户模式变换到管理模式，CPSR保存到管理模式的SPSR中，执行转移到SWI向量。在其他模式下也可以使用SWI指令，处理器同样切换到管理模式。

1、SWI指令格式如下：

SWI\{cond\} immed\_24

其中：

immed\_24 24位立即数，值为从0――16777215之间的整数。

SWI指令后面的24立即数是干什么用的呢？用户程序通过SWI指令切换到特权模式，进入软中断处理程序，但是软中断处理程序不知道用户程序到底想要做什么？SWI指令后面的24位用来做用户程序和软中断处理程序之间的接头暗号。通过该软中断立即数来区分用户不同操作，执行不同内核函数。如果用户程序调用系统调用时传递参数，根据ATPCSC语言与汇编混合编程规则将参数放入R0~R4即可。

2、指令举例

使用SWI指令时，通常使用以下两种方法进行参数传递，SWI异常处理程序可以提供相关的服务，这两种方法均是用户软件协定。SWI异常中断处理程序要通过读取引起软件中断的SWI指令，以取得24为立即数。

1）、指令中24位的立即数指定了用户请求的服务类型，中断服务的参数通过通用寄存器传递。

如下面这个程序产生一个中断号位12 的软中断：

MOV R0,\#34 ；设置功能号为34

SWI 12 ；产生软中断，中断号为12

2）、指令中的24位立即数被忽略，用户请求的服务类型有寄存器R0的值决定，参数通过其他的通用寄存器传递。

如下面的例子通过R0传递中断号，R1传递中断的子功能号：

MOV R0, \#12 ；设置12号软中断

MOV R1, \#34 ；设置功能号为34

SWI 0

下面的例子通过系统调用函数int led\_on(int led\_no)实现点亮第led\_no 个LED灯，由于C语言里没有SWI 指令对应的语句，因此这儿要用到C语言与汇编混合编程，led\_on函数里将参数led\_no的值传递给R0，通过软中断SWI指令切换到软中断管理模式，同时R0 软中断方式点亮LED灯，用户通过SWI \#1指令可以点灯，具体点亮哪个灯，通过R0保存参数传递，如果亮灯成功返回对应LED号。

\#define \_\_led\_on\_swi\_no 1 // 软中断号1，调用管理模式下的do\_led\_on函数  
int led\_on(int led\_no)\{  
  
int ret; // 返回值  
\_\_asm\{ // 由于C程序中没有SWI对应表达式，所以使用混合编程  
mov r0, led\_no // 根据ATPCS规则，r0存放第一个参数  
swi \_\_led\_on\_swi\_no // 产生SWI软中断，中断号为\_\_led\_on\_swi\_no  
  
mov ret, r0 // 软中断处理结束，取得中断处理返回值，传递给ret变量  
\}  
  
return ret; // 将ret返回给调用led\_on的语句  
\}

二、软中断处理

CPU执行到swi xxx执行后，产生软件中断，由异常处理部分知识可知，软中断产生后CPU将强制将PC的值置为异常向量表地址0x08，在异常向量表0x08处安放跳转指令b HandleSWI，这样CPU就跳往我们自己定义的HandleSWI处执行。

1--保护现场

软中断处理中通过STMFD SP!, \{R0-R12, LR\} 要保存程序执行现场，将R0~R12通用寄存器数据保存在管理模式下SP栈内，LR由硬件自动保存软中断指令下一条指令的地址（后面利用LR的地址取得SWI指令编码），该寄存器值也保存在SP栈内，将来处理完毕之后返回；

2--获取SWI指令编码

由SWI指令编码知识可知，SWI指令低24位保存有软中断号，通过LDR R4, \[LR, \#-4\]指令，取得SWI指令编码（LR为硬件自动保存SWI xxx指令的下一条指令地址，LR – 4就是SWI指令地址），将其保存在R4寄存器中。通过BIC R4, R4, \#0xFF000000 指令将SWI指令高8位清除掉，只保留低24位立即数，取得ＳＷＩ指令编码；

3--根据SWI指令做出相应操作

根据24位立即数中的软中断号判断用户程序的请求操作。如果24位立即数为1，表示led\_on系统调用产生的软中断，则在管理模式下调用对应的亮灯操作do\_led\_on。如果24位立即数为2，表示led\_off系统调用产生的软中断，则调用灭灯操作do\_led\_on，根据ATPCS调用规则，R0~R3做为参数传递寄存器，在软中断处理中没有使用这4个寄存器，而是使用R4作为操作寄存器的。

4--返回并恢复现场

执行完系统调用操作之后，返回到swi\_return（在调用对应系统操作时，通过LDREQ LR, =swi\_return设置了返回地址），执行返回处理，通过LDMIA SP!, \{R0-R12, PC\}^ 指令将用户寄存器数据恢复到R0~R12，将进入软中断处理时保存的返回地址LR的值恢复给PC，实现程序返回，同时还恢复了状态寄存器。切换回用户模式下程序中继续执行。

; 异常向量表开始  
; 0x00: 复位Reset异常  
b Reset  
  
  
  
; 0x04: 未定义异常（未处理）  
HandleUndef  
  
b HandleUndef  
  
  
  
; 0x08: 软件中断异常，跳往软件中断处理函数HandleSWI  
  
b HandleSWI  
  
… …  
  
; 省略其它异常向量和对应处理  
… …  
  
;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
  
; 软中断处理  
;\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*\*  
  
IMPORT do\_led\_on  
  
IMPORT do\_led\_off  
  
HandleSWI  
  
STMFD SP!, \{R0-R12, LR\} ; 保存程序执行现场  
LDR R4, \[LR, \#-4\] ; LR - 4 为指令" swi xxx" 的地址，低24位是软件中断号  
BIC R4, R4, \#0xFF000000 ; 取得ARM指令24位立即数  
  
  
CMP R4, \#1 ; 判断24位立即数，如果为1，调用do\_led\_on系统调用  
LDREQ LR, =swi\_return ; 软中断处理返回地址  
LDREQ PC, = do\_led\_on ; 软中断号1对应系统调用处理  
  
  
CMP R4, \#2 ; 判断24位立即数，如果为2，调用do\_led\_off系统调用  
LDREQ LR, =swi\_return ; 软中断处理返回地址  
LDREQ PC, = do\_led\_off ; 软中断号2对应系统调用处理  
  
  
MOVNE R0, \#-1 ; 没有该软中断号对应函数，出错返回-1  
  
swi\_return  
  
LDMIA SP!, \{R0-R12, PC\}^ ; 中断返回, ^表示将spsr的值复制到cpsr

其实讲到这，会产生一个疑问，什么时候需要我们从用户模式切换到管理模式？我们应该记得系统调用，就是用户态向内核态的切换。

三、系统调用

操作系统的主要功能是为应用程序的运行创建良好的环境，保障每个程序都可以最大化利用硬件资源，防止非法程序破坏其它应用程序执行环境，为了达到这个目的，操作系统会将硬件的操作权限交给内核来管理，用户程序不能随意使用硬件，使用硬件（对硬件寄存器进行读写）时要先向操作系统发出请求，操作系统内核帮助用户程序实现其操作，也就是说用户程序不会直接操作硬件，而是提供给用户程序一些具备预定功能的内核函数，通过一组称为系统调用的（system call)的接口呈现给用户，系统调用把应用程序的请求传给内核，调用相应的内核函数完成所需的处理，将处理结果返回给应用程序。

这好比我们去银行取款，用户自己的银行帐户不可能随意操作，必须要有一个安全的操作流程和规范，银行里的布局通常被分成两部分，中间用透明玻璃分隔开，只留一个小窗口，面向用户的是用户服务区，工作人员所在区域为内部业务操作区，取款时，将银行卡或存折通过小窗口交给业务员，并且告诉他要取多少钱，具体取钱的操作你是不会直接接触的，业务员会将银行帐户里减掉取款金额，将现金给你。上述操作流程可以很好保护银行系统，银行系统的操作全部由业务员来实现，用户只能向业务员提出自己的服务请求。银行里的小窗口就类似与操作系统的系统调用接口，是将用户请求传递给内核的接口。

![watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3d1aGVueW91eXV5b3V5dQ_size_16_color_FFFFFF_t_70][]

操作系统里将用户程序运行在用户模式下，并且为其分配可以使用内存空间，其它内存空间不能访问，内核态运行在特权模式下，对系统所有硬件进行统一管理和控制。从前面所学知识可以了解到，用户模式下没有权限进行模式切换，这也就意味着用户程序不可能直接通过切换模式去访问硬件寄存器，如果用户程序试图访问没有权限的硬件，会产生异常。这样用户程序被限制起来，如果用户程序想要使用硬件时怎么办呢？用户程序使用硬件时，必须调用操作系统提供的API接口才可以，而操作系统API接口通过软件中断方式切换到管理模式下，实现从用户模式下进入特权模式。

At91rm9200处理器对应的linux2.4.19内核系统调用对应的软中断定义如下：

\#if defined(\_\_thumb\_\_) //thumb模式  
\#define \_\_syscall(name) \\  
"push \{r7\}\\n\\t" \\  
"mov r7, \#" \_\_sys1(\_\_NR\_\#\#name) "\\n\\t" \\  
"swi 0\\n\\t" \\  
"pop \{r7\}"  
\#else //arm模式  
\#define \_\_syscall(name) "swi\\t" \_\_sys1(\_\_NR\_\#\#name) "\\n\\t"  
\#endif  
  
\#define \_\_sys2(x) \#x  
\#define \_\_sys1(x) \_\_sys2(x)  
\#define \_\_NR\_SYSCALL\_BASE 0x900000 //此为OS\_NUMBER << 20运算值  
\#define \_\_NR\_open (\_\_NR\_SYSCALL\_BASE+ 5) //0x900005

举一个例子来说:open系统调用,库函数最终会调用\_\_syscall(open),宏展开之后为swi \#\_\_NR\_open,即,swi \#0x900005触发中断,中断号0x900005存放在\[lr,\#-4\]地址中,处理器跳转到arch/arm/kernel/entry-common.S中vector\_swi读取\[lr,\#-4\]地址中的中断号,之后查询arch/arm/kernel/entry-common.S中的sys\_call\_table系统调用表,该表内容在arch/arm/kernel/calls.S中定义,\_\_NR\_open在表中对应的顺序号为

\_\_syscall\_start:

.long SYMBOL\_NAME(sys\_open) //第5个  
...  
将sys\_call\_table\[5\]中内容传给pc,系统进入sys\_open函数,处理实质的open动作  
注:用到的一些函数数据所在文件,如下所示  
arch/arm/kernel/calls.S声明了系统调用函数  
include/asm-arm/unistd.h定义了系统调用的调用号规则  
vector\_swi定义在arch/arm/kernel/entry-common.S  
vector\_IRQ定义在arch/arm/kernel/entry-armv.S  
vector\_FIQ定义在arch/arm/kernel/entry-armv.S  
arch/arm/kernel/entry-common.S中对sys\_call\_table进行了定义:  
.type sys\_call\_table, \#object  
ENTRY(sys\_call\_table)  
\#include "calls.S" //将calls.S中的内容顺序链接到这里

源程序：

ENTRY(vector\_swi)  
save\_user\_regs  
zero\_fp  
get\_scno //将\[lr,\#-4\]中的中断号转储到scno(r7)  
arm710\_bug\_check scno, ip  
\#ifdef CONFIG\_ALIGNMENT\_TRAP  
ldr ip, \_\_cr\_alignment  
ldr ip, \[ip\]  
mcr p15, 0, ip, c1, c0 @ update control register  
\#endif  
enable\_irq ip  
  
str r4, \[sp, \#-S\_OFF\]! @ push fifth arg  
  
get\_current\_task tsk  
ldr ip, \[tsk, \#TSK\_PTRACE\] @ check for syscall tracing  
bic scno, scno, \#0xff000000 @ mask off SWI op-code  
//\#define OS\_NUMBER 9\[entry-header.S\]  
//所以对于上面示例中open系统调用号scno=0x900005  
//eor scno,scno,\#0x900000  
//之后scno=0x05  
eor scno, scno, \#OS\_NUMBER << 20 @ check OS number  
//sys\_call\_table项为calls.S的内容  
adr tbl, sys\_call\_table @ load syscall table pointer  
tst ip, \#PT\_TRACESYS @ are we tracing syscalls?  
bne \_\_sys\_trace  
  
adrsvc al, lr, ret\_fast\_syscall @ return address  
cmp scno, \#NR\_syscalls @ check upper syscall limit  
//执行sys\_open函数  
ldrcc pc, \[tbl, scno, lsl \#2\] @ call sys\_\* routine  
add r1, sp, \#S\_OFF  
2: mov why, \#0 @ no longer a real syscall  
cmp scno, \#ARMSWI\_OFFSET  
eor r0, scno, \#OS\_NUMBER << 20 @ put OS number back  
bcs SYMBOL\_NAME(arm\_syscall)  
b SYMBOL\_NAME(sys\_ni\_syscall) @ not private func  
/\*  
\* This is the really slow path. We're going to be doing  
\* context switches, and waiting for our parent to respond.  
\*/  
\_\_sys\_trace:  
add r1, sp, \#S\_OFF  
mov r0, \#0 @ trace entry \[IP = 0\]  
bl SYMBOL\_NAME(syscall\_trace)  
/\*  
//2007-07-01 gliethttp \[entry-header.S\]  
//Like adr, but force SVC mode (if required)  
.macro adrsvc, cond, reg, label  
adr\\cond \\reg, \\label  
.endm  
//对应反汇编:  
//add lr, pc, \#16 ; lr = \_\_sys\_trace\_return  
\*/  
adrsvc al, lr, \_\_sys\_trace\_return @ return address  
add r1, sp, \#S\_R0 + S\_OFF @ pointer to regs  
cmp scno, \#NR\_syscalls @ check upper syscall limit  
ldmccia r1, \{r0 - r3\} @ have to reload r0 - r3  
ldrcc pc, \[tbl, scno, lsl \#2\] @ call sys\_\* routine  
b 2b  
  
\_\_sys\_trace\_return:  
str r0, \[sp, \#S\_R0 + S\_OFF\]! @ save returned r0  
mov r1, sp  
mov r0, \#1 @ trace exit \[IP = 1\]  
bl SYMBOL\_NAME(syscall\_trace)  
b ret\_disable\_irq  
  
.align 5  
\#ifdef CONFIG\_ALIGNMENT\_TRAP  
.type \_\_cr\_alignment, \#object  
\_\_cr\_alignment:  
.word SYMBOL\_NAME(cr\_alignment)  
\#endif  
  
.type sys\_call\_table, \#object  
ENTRY(sys\_call\_table)  
\#include "calls.S"

\---------------------  
作者：zqixiao\_09  
来源：CSDN  
原文：https://blog.csdn.net/zqixiao\_09/article/details/50776191  
版权声明：本文为博主原创文章，转载请附上博文链接！

一、SWI软件中断原理。

在特权模式下，处理器模式切换可以通过软件控制进行切换，即修改 CPSR 的模式位。但在用户模式下，是没有权限通过修改 CPSR 实现模式转换的，除非 通过外部中断或是异常处理过程进行切换。为方便在用户模式下灵活实现模式的 转换， ARM 指令集提供了产生异常的指令，即软件中断指令 SWI 。也就是说用 户程序里可以通过写入 SWI 指令来切换到特权模式，当 CPU 执行到 SWI 指令时会 从用户模式切换到管理模式下，执行软件中断处理。在其他模式下也可以使用 SWI 指令，处理器同样切换到管理模式。

指令格式：  
SWI\{cond\} immed\_24  
其中： immed\_24 为 24 位立即数，值为从 0――16777215 之间的整数。它 用来做用户程序和软中断处理程序之间的接头暗号。通过该软中断立即数来区分 用户不同操作。

指令编码格式：

![20190104083245194.jpg][]

指令举例：  
SWI 1;产生 1 号软中断

指令说明：  
在用户模式下调用 SWI 软中断指令，可使处理器跳转至 SWI 中断向量表所对 应的地址中，继而跳入软中断处理程序

中。在软中断处理程序中，可根据软中断号，实现不同的操作。软中断号的判断方法如下：

LDR R4, \[LR, \#-4\] ； LR 为硬件自动保存 SWI xxx 指令的下一条指令地址  
； LR – 4 就是 SWI 指令地址  
BIC R4, R4, \#0xFF000000 ；将 SWI 指令高 8 位清除掉，只保留低 24 位立  
； 即数，取得ＳＷＩ指令编码，则 R4 即为 SWI  
；指令后的软中断号；

二、代码

<span style="font-size:18px;"> AREA Stack1,DATA,READWRITE  
stack1 DCD 10\*512  
PRESERVE8  
AREA TEST,CODE,READONLY  
CODE32  
ENTRY  
  
b reset  
b \_undefined\_instruction  
b \_software\_interrupt  
b \_prefetch\_abort  
b \_data\_abort  
b \_not\_used  
b \_irq  
b \_fiq  
\_undefined\_instruction  
nop  
\_prefetch\_abort  
nop  
\_data\_abort  
nop  
\_not\_used  
nop  
\_irq  
nop  
\_fiq  
nop  
reset  
mrs r0,cpsr  
bic r0,r0,\#0x1f  
orr r0,r0,\#0xd3  
msr cpsr\_c,r0 ;Enable svc mode of cpu  
init\_stack  
ldr r0,=stack1 ;get stack top pointer\*/  
;svc mode stack  
mov sp,r0  
sub r0,\#128\*4 ;/\*512 byte for irq mode of stack\*/  
;/\*\*\*\*irq mode stack\*\*/  
msr cpsr\_c,\#0xd2  
mov sp,r0  
sub r0,\#128\*4 ;/\*512 byte for irq mode of stack\*/  
;/\*\*\*fiq mode stack\*\*\*/  
msr cpsr\_c,\#0xd1  
mov sp,r0  
sub r0,\#0  
;/\*\*\*abort mode stack\*\*\*/  
msr cpsr\_c,\#0xd7  
mov sp,r0  
sub r0,\#0  
;/\*\*\*undefine mode stack\*\*\*/  
msr cpsr\_c,\#0xdb  
mov sp,r0  
sub r0,\#0  
;/\*\*\* sys mode and usr mode stack \*\*\*/  
msr cpsr\_c,\#0x10  
mov sp,r0 ;/\*1024 byte for user mode of stack\*/  
swi 1  
swi 2  
LOOP  
B LOOP  
\_software\_interrupt  
STMFD SP!, \{R0-R4, LR\} ; 保存程序执行现场  
LDR R4, \[LR, \#-4\] ; LR - 4 为指令" swi xxx" 的地址，低 24 位 是 软件中断号  
BIC R4, R4, \#0xFF000000 ; 取得 ARM 指令 24 位立即数  
CMP R4, \#1  
ADDEQ R5,R5,\#1 ; 判断 24 位立即数，如果为 1，则执行R5+1 操作  
LDREQ PC, =swi\_return ; 软中断处理返回CMP R4, \#2 ; 判断 24 位立即数，如果为 2，则执行 R6+1 操作  
ADDEQ R6,R6,\#1  
LDREQ PC, =swi\_return ; 软中断处理返回地址  
swi\_return  
LDMFD SP!, \{R0-R4, PC\}^ ; 中断返回, ^表示将 spsr 的值复制到 cpsr  
END</span>

PS：  
1. bic  
BIC指令的格式为：  
BIC\{条件\}\{S\} 目的寄存器，操作数1，操作数2  
BIC指令用于清除操作数1的某些位，并把结果放置到目的寄存器中。操作数1应是一个寄存器，  
操作数2可以是一个寄存器、被移位的寄存器、或一个立即数。操作数2为32位的掩码，如果在  
掩码中置了某一位1，则清除这一位。未设置的掩码位保持不变。

bic r0,r0,\#0x1f  
0x1f=11111b  
其含义：清除r0的bit\[4:0\]位。

2，orr  
ORR指令的格式为：  
ORR\{条件\}\{S\} 目的寄存器，操作数1，操作数2  
ORR指令用于在两个操作数上进行逻辑戒运算，并把结果放置到目的寄存器中。操作数1应该是一  
个寄存器，操作数2可以是一个寄存器，被移位的寄存器，或一个立即数。该指令常用于设置操  
作数1的某些位。  
指令示例：  
ORR R0，R0，＃3 ； 该指令设置R0的0、1位，其余位保持不变。

orr r0,r0,\#0xd3  
0xd3=1101 0111  
将r0与0xd3作算数或运算，然后将结果返还给r0,即把r0的bit\[7:6\]和bit\[4\]和bit\[2:0\]置为1。  
\---------------------  
作者：赵琦丶  
来源：CSDN  
原文：https://blog.csdn.net/qq\_23541951/article/details/78868933  
版权声明：本文为博主原创文章，转载请附上博文链接！

[https_blog.csdn.net_zqixiao_09_article_details_50776191]: https://blog.csdn.net/zqixiao_09/article/details/50776191
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3d1aGVueW91eXV5b3V5dQ_size_16_color_FFFFFF_t_70]: /images/20220401/14ba3de5a714478e8ae9486168e2bdbc.png
[20190104083245194.jpg]: /images/20220401/01681957980149efa6d9fc3e168fcae0.png