led裸机程序分析四(CPU初始化文件init.s)

迈不过友情╰ 2021-07-26 16:08 334阅读 0赞

## 分析流程图： ##

![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3UwMTI1Nzc0NzQ_size_16_color_FFFFFF_t_70]

## 源码分析： ##

;=========================================
    ; NAME: 2440INIT.S
    ; DESC: C start up codes
    ;       Configure memory, ISR ,stacks
    ;	Initialize C-variables
    ; HISTORY:
    ; 2002.02.25:kwtark: ver 0.0
    ; 2002.03.20:purnnamu: Add some functions for testing STOP,Sleep mode
    ; 2003.03.14:DonGo: Modified for 2440.
    ;=========================================
    
    	GET option.inc  ;定义芯片相关配置
    	GET memcfg.inc  ;定义存储器相关配置
    	GET 2440addr.inc ;定义寄存器符号
    
    BIT_SELFREFRESH EQU	(1<<22) ;用于节电模式中，SDRAM自动刷新
    
    ;Pre-defined constants  ;处理器模式常量: CPSR寄存器的后5位决定目前处理器模式 M[4:0]
    USERMODE    EQU 	0x10   ;正常 ARM 程序执行状态
    FIQMODE     EQU 	0x11   ;为支持数据传输或通道处理设计
    IRQMODE     EQU 	0x12   ;用于一般用途的中断处理
    SVCMODE     EQU 	0x13   ;操作系统保护模式
    ABORTMODE   EQU 	0x17   ;数据或指令预取中止后进入
    UNDEFMODE   EQU 	0x1b   ;执行了一个未定义指令时进入
    MODEMASK    EQU 	0x1f   ;操作系统的特权用户模式 M[4:0]  
    
    NOINT       EQU 	0xc0   ;禁止中断 （FIQ 禁止、IRQ 禁止）
    
    ;The location of stacks ;定义处理器各模式下堆栈地址常量   
    
    UserStack	EQU	(_STACK_BASEADDRESS-0x3800)	;0x33ff4800 ~   _STACK_BASEADDRESS=0x33ff8000定义在option.inc中
    SVCStack	EQU	(_STACK_BASEADDRESS-0x2800)	;0x33ff5800 ~
    UndefStack	EQU	(_STACK_BASEADDRESS-0x2400)	;0x33ff5c00 ~
    AbortStack	EQU	(_STACK_BASEADDRESS-0x2000)	;0x33ff6000 ~
    IRQStack	EQU	(_STACK_BASEADDRESS-0x1000)	;0x33ff7000 ~
    FIQStack	EQU	(_STACK_BASEADDRESS-0x0)	;0x33ff8000 ~
    
    ;arm处理器有两种工作状态 1.arm:32位 这种工作状态下执行字对准的arm指令 2.Thumb:16位 这种工作状
    ;态执行半字对准的Thumb指令
    ;因为处理器分为16位 32位两种工作状态 程序的编译器也是分16位和32两种编译方式 所以下面的程序用
    ;于根据处理器工作状态确定编译器编译方式
    ;code16伪指令指示汇编编译器后面的指令为16位的thumb指令
    ;code32伪指令指示汇编编译器后面的指令为32位的arm指令
    ;
    ;Arm上电时处于ARM状态，故无论指令为ARM集或Thumb集，都先强制成ARM集，待init.s初始化完成后
    ;再根据用户的编译配置转换成相应的指令模式。为此，定义变量THUMBCODE作为指示，跳转到main之前
    ;根据其值切换指令模式
    ;
    ;这段是为了统一目前的处理器工作状态和软件编译方式（16位编译环境使用tasm.exe编译
    ;Check if tasm.exe(armasm -16 ...@ADS 1.0) is used.
    
    	GBLL    THUMBCODE ;定义THUMBCODE全局变量注意EQU所定义的宏与变量的区别
    	[ { CONFIG} = 16  ;如果发现是在用16位代码的话（编译选项中指定使用thumb指令）
    THUMBCODE SETL  { TRUE}  ;一方面把THUMBCODE设置为TURE
    	    CODE32  ;另一方面暂且把处理器设置成为ARM模式，以方便初始化
     		|		;（|表示else）如果编译选项本来就指定为ARM模式
    THUMBCODE SETL  { FALSE}  ;把THUMBCODE设置为FALSE就行了
        ]
        
    ;MACRO伪操作标识宏定义的开始，MEND标识宏定义的结束。
    ;用MACRO及MEND定义一段代码，称为宏定义体，这样在程序中就可以通过宏指令多次调用该代码段。 
     		MACRO  			 ;一个根据THUMBCODE把PC寄存的值保存到LR的宏
    	MOV_PC_LR			;宏名称(完成子程序返回)
     		[ THUMBCODE     ;如果定义了THUMBCODE，则
    	    bx lr           ;在ARM模式中要使用BX指令转跳到THUMB指令,并转换模式. bx指令会根据PC最后1位来确定是否进入thumb状态
     		|				;否则
    	    mov	pc,lr		;如果目标地址也是ARM指令的话就采用这种方式
     		]
    	MEND       ;宏定义结束标志
    
     		MACRO    ;和上面的宏一样,只是多了一个相等的条件
    	MOVEQ_PC_LR
     		[ THUMBCODE
            bxeq lr
     		|
    	    moveq pc,lr
     		]
    	MEND
    
    		;=======================================================================================
    		;下面这个宏是用于第一次查表过程的实现中断向量的重定向,如果你比较细心的话就会发现
    		;在_ISR_STARTADDRESS=0x33FF_FF00里定义的第一级中断向量表是采用型如Handle***的方式的.
    		;而在程序的ENTRY处(程序开始处)采用的是b Handler***的方式.
    		;在这里Handler***就是通过HANDLER这个宏和Handle***建立联系的.
    		;这种方式的优点就是正真定义的向量数据在内存空间里,而不是在ENTRY处的ROM(FLASH)空间里,
    		;这样,我们就可以在程序里灵活的改动向量的数据了.
    		;========================================================================================
    		;;这段程序用于把中断服务程序的首地址装载到pc中，有人称之为“加载程序”。
    		;本初始化程序定义了一个数据区（在文件最后），34个字空间，存放相应中断服务程序的首地址。每个字
    		;空间都有一个标号，以Handle***命名。
    		;在向量中断模式下使用“加载程序”来执行中断服务程序。
    		;这里就必须讲一下向量中断模式和非向量中断模式的概念
    		;向量中断模式是当cpu读取位于0x18处的IRQ中断指令的时候，系统自动读取对应于该中断源确定地址上的;
    		;指令取代0x18处的指令，通过跳转指令系统就直接跳转到对应地址
    		;函数中 节省了中断处理时间提高了中断处理速度度 例如 ADC中断的向量地址为0xC0,则在0xC0处放如下
    		;代码：ldr PC,=HandlerADC 当ADC中断产生的时候系统会
    		;自动跳转到HandlerADC函数中
    		;非向量中断模式处理方式是一种传统的中断处理方法，当系统产生中断的时候，系统将interrupt
    		;pending寄存器中对应标志位置位 然后跳转到位于0x18处的统一中断
    		;函数中 该函数通过读取interrupt pending寄存器中对应标志位 来判断中断源 并根据优先级关系再跳到
    		;对应中断源的处理代码中
    		;
    		;H|------|			 H|------|		  H|------| 		  H|------| 		H|------|		
    		; |/ / / |			  |/ / / |		   |/ / / | 		   |/ / / | 		 |/ / / |		
    		; |------|<----sp	  |------|		   |------| 		   |------| 		 |------|<------sp 
    		;L| 	 |			  |------|<----sp L|------| 		   |-isr--| 		 |------| isr==>pc
    		; | 	 |			  | 	 |		   |--r0--|<----sp	   |---r0-|<----sp	L|------| r0==>r0
    		;	 (0)				(1) 			 (2)				  (3)				(4)
    		 
    
    
    ;[各中断跳转处理，跳转到我们最后面定义的中断地址去处理]
     		MACRO
    $HandlerLabel HANDLER $HandleLabel  ;注意$HandlerLabel符号 比后面的$HandleLabel符号 多一个字母‘r’ ，相当于函数的形参
    ;$HandlerLabel为ARM体现中统一定义的几种异常中断
    ;$HandleLabel为ARM处理器中每个中断的定义，见中断向量表
    $HandlerLabel    ;标号
    	sub	sp,sp,#4	;(1)减少sp，预留一个用来存储PC地址（因为stmfd是递减入栈的，又是arm（32位）模式所以减4）
    	;由于要利用r0寄存器来传递数据，所以要保存r0数据，使其入栈
    	stmfd	sp!,{ r0}	;(2)把工作寄存器压入栈(lr does not push because it return to original address)
    	ldr     r0,=$HandleLabel  ;将HandleXXX的址址放入r0
    	ldr     r0,[r0]	 		  ;把HandleXXX所指向的内容(也就是中断程序的入口地址)放入r0
    	str     r0,[sp,#4]      ;(3)中断服务函数的起始地址入栈
    	ldmfd   sp!,{ r0,pc}     ;(4)将事先保存的r0寄存器和中断函数首地址出栈，并使系统跳转到相应的中断处理函数（跳转到下面的IsrIRQ函数处）
    	MEND
    	;首先这段程序是个宏定义，HANDLER是宏名，不要想歪了
    	;其次后面程序遇到的HandlerXXX HANDLER HandleXXX这些语句将都被上面这段程序展开
    			
    		;=========================================================================================
    		;在这里用IMPORT伪指令(和c语言的extren一样)引入|Image$$RO$$Base|,|Image$$RO$$Limit|...
    			;这些变量是通过ADS的工程设置里面设定的RO Base和RW Base设定的,
    			;最终由编译脚本和连接程序导入程序.
    			;那为什么要引入这玩意呢,最简单的用处是可以根据它们拷贝自已
    			;==========================================================================================
    			;Image$$RO$$Base等比较古怪的变量是编译器生成的。RO, RW, ZI这三个段都保存在Flash中，但RW，ZI在Flash中
    			;的地址肯定不是程序运行时变量所存储的位置，因此我们的程序在初始化时应该把Flash中的RW，ZI拷贝到RAM的对应位置。
    			;一般情况下，我们可以利用编译器替我们实现这个操作。比如我们跳转到main()时，使用 b	__Main,编译器就会在__Main
    			;和Main之间插入一段汇编代码，来替我们完成RW，ZI段的初始化。 如果我们使用 b	Main， 那么初始化工作要我们自己做。
    			;编译器会生成如下变量告诉我们RO，RW，ZI三个段应该位于什么位置，但是它并没有告诉我们RW，ZI在Flash中存储在什么位置，
    			;实际上RW，ZI在Flash中的位置就紧接着RO存储。我们知道了Image$$RO$$Base，Image$$RO$$Limit，那么Image$$RO$$Limit就
    			;是RW（ROM data）的开始。
    
    
    	IMPORT  |Image$$RO$$Limit|  ; End of ROM code (=start of ROM data)  ;RO起始地址
    	IMPORT  |Image$$RW$$Base|   ; Base of RAM to initialise		;RO结束地址加1等于RW段起始地址
    	IMPORT  |Image$$ZI$$Base|   ; Base and limit of area		;ZI段起始地址
    	IMPORT  |Image$$ZI$$Limit|  ; to zero initialise			;ZI段结束地址
    	
    			;这里引入一些在其它文件中实现在函数,包括为我们所熟知的main函数
    	IMPORT	Main
    
    		
    			;从这里开始就是正真的代码入口了!
    	AREA    Init,CODE,READONLY  ;这表明下面的是一个名为Init的代码段
    
    	ENTRY	;定义程序的入口(调试用)
    
    	
    
    	;1)The code, which converts to Big-endian, should be in little endian code.
    	;2)The following little endian code will be compiled in Big-Endian mode.
    	;  The code byte order should be changed as the memory bus width.
    	;3)The pseudo instruction,DCD can't be used here because the linker generates error.
    	
    	;条件编译，在编译成机器码前就设定好
    	
    	ASSERT	:DEF:ENDIAN_CHANGE		;判断ENDIAN_CHANGE是否已定义
    	[ ENDIAN_CHANGE					;如果已经定义了ENDIAN_CHANGE，则（在Option.inc里已经设为FALSE ）
    	    ASSERT  :DEF:ENTRY_BUS_WIDTH	;判断ENTRY_BUS_WIDTH是否已定义
    	    [ ENTRY_BUS_WIDTH=32		;如果已经定义了ENTRY_BUS_WIDTH，则判断是不是为32
    		b	ChangeBigEndian	    ;DCD 0xea000007		;DCD 0xea000007
    	    ]
    	    
    		;在bigendian中，地址为A的字单元包括字节单元A，A+1，A+2，A+3，字节单元由高位到低位为A，A+1，A+2，A+3
    		;	  地址为A的字单元包括半字单元A，A+2，半字单元由高位到低位为A，A+2
    
    	    [ ENTRY_BUS_WIDTH=16
    		andeq	r14,r7,r0,lsl #20   ;DCD 0x0007ea00		;DCD 0x0007ea00 也是b ChangeBigEndian指令，只是由于总线不一样而取机器码的顺序不一样
    	    ]						;先取低位->高位 上述指令是通过机器码转换而来的
    
    	    [ ENTRY_BUS_WIDTH=8
    		streq	r0,[r0,-r10,ror #1] ;DCD 0x070000ea		;DCD 0x070000ea 也是b ChangeBigEndian指令，只是由于总线不一样而取机器码的顺序不一样
    	    ]
    	|
    	    b	ResetHandler		;我们的程序由于ENDIAN_CHANGE设成FALSE就到这儿了,转跳到复位程序入口   	
        ]
    	b	HandlerUndef	;handler for Undefined mode
    	b	HandlerSWI	;handler for SWI interrupt
    	b	HandlerPabort	;handler for PAbort
    	b	HandlerDabort	;handler for DAbort
    	b	.		;reserved
    	b	HandlerIRQ	;handler for IRQ interrupt
    	b	HandlerFIQ	;handler for FIQ interrupt
    
    ;@0x20  当前位置地址是0x20,0到0x1c地址空间被中断向量所占用
    	b	EnterPWDN	; Must be @0x20.  ;函数功能：根据r0参数判断是否进入睡眠模式
    
    		;当c程序中可以看到这样的宏声明：#define EnterPWDN(clkcon) ((void (*)(int))0x20)(clkcon)，
    		;这里把EnterPWDN函数提供给c程序调用	
    		;跳转到地址0x20处执行代码，并且把参数传到r0，ATPCS中规定1-4个参数对应的存储寄存器为r0-r3。
    		
    ChangeBigEndian
    ;@0x24
    	[ ENTRY_BUS_WIDTH=32
    	    DCD	0xee110f10	;0xee110f10 => mrc p15,0,r0,c1,c0,0
    	    DCD	0xe3800080	;0xe3800080 => orr r0,r0,#0x80;  //Big-endian
    	    DCD	0xee010f10	;0xee010f10 => mcr p15,0,r0,c1,c0,0
    	]
    	[ ENTRY_BUS_WIDTH=16
    	    DCD 0x0f10ee11
    	    DCD 0x0080e380
    	    DCD 0x0f10ee01
    	]
    	[ ENTRY_BUS_WIDTH=8
    	    DCD 0x100f11ee
    	    DCD 0x800080e3
    	    DCD 0x100f01ee
        ]
    	DCD 0xffffffff  ;swinv 0xffffff is similar with NOP and run well in both endian mode.
    	DCD 0xffffffff
    	DCD 0xffffffff
    	DCD 0xffffffff
    	DCD 0xffffffff
    	b ResetHandler
    
    ;Function for entering power down mode
    ; 1. SDRAM should be in self-refresh mode.
    ; 2. All interrupt should be maksked for SDRAM/DRAM self-refresh.
    ; 3. LCD controller should be disabled for SDRAM/DRAM self-refresh.
    ; 4. The I-cache may have to be turned on.
    ; 5. The location of the following code may have not to be changed.
    
    ;进入睡眠模式
    ;void EnterPWDN(int CLKCON);
    EnterPWDN
    	mov r2,r0		;r2=rCLKCON
    	tst r0,#0x8		;SLEEP mode?
    	bne ENTER_SLEEP		;调用进入睡眠模式的函数
    
    ENTER_STOP
    	ldr r0,=REFRESH
    	ldr r3,[r0]		;r3=rREFRESH
    	mov r1, r3
    	orr r1, r1, #BIT_SELFREFRESH
    	str r1, [r0]		;Enable SDRAM self-refresh
    
    	mov r1,#16			;wait until self-refresh is issued. may not be needed.
    0	subs r1,r1,#1
    	bne %B0
    
    	ldr r0,=CLKCON		;enter STOP mode.
    	str r2,[r0]
    
    	mov r1,#32
    0	subs r1,r1,#1	;1) wait until the STOP mode is in effect.
    	bne %B0		;2) Or wait here until the CPU&Peripherals will be turned-off
    			;   Entering SLEEP mode, only the reset by wake-up is available.
    
    	ldr r0,=REFRESH ;exit from SDRAM self refresh mode.
    	str r3,[r0]
    
    	MOV_PC_LR
    	
    ;进入睡眠模式函数
    ENTER_SLEEP
    	;NOTE.
    	;rGSTATUS3需要有从睡眠模式唤醒后的返回地址
    	;1) rGSTATUS3 should have the return address after wake-up from SLEEP mode.
    	
    	;设置SDRAM为自刷新方式 
    	ldr r0,=REFRESH
    	ldr r1,[r0]		;r1=rREFRESH
    	orr r1, r1, #BIT_SELFREFRESH
    	str r1, [r0]		;Enable SDRAM self-refresh
    	
    	;等待一段时间 
    	mov r1,#16			;Wait until self-refresh is issued,which may not be needed.
    0	subs r1,r1,#1
    	bne %B0
    	
    	;在进入SLEEP模式之前，配置必要的时钟和OFFREFRESH
    	ldr	r1,=MISCCR
    	ldr	r0,[r1]
    	orr	r0,r0,#(7<<17)  ;Set SCLK0=0, SCLK1=0, SCKE=0.
    	str	r0,[r1]
    	;进入睡眠模式
    	ldr r0,=CLKCON		; Enter sleep mode
    	str r2,[r0]
    	;进入死循环
    	b .			;CPU will die here.
    
    ;从SLEEP模式下被唤醒函数 
    WAKEUP_SLEEP	
    	;Release SCLKn after wake-up from the SLEEP mode.
    	;设置时钟和OFFREFRESH 
    	ldr	r1,=MISCCR
    	ldr	r0,[r1]
    	bic	r0,r0,#(7<<17)  ;SCLK0:0->SCLK, SCLK1:0->SCLK, SCKE:0->=SCKE.
    	str	r0,[r1]
    	
    	;配置内存控制寄存器 
    	;Set memory control registers
     	ldr	r0,=SMRDATA
    	ldr	r1,=BWSCON	;BWSCON Address
    	add	r2, r0, #52	;End address of SMRDATA
    0
    	ldr	r3, [r0], #4
    	str	r3, [r1], #4
    	cmp	r2, r0
    	bne	%B0
    	
    	;等待一段时间 
    	mov r1,#256
    0	subs r1,r1,#1	;1) wait until the SelfRefresh is released.
    	bne %B0
    	
    	;GSTATUS3存放着想要从SLEEP模式唤醒后的执行地址
    	ldr r1,=GSTATUS3 	;GSTATUS3 has the start address just after SLEEP wake-up
    	ldr r0,[r1]
    
    	mov pc,r0
    	
    	;LTORG用于声明一个数据缓冲池，（也称为文字池）的开始。在使用伪指令LDR时，
    	;常常需要在适当的地方加入LTORG声明数据缓冲池，LDR加载的数据暂时被编译器放于数据缓冲池中。
    	LTORG
    ;各中断入口跳转到此处	
    ;此处会调用前面的 $HandlerLabel HANDLER $HandleLabel 函数
    HandlerFIQ      HANDLER HandleFIQ
    HandlerIRQ      HANDLER HandleIRQ
    HandlerUndef    HANDLER HandleUndef
    HandlerSWI      HANDLER HandleSWI
    HandlerDabort   HANDLER HandleDabort
    HandlerPabort   HANDLER HandlePabort
    
    
    ;下面这段代码是用于处理非向量中断，即由软件程序来判断到底发生了哪种中断，然后跳转到相应地中断服务程序中 
    ;具体地说就是，当发生中断时，会置INTOFFSET寄存器相应的位为1，然后通过查表(见该程序末端部分的中断向量表)，
    ;找到相对应的中断入口地址。 
    ;观察中断向量表，会发现它与INTOFFSET寄存器中的中断源正好相对应，即向量表的顺序与INTOFFSET寄存器中的中断源
    ;的由小到大的顺序一致，因此我们可以用基址加变址的方式很容易找到相对应的中断入口地址。其中基址为向量表的首
    ;个中断源地址，变址为INTOFFSET寄存器的值乘以4(因为系统是用4个字节单元来存放一个中断向量)。
    
    IsrIRQ
    
    	sub	sp,sp,#4       ;reserved for PC
    	stmfd	sp!,{ r8-r9}
    
    	ldr	r9,=INTOFFSET	;INTOFFSET寄存器用来指示 IRQ 中断请求源
    	ldr	r9,[r9]		;获取INTOFFSET寄存器当前的值到r9
    	ldr	r8,=HandleEINT0		;获取中断向量表中的HandleEINT0中断的入口地址（将根据当前的INTOFFSET来计算当前中断入口）
    	add	r8,r8,r9,lsl #2		;用基址加变址的方式得到中断向量表的地址  (r9左右2位即是，r8=r8+r9*2^2，计算结果是地址偏移)
    	ldr	r8,[r8]				;得到中断服务程序入口地址（目标地址中的值即为中断入口地址）
    	str	r8,[sp,#8]			;使中断服务程序入口地址入栈
    	ldmfd	sp!,{ r8-r9,pc}	;使r8，r9和入口地址出栈，并跳到中断服务程序中 
    
    ;==========================================
    ; ENTRY(好了,我们的CPU要在这复位了.)
    ;==========================================
    ResetHandler
    	ldr	r0,=WTCON       ;1.关看门狗
    	ldr	r1,=0x0
    	str	r1,[r0]
    
    	ldr	r0,=INTMSK
    	ldr	r1,=0xffffffff  ;2.关中断
    	str	r1,[r0]
    
    	ldr	r0,=INTSUBMSK
    	ldr	r1,=0x3ff		;3.关子中断
    	str	r1,[r0]
    
    	[ { FALSE}   ;4.得有些表示了,该点点LED灯了,不过被FALSE掉了
    	; rGPFDAT = (rGPFDAT & ~(0xf<<4)) | ((~data & 0xf)<<4);
    	; Led_Display
    	ldr	r0,=GPFCON
    	ldr	r1,=0x5500
    	str	r1,[r0]
    	ldr	r0,=GPFDAT
    	ldr	r1,=0x10
    	str	r1,[r0]
    	]
    	
    	;5.为了减少PLL的lock time, 调整LOCKTIME寄存器.
    	;To reduce PLL lock time, adjust the LOCKTIME register.
    	ldr	r0,=LOCKTIME
    	ldr	r1,=0xffffff	;reset的默认值
    	str	r1,[r0]
    	
    ;6.下面就来设置PLL了,你的板快不快就看这了!!
    ;这里介绍一下计算公式--------------------------------------------------------------------------
    ;1. Fout = 2 × m × Fin / ( p*2s )，Fvco = 2 × m × Fin / p 此处：m =MDIV+8, p=PDIV+2, s=SDIV
    ;2. 600MHz ≤ FVCO ≤ 1.2GHz
    ;3. 200MHz ≤ FCLKOUT ≤ 600MHz
    ;4. 不要设置 P 或 M 的值为 0，这是因为设置 P=000000，M=00000000 将会引起 PLL 的故障。
    ;5. P 和 M 的合理范围为：1 ≤ P ≤ 62，1 ≤ M ≤ 248
    ;---------------------------------------------------------------------------------------------
    ;如下面的PLLCON设定中的M_DIV P_DIV S_DIV是取自option.h中
    ;#elif (MCLK==30400000)
    ;#define PLL_M (68)
    ;#define PLL_P (3)
    ;#define PLL_S (1)
    ;所以m=MDIV+8=76,p=PDIV+2=3,s=SDIV=1
    ;硬件使用晶振为12Mhz,即Fin=12Mhz
    ;Fpllo=(2*76*12000000)/(3*2^1)=30400000HZ ,经公式验证成功（提示：S3C2440芯片手册已给出各个频率下相应的MDIV、PDIV和SDIV的值了。）
    
    ;PLL配置（包括Fclk:Hclk:Pclk分频比设置、UPLL和MPLL设置）
        [ PLL_ON_START    ;是否开启PLL,如果定义开启PLL则执行
        ;分频比设置
    	; Added for confirm clock divide. for 2440.
    	; Setting value Fclk:Hclk:Pclk
    	ldr	r0,=CLKDIVN    ;读取 时钟分频控制寄存器(CLKDIVN)的地址到r0
    	;CLKDIV_VAL在option.ini定义过，其值是7 。
    	ldr	r1,=CLKDIV_VAL		;CLKDIV_VAL=7,将会设置把Fclk:Hclk:Pclk分频比设为1:1/3:1/6
    	str	r1,[r0]		;设置Fclk:Hclk:Pclk分频比
    ;MPLL 和 UPLL 的设置
    ;提升：
    ;S3C2440 CPU主频可达400MHz，开发板上的外接晶振为12M，通过时钟控制逻辑的PLL（phase locked loop，锁相环电路）来倍频这个系统时钟。
    ;2440有两个PLL（phase locked loop）一个是MPLL，一个是UPLL。UPLL专用于USB设备，常用频率为48MHz和96MHz。MPLL用于CPU及其他外围器件，
    ;用于产生FCLK， HCLK， PCLK三种频率，上电时，PLL并没有被启动，FCLK=Fin=12MHz，若要提高系统时钟，需要软件来启动PLL。
    ;注意：当你设置 MPLL 和 UPLL 的值时，你必须首先设置 UPLL 值再设置 MPLL 值。（大约需要 7 个 NOP 的间隔）
    
    	;配置 UPLL
    	ldr	r0,=UPLLCON
    	ldr	r1,=((U_MDIV<<12)+(U_PDIV<<4)+U_SDIV) 
    	str	r1,[r0]
    	
    	nop	; Caution: After UPLL setting, at least 7-clocks delay must be inserted for setting hardware be completed.
    	nop
    	nop
    	nop
    	nop
    	nop
    	nop
    	
    	;配置 MPLL	
    	ldr	r0,=MPLLCON
    	ldr	r1,=((M_MDIV<<12)+(M_PDIV<<4)+M_SDIV) 
    	str	r1,[r0]
        ]
        
    	;检查是否从SLEEP模式中恢复
        	;Check if the boot is caused by the wake-up from SLEEP mode.
    	ldr	r1,=GSTATUS2  ;GSTATUS2用来记录系统是通过何种方式重启的，通过读取该寄存器的内容可以得知系统是通过何种方式重启的。
    	ldr	r0,[r1]  
    	;tst：逻辑处理指令，用于把一个寄存器的内容和另一个寄存器的内容或立即数进行按位的与运算，并根据运算结果更新CPSR中条件标志位的值。当前运算结果为1，则Z=0；当前运算结果为0，则Z=1	
    	tst	r0,#0x2   ;
    	;In case of the wake-up from SLEEP mode, go to SLEEP_WAKEUP handler.
    	;bne: 数据跳转指令，标志寄存器中Z标志位不等于零时, 跳转到BNE后标签处
    	bne	WAKEUP_SLEEP  ;如果Z！=0 表示启动方式是SLEEP唤醒启动则，跳转到WAKEUP_SLEEP 执行从SLEEP模式中恢复。
    
    	EXPORT StartPointAfterSleepWakeUp  ;导出该地址标号，以便在C语言程序中使用 
    StartPointAfterSleepWakeUp
    
    ;设置内存控制寄存器 
    ;关于内存控制寄存器一共有以BWSCON为开始的连续放置的13个寄存器，我们要一次性批量完成这13个寄存器的配置 
    ;因此开辟一段以SMRDATA为地址起始点的13个字单元空间，按顺序放入要写入的13个寄存器内容
    
    	;Set memory control registers 
     	ldr	r0,=SMRDATA
    ;得到SMRDATA空间的首地址  	
    	ldr	r1,=BWSCON	;BWSCON Address
    ;得到BWSCON的地址 
    	add	r2, r0, #52	;End address of SMRDATA
    ;得到SMRDATA空间的末地址 
    ;完成13个字数据的复制 
    
    
    ;循环拷贝13个字数据到以BWSCON为首地址的连续的13个寄存器中
    0
    	ldr	r3, [0r], #4
    	str	r3, [r1], #4
    	cmp	r2, r0
    	bne	%B0 	 ;bne %B0,如果不相等则跳到本条语句前的lable为0的行
    	
    		;%B 代表，往前搜索　lable为0的行，换句话说，就是指本条语句前，lable为0的地址。整条语句的意思就是，
    		;如果不相等则跳转到lable为0的行。
    		;同样，有了bne %B0，也就有了bne %F1，这是向后搜索lable为１的行
    		;bne %B0,如果不相等则跳到本条语句前的lable为0的行。	
    ;栈的初始化
     		;Initialize stacks
    	bl	InitStacks
    
    ;普通中断处理 
    ;当普通中断发生时，执行的是IsrIRQ 
    
      	; Setup IRQ handler   
    	ldr	r0,=HandleIRQ       ;This routine is needed
    	ldr	r1,=IsrIRQ	  ;if there isn't 'subs pc,lr,#4' at 0x18, 0x1c
    	str	r1,[r0]  ;//initialize the IRQ 将普通中断判断程序的入口地址给HandleIRQ
    
    	;//
    	;注意，以下这段可能不需要!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!!
    	;//6.将数据段拷贝到ram中 将零初始化数据段清零跳入C语言的main函数执行到这步结束bootloader初步引导结束
    
    	;If main() is used, the variable initialization will be done in __main().
        [	:LNOT:USE_MAIN	;by tinko -- 最外面的条件由tinko添加，实际上不再执行这段
        	;Copy and paste RW data/zero initialized data
    	LDR     r0, =|Image$$RO$$Limit| ; Get pointer to ROM data
    	LDR     r1, =|Image$$RW$$Base|  ; and RAM copy
    	LDR     r3, =|Image$$ZI$$Base|  
    	
    	;Zero init base => top of initialised data
    	CMP     r0, r1      ; Check that they are different
    	BEQ     %F2
    1       
    	CMP     r1, r3      ; Copy init data
    	LDRCC   r2, [r0], #4    ;--> LDRCC r2, [r0] + ADD r0, r0, #4         
    	STRCC   r2, [r1], #4    ;--> STRCC r2, [r1] + ADD r1, r1, #4
    	BCC     %B1
    2       
    	LDR     r1, =|Image$$ZI$$Limit| ; Top of zero init segment
    	MOV     r2, #0
    3       
    	CMP     r3, r1      ; Zero init
    	STRCC   r2, [r3], #4
    	BCC     %B3
        ]
    
    ;完成最基本的初始化任务，跳转到由C语言撰写的Main()函数内继续执行其他程序 
    ;这里不能写main，因为写了main，系统会自动为我们完成一些初始化工作，而这些工作在这段程序中是由我们显式地人为完成的。
    
       	
        [ :LNOT:THUMBCODE	;L代表logic变量,not是非，没有定义THUMBCODE则执行
        	bl	Main        ;Don't use main() because ...... ;跳转main函数去执行
        	b	.    ;'.'表示当前地址，这里是死循环的意思（当从Main函数返回，将停在这里）                   
        ]
    
    ;如果定义了THUMBCODE模式
        [ THUMBCODE         ;for start-up code for Thumb mode
        	orr	lr,pc,#1  
        	bx	lr
        	CODE16  ;告诉编译器后面以THUMBCODE模式编译
        	bl	Main        ;Don't use main() because ......
        	b	.	;注意小圆点      
        	CODE32
        ]
    
    
    ;初始化堆栈函数  
    ;function initializing stacks
    
    InitStacks
    	;Don't use DRAM,such as stmfd,ldmfd......
    	;SVCstack is initialized before
    	;Under toolkit ver 2.5, 'msr cpsr,r1' can be used instead of 'msr cpsr_cxsf,r1'
    ;改变CPSR中M控制位，切换到相应的处理器模式下
    ;为各自模式下的SP赋值 
    	mrs	r0,cpsr		;在对CPSR，SPSR寄存器进行操作不能使用mov，ldr等通用指令，只能使用特权指令msr(写)和mrs（读）。
    	bic	r0,r0,#MODEMASK   ;清除M[4:0]模式设置的5个位（MODEMASK=0x1f）  
    	orr	r1,r0,#UNDEFMODE|NOINT    ;配置cpsr关中断和进入UndefMode模式  
    	msr	cpsr_cxsf,r1		;UndefMode	
    	ldr	sp,=UndefStack		; UndefStack=0x33FF_5C00  ;让UndefMode模式下的sp指向UndefStack地址（我们设置的UndefStack栈地址的起始地址）  
    	
    	;cpsr_cxsf具体含义如下： 
    	;例如cpsr_c代表的是cpsr寄存器的低8位，也就是控制位.
    	;specifies the field or fields to be moved. can be one or more of: 
    	;c － control field mask byte (PSR[7:0]) 
    	;x － extension field mask byte (PSR[15:8]) 
    	;s － status field mask byte (PSR[23:16) 
    	;f － flags field mask byte (PSR[31:24]).
    
    ;切换到AbortMode并且关闭中断，然后把AbortMode模式下的sp指向AbortStack栈的起始地址
    	orr	r1,r0,#ABORTMODE|NOINT
    	msr	cpsr_cxsf,r1		;AbortMode
    	ldr	sp,=AbortStack		; AbortStack=0x33FF_6000
    	
    ;切换到IRQMode并且关闭中断，然后把IRQMode模式下的sp指向IRQStack栈的起始地址
    	orr	r1,r0,#IRQMODE|NOINT
    	msr	cpsr_cxsf,r1		;IRQMode
    	ldr	sp,=IRQStack		; IRQStack=0x33FF_7000
    	
    ;切换到FIQMode并且关闭中断，然后把FIQMode模式下的sp指向FIQStack栈的起始地址
    	orr	r1,r0,#FIQMODE|NOINT
    	msr	cpsr_cxsf,r1		;FIQMode
    	ldr	sp,=FIQStack		; FIQStack=0x33FF_8000
    	
    ;切换到SVCMode并且关闭中断，然后把SVCMode模式下的sp指向SVCStack栈的起始地址
    	bic	r0,r0,#MODEMASK|NOINT
    	orr	r1,r0,#SVCMODE
    	msr	cpsr_cxsf,r1		;SVCMode
    	ldr	sp,=SVCStack		; SVCStack=0x33FF_5800
    
    	;USER mode has not be initialized.
    	;系统模式和用户模式共用一个栈空间，因此不用再重复设置用户模式堆栈 
    	;系统复位后进入的是SVC模式，而且各种模式下的lr不同，因此
    	;要想从该函数内返回，要首先切换到SVC模式，再使用lr，这样可
    	;以正确返回了
    
    	mov	pc,lr  ;因为当前已经是SVC模式，所以通过当前的lr直接从当前函数返回
    	;The LR register won't be valid if the current mode is not SVC mode.
    
    	
    ;=====================================================================
    ; Clock division test
    ; Assemble code, because VSYNC time is very short
    ;=====================================================================
    	EXPORT CLKDIV124
    	EXPORT CLKDIV144
    	
    CLKDIV124
    	
    	ldr     r0, = CLKDIVN
    	ldr     r1, = 0x3		; 0x3 = 1:2:4
    	str     r1, [r0]
    ;	wait until clock is stable
    	nop
    	nop
    	nop
    	nop
    	nop
    
    	ldr     r0, = REFRESH
    	ldr     r1, [r0]
    	bic		r1, r1, #0xff
    	bic		r1, r1, #(0x7<<8)
    	orr		r1, r1, #0x470	; REFCNT135
    	str     r1, [r0]
    	nop
    	nop
    	nop
    	nop
    	nop
    	mov     pc, lr
    
    CLKDIV144
    	ldr     r0, = CLKDIVN
    	ldr     r1, = 0x4		; 0x4 = 1:4:4
    	str     r1, [r0]
    ;	wait until clock is stable
    	nop
    	nop
    	nop
    	nop
    	nop
    
    	ldr     r0, = REFRESH
    	ldr     r1, [r0]
    	bic		r1, r1, #0xff
    	bic		r1, r1, #(0x7<<8)
    	orr		r1, r1, #0x630	; REFCNT675 - 1520
    	str     r1, [r0]
    	nop
    	nop
    	nop
    	nop
    	nop
    	mov     pc, lr
    
    
    	LTORG
    	
    ;连续13个内存控制寄存器的定义空间
    SMRDATA DATA	;SMRDATA是段名，DATA是属性(定义为数据段) 		
    ; Memory configuration should be optimized for best performance
    ; The following parameter is not optimized.
    ; Memory access cycle parameter strategy
    ; 1) The memory settings is  safe parameters even at HCLK=75Mhz.
    ; 2) SDRAM refresh period is for HCLK<=75Mhz.
    ;DCD指令用于分配一片连续的字存储单元并用伪指令中指定的表达式初始化 
    
    	DCD (0+(B1_BWSCON<<4)+(B2_BWSCON<<8)+(B3_BWSCON<<12)+(B4_BWSCON<<16)+(B5_BWSCON<<20)+(B6_BWSCON<<24)+(B7_BWSCON<<28))
    	DCD ((B0_Tacs<<13)+(B0_Tcos<<11)+(B0_Tacc<<8)+(B0_Tcoh<<6)+(B0_Tah<<4)+(B0_Tacp<<2)+(B0_PMC))   ;GCS0
    	DCD ((B1_Tacs<<13)+(B1_Tcos<<11)+(B1_Tacc<<8)+(B1_Tcoh<<6)+(B1_Tah<<4)+(B1_Tacp<<2)+(B1_PMC))   ;GCS1
    	DCD ((B2_Tacs<<13)+(B2_Tcos<<11)+(B2_Tacc<<8)+(B2_Tcoh<<6)+(B2_Tah<<4)+(B2_Tacp<<2)+(B2_PMC))   ;GCS2
    	DCD ((B3_Tacs<<13)+(B3_Tcos<<11)+(B3_Tacc<<8)+(B3_Tcoh<<6)+(B3_Tah<<4)+(B3_Tacp<<2)+(B3_PMC))   ;GCS3
    	DCD ((B4_Tacs<<13)+(B4_Tcos<<11)+(B4_Tacc<<8)+(B4_Tcoh<<6)+(B4_Tah<<4)+(B4_Tacp<<2)+(B4_PMC))   ;GCS4
    	DCD ((B5_Tacs<<13)+(B5_Tcos<<11)+(B5_Tacc<<8)+(B5_Tcoh<<6)+(B5_Tah<<4)+(B5_Tacp<<2)+(B5_PMC))   ;GCS5
    	DCD ((B6_MT<<15)+(B6_Trcd<<2)+(B6_SCAN))    ;GCS6
    	DCD ((B7_MT<<15)+(B7_Trcd<<2)+(B7_SCAN))    ;GCS7
    	DCD ((REFEN<<23)+(TREFMD<<22)+(Trp<<20)+(Trc<<18)+(Tchr<<16)+REFCNT)
    
    	DCD 0x32	    ;SCLK power saving mode, BANKSIZE 128M/128M
    
    	DCD 0x30	    ;MRSR6 CL=3clk
    	DCD 0x30	    ;MRSR7 CL=3clk
    
    
    	ALIGN	 ;重新使数据字对齐 
    
    	AREA RamData, DATA, READWRITE
    	
    ;在0x33FF_FF00处定义中断向量表 
    ;^符号相当于伪指令MAP，用于定义一个结构化的内存表的首地址
    ;#是FIELD的同义词 ,FIELD伪指令，可以表示结构体中的每个变量，可以指定其大小（占几个字节）
    
    	^   _ISR_STARTADDRESS		; _ISR_STARTADDRESS=0x33FF_FF00
    HandleReset 	#   4		;HandleReset+4
    HandleUndef 	#   4		;HandleUndef+4
    HandleSWI		#   4
    HandlePabort    #   4
    HandleDabort    #   4
    HandleReserved  #   4
    HandleIRQ		#   4
    HandleFIQ		#   4
    
    ;Don't use the label 'IntVectorTable',
    ;The value of IntVectorTable is different with the address you think it may be.
    ;IntVectorTable  ;中断向量表
    ;@0x33FF_FF20
    HandleEINT0		#   4
    HandleEINT1		#   4
    HandleEINT2		#   4
    HandleEINT3		#   4
    HandleEINT4_7	#   4
    HandleEINT8_23	#   4
    HandleCAM		#   4		; Added for 2440.
    HandleBATFLT	#   4
    HandleTICK		#   4
    HandleWDT		#   4
    HandleTIMER0 	#   4
    HandleTIMER1 	#   4
    HandleTIMER2 	#   4
    HandleTIMER3 	#   4
    HandleTIMER4 	#   4
    HandleUART2  	#   4
    ;@0x33FF_FF60
    HandleLCD 		#   4
    HandleDMA0		#   4
    HandleDMA1		#   4
    HandleDMA2		#   4
    HandleDMA3		#   4
    HandleMMC		#   4
    HandleSPI0		#   4
    HandleUART1		#   4
    HandleNFCON		#   4		; Added for 2440.
    HandleUSBD		#   4
    HandleUSBH		#   4
    HandleIIC		#   4
    HandleUART0 	#   4
    HandleSPI1 		#   4
    HandleRTC 		#   4
    HandleADC 		#   4
    ;@0x33FF_FFA0
    	END

[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L3UwMTI1Nzc0NzQ_size_16_color_FFFFFF_t_70]: /images/20210726/ce59182f7e1b405f9fe67bdc7a46072f.png