powerdesign 下ER模型中展示数据注释中文列

短命女 2022-01-29 16:31 253阅读 0赞

工作三年了，如果说对于[数据库][Link 1]不敏感，我觉得的无论是作为一个[前端开发][Link 2]人员还是后端开发人员来说，跟别人说你是个软件开发人员，我觉得都有点惭愧。可能之前一直在关注数据库sql的编写等等，但是现在我觉得有必要升华一下了，下面我就我遇到的问题，向大家提供一个解决方案，可能不是最好的，但是当实现了这个效果后，我真的眼前一亮，在此分享给大家......

软件环境：powerdesign16.5 + win64（64位系统下，由于jdk的版本，powerdesign软件运行不正常，这个我安装jdk1.6\_x86 后解决此问题，大家可百度具体步骤）

问题：当在使用powerdesign时，ER模型中展示code和dataType，即使选择了Comment或者Name，从数据库中反向生成的model中依然在ER视图中看不到中文注释，具体如图：

![aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTE1MzQyNy0xOTk2NzY1OTg5LnBuZw][]

用powerdesign反向生成的model中展示如下：

![aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTQ1MDYzMC0xNTkzNjE2MDEzLnBuZw][]

题：该图中没有展示数据库中列的注释，通过以下步骤可解决此问题：

1、在powerdesign中菜单 Tools——>Display Preference...——>Table——>Advanced...

![aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTg0MDAwNS01MDYzNTA4NzYucG5n][]

2、点击确定，模型显示如图：

![aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTkyMTg4MC0yMTAyOTMwOTg5LnBuZw][]

3、接下来，我们执行脚本，在桌面建立文件powerdesign-name-comment.vbs ，文件名称可随便写，但是必须是vbs文件，名称最好用英文，该文件内容为：

'******************************************************************************
    '* File:     comment2code.vbs
    '* Purpose: 在PowerDesigner的PDM图形窗口中显示数据列的中文注释
    '* Title:    将字段的comment赋值到字段的code中
    '* Category: 打开物理模型，运行本脚本（Ctrl+Shift+X）
    '* Copyright:foxzz@163.com,2006/07/25 .
    '* Author:   foxzz
    '* Created:
    '* Modified:
    '* Version: 1.0
    '* Comment: 遍历物理模型中的所有表，将字段的comment赋值到字段的code中。
    '            在将code置换为comment过程中，需要考虑的问题
    '            1、code必须唯一，而comment有可能不唯一。
    '               处理办法是如果字段的comment重复，则字段的code=comment+1、2、3...
    '            2、comment值有可能为空，这种情况下对字段的code不处理。
    '               针对Oracle数据库,将comment on column 字段名称 is '';添加到C:\pdcomment.txt文件中。
    '               在补充comment完毕后，便于在数据库中执行      
    '******************************************************************************
    
    
    Option Explicit
    ValidationMode = True
    InteractiveMode = im_Batch
    
    
    Dim system, file
    Set system = CreateObject("Scripting.FileSystemObject")
    Dim ForReading, ForWriting, ForAppending   '打开文件选项
    ForReading   = 1 ' 只读
    ForWriting   = 2 ' 可写
    ForAppending = 8 ' 可写并追加
    '打开文本文件
    Set file = system.OpenTextFile("C:\pdcomment.txt", ForWriting, true)
    
    
    
    
    '判断当前model是否物理数据模型
    Dim mdl
    Set mdl = ActiveModel
    If (mdl Is Nothing) Then
       MsgBox "处理对象无模型"
    ElseIf Not mdl.IsKindOf(PdPDM.cls_Model) Then
       MsgBox "当前模型不是物理数据模型"
    Else
       ProcessFolder mdl,file
    End If
    file.Close
    
    
    
    
    '******************************************************************************
    Private sub ProcessFolder(folder,file)
    
    
    Dim i,j,k
    i=0:j=0:k=0
    
    
    '列数组，记录字段里不重复的comment
    Dim ColumnComment()
    Dim ColumnCommentNumber()
    ReDim Preserve ColumnComment(i)
    ReDim Preserve ColumnCommentNumber(i)
    
    
    Dim tbl   '当前表
    Dim col   '当前字段
    dim curComment '当前字段comment
    
    
    '处理模型中的表
    for each tbl in folder.tables
        if not tbl.isShortcut then
           if len(trim(tbl.comment))<>0 then
              '可以在这里显示table的comment
              'tbl.code = tbl.code+"("+trim(tbl.comment)+")"
           end if 
    
    
           '处理表中的列
           for each col in tbl.columns
               k = 0
               curComment = trim(col.comment)
               if len(curComment)<>0 then
                  '遍历相异的comment数组
                  for j = 0 to i
                      if ColumnComment(j) = curComment then
                         '如果找到相同的comment,则相关计数器加1
                         ColumnCommentNumber(j) = ColumnCommentNumber(j) + 1
                         k = j
                      end if
                  Next
                  '如果没有相同的comment,则k=0,此时ColumnCommentNumber(0)也为0
                  '否则ColumnCommentNumber(k)不为0
                  if ColumnCommentNumber(k) <> 0 then
                     col.name = curComment & cstr(ColumnCommentNumber(k))
                  else
                     col.name = curComment
                     'ColumnComment(0)、ColumnCommentNumber(0)永远为空
                     '将相异的comment记录添加到数组中
                     i = i + 1
                     ReDim Preserve ColumnComment(i)
                     ReDim Preserve ColumnCommentNumber(i)
                     ColumnComment(i) = curComment
                     ColumnCommentNumber(i) = 0
                  end if
               else
                  '写入文件中
                  file.WriteLine "comment on column "+ tbl.code+"."+col.name+" is '';"         
               end if
           next
        end if
        '由于不同表的code允许相同,因此此时重新初始化。
        '因为ColumnComment(0)、ColumnCommentNumber(0)为空，可以保留
        ReDim Preserve ColumnComment(0)
        ReDim Preserve ColumnCommentNumber(0)
        i=0:j=0:k=0
    
    
    next
    
    
    Dim view '当前视图
    for each view in folder.Views
        if not view.isShortcut then
           '可以在这里显示view的comment
           'view.code = view.comment
        end if
    next
    
    
    '对子目录进行递归
    Dim subpackage 'folder
    For Each subpackage In folder.Packages
        if not subpackage.IsShortcut then
           ProcessFolder subpackage , file
        end if
    Next
    
    
    end sub
    
    '******************************************************************************

4、在powerdesign中菜单Tools——>Excute Commands——>Edit/Run Script...  选择上一步创建的文件，点击执行，效果如下：

![aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MjExNTY5Mi0zMjgxODk5ODYucG5n][]

5、至此，完毕！ （如果报无权限，把pdcomment.txt文件内容复制然后新建一个新的文件即可）

原文：[https://www.cnblogs.com/zh-haining/p/6291750.html][https_www.cnblogs.com_zh-haining_p_6291750.html]

[Link 1]: http://lib.csdn.net/base/mysql
[Link 2]: http://lib.csdn.net/base/javascript
[aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTE1MzQyNy0xOTk2NzY1OTg5LnBuZw]: /images/20220129/feaadfc65dda458cb1f1de5e9ada83f7.png
[aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTQ1MDYzMC0xNTkzNjE2MDEzLnBuZw]: /images/20220129/86b730ad20844581875c395cbce19ca3.png
[aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTg0MDAwNS01MDYzNTA4NzYucG5n]: /images/20220129/471aebc9db9d4e96a12c0d36597adfab.png
[aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MTkyMTg4MC0yMTAyOTMwOTg5LnBuZw]: /images/20220129/4144a8638d2341c3a34348d4daec9da7.png
[aHR0cHM6Ly9pbWFnZXMyMDE1LmNuYmxvZ3MuY29tL2Jsb2cvMTA1NzM2OS8yMDE3MDEvMTA1NzM2OS0yMDE3MDExNzA5MjExNTY5Mi0zMjgxODk5ODYucG5n]: /images/20220129/5238c1d01edc4d748a34ba6ae1c1c00e.png
[https_www.cnblogs.com_zh-haining_p_6291750.html]: https://www.cnblogs.com/zh-haining/p/6291750.html