Hive-分区表与分桶表

红太狼 2022-09-06 10:26 212阅读 0赞

# 分区表和分桶表 #

## 分区表 ##

分区表实际上就是对应一个 HDFS 文件系统上的独立的文件夹,该文件夹下是该分区所有的数据文件。 **Hive 中的分区就是分目录**,把一个大的数据集根据业务需要分割成小的数据集。在查询时通过 WHERE 子句中的表达式选择查询所需要的指定的分区,这样的查询效率会提高很多。

准备数据

dept1.txt
    10,ACCOUNTING,1700
    20,RESEARCH,1800
    
    dept2.txt
    30,SALES,1900
    40,OPERATIONS,1700
    
    dept3.txt
    50,TEST,2000
    60,DEV,1900

创建表，分区字段必须与表中不同

create table dept_partition(
    	deptno int, dname string, loc string
    )
    partitioned by (day string)
    row format delimited fields terminated by ',';

加载数据

load data local inpath
    '/opt/module/hive/data/dept1.txt' into table dept_partition
    partition(day='1');
    
    load data local inpath
    '/opt/module/hive/data/dept2.txt' into table dept_partition
    partition(day='2');
    
    load data local inpath
    '/opt/module/hive/data/dept3.txt' into table dept_partition
    partition(day='3');
    
    // 如果不指定分区的话，也能上传成功，但是是放到一个默认的分区—_HIVE_DEFAULT_PARTITION_下
    
    // 查询数据
    hive (default)> select * from dept_partition;
    OK
    dept_partition.o        dept_partition.dname    dept_partition.loc      dept_partition.day
    10      ACCOUNTING      1700    1
    20      RESEARCH        1800    1
    30      SALES   1900    2
    40      OPERATIONS      1700    2
    50      TEST    2000    3
    60      DEV     1900    3
    Time taken: 1.24 seconds, Fetched: 6 row(s)
    
    // 单分区查询
    hive (default)> select * from dept_partition where day='1';
    OK
    dept_partition.o        dept_partition.dname    dept_partition.loc      dept_partition.day
    10      ACCOUNTING      1700    1
    20      RESEARCH        1800    1
    Time taken: 2.068 seconds, Fetched: 2 row(s)

注意:分区表加载数据时,必须指定分区

![在这里插入图片描述][fbb7516e4db248c981657eee7dcc16ca.png]

其中day=x都是文件夹，里面是对应分区的数据文件

分区信息元数据如下：  
![在这里插入图片描述][watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2NsZWFybHhq_size_16_color_FFFFFF_t_70]

当过滤条件里面携带分区字段时，就不会进行全表扫描，之后对指定分区的数据进行扫描和过滤，会提高效率。

增加分区

// 创建单个分区
    hive (default)> alter table dept_partition add partition(day='4');
    
    // 同时创建多个分区
    hive (default)> alter table dept_partition add partition(day='5') partition(day='6');

删除分区

// 删除单个分区
    hive (default)> alter table dept_partition drop partition (day='4');
    // 同时删除多个分区
    hive (default)> alter table dept_partition drop partition (day='5'), partition(day='6');

查看分区表有多少分区

hive> show partitions dept_partition;

查看分区表结构

hive> desc formatted dept_partition;

### 二级分区 ###

如果一个分区里面的数据还是很大，那么就会涉及到二级分区了。

创建表

create table dept_partition2(
        deptno int, dname string, loc string
    )
    partitioned by (day string, hour string)
    row format delimited fields terminated by ',';

将数据放到分区中

load data local inpath
    '/opt/module/hive/data/dept1.txt' into table dept_partition2
    partition(day='1', hour='1');
    
    load data local inpath
    '/opt/module/hive/data/dept2.txt' into table dept_partition2
    partition(day='1',  hour='2');
    
    load data local inpath
    '/opt/module/hive/data/dept3.txt' into table dept_partition2
    partition(day='2', hour='1');
    
    // 全表查询
    hive (default)> select * from dept_partition2;
    OK
    dept_partition2.deptno  dept_partition2.dname   dept_partition2.loc     dept_partition2.day     dept_partition2.hour
    10      ACCOUNTING      1700    1       1
    20      RESEARCH        1800    1       1
    30      SALES   1900    1       2
    40      OPERATIONS      1700    1       2
    50      TEST    2000    2       1
    60      DEV     1900    2       1
    Time taken: 1.23 seconds, Fetched: 6 row(s)
    
    // 单分区查询
    hive (default)> select * from dept_partition2 where day='1';
    OK
    dept_partition2.deptno  dept_partition2.dname   dept_partition2.loc     dept_partition2.day     dept_partition2.hour
    10      ACCOUNTING      1700    1       1
    20      RESEARCH        1800    1       1
    30      SALES   1900    1       2
    40      OPERATIONS      1700    1       2
    Time taken: 1.453 seconds, Fetched: 4 row(s)
    
    // 单个二级分区查询
    hive (default)> select * from dept_partition2 where day='1' and hour='1';
    OK
    dept_partition2.deptno  dept_partition2.dname   dept_partition2.loc     dept_partition2.day     dept_partition2.hour
    10      ACCOUNTING      1700    1       1
    20      RESEARCH        1800    1       1
    Time taken: 1.416 seconds, Fetched: 2 row(s)

**把数据直接上传到分区目录上,让分区表和数据产生关联的三种方式**

以没有二级分区的表为例

**方式一:上传数据后修复**

// 创建目录，并上传文件
    hadoop fs -mkdir  /user/hive/warehouse/dept_partition/day=4
    hadoop fs -put dept1.txt /user/hive/warehouse/dept_partition/day=4
    
    // 此时去查询，既没有数据也没有分区数据
    hive (default)> select * from dept_partition;
    OK
    dept_partition.o        dept_partition.dname    dept_partition.loc      dept_partition.day
    10      ACCOUNTING      1700    1
    20      RESEARCH        1800    1
    30      SALES   1900    2
    40      OPERATIONS      1700    2
    50      TEST    2000    3
    60      DEV     1900    3
    Time taken: 1.298 seconds, Fetched: 6 row(s)
    
    // 直接查看分区数据
    hive (default)> show partitions dept_partition;
    OK
    partition
    day=1
    day=2
    day=3
    Time taken: 1.062 seconds, Fetched: 3 row(s)
    
    // 因为元数据中没有该分区的信息，因此该文件夹相关信息不算为分区数据
    
    // 执行修复分区命令，之后即可查询到指定数据了
    hive (default)> msck repair table dept_partition;
    OK
    Partitions not in metastore:    dept_partition:day=4
    Repair: Added partition to metastore dept_partition:day=4
    Time taken: 1.609 seconds, Fetched: 2 row(s)

方式二:上传数据后添加分区

// 创建目录，并上传文件
    hadoop fs -mkdir  /user/hive/warehouse/dept_partition/day=5
    hadoop fs -put dept1.txt /user/hive/warehouse/dept_partition/day=5
    
    // 执行添加分区
    hive (default)> alter table dept_partition add partition(day='5');

方式三:创建文件夹后 load 数据到分区

### 动态分区调整 ###

关系型数据库中,对分区表 Insert 数据时候,数据库自动会根据分区字段的值,将数据插入到相应的分区中, Hive 中也提供了类似的机制,即动态分区(Dynamic Partition),只不过,使用 Hive 的动态分区,需要进行相应的配置。

开启动态分区参数设置

## (1)开启动态分区功能(默认 true,开启)
    hive.exec.dynamic.partition=true
    
    ## (2)设置为非严格模式(动态分区的模式,默认strict,表示必须指定至少一个分区为静态分区,nonstrict模式表示允许所有的分区字段都可以使用动态分区。)
    hive.exec.dynamic.partition.mode=nonstrict
    
    ## (3)在所有执行 MR 的节点上,最大一共可以创建多少个动态分区。默认 1000
    hive.exec.max.dynamic.partitions=1000
    
    ## (4)在每个执行 MR 的节点上,最大可以创建多少个动态分区。该参数需要根据实际的数据来设定。比如:源数据中包含了一年的数据,即 day 字段有 365 个值,那么该参数就需要设置成大于 365,如果使用默认值 100,则会报错。
    hive.exec.max.dynamic.partitions.pernode=100
    
    ## (5)整个 MR Job 中,最大可以创建多少个 HDFS 文件。默认 100000
    hive.exec.max.created.files=100000
    
    ## (6)当有空分区生成时,是否抛出异常。一般不需要设置。默认 false
    hive.error.on.empty.partition=false

实操

// (1)创建目标分区表
    create table dept_partition_by(
    	dname string, loc string
    )
    partitioned by (deptno int)
    row format delimited fields terminated by ',';
    
    // 静态分区数据插入
    insert into table dept_partition_by partition(deptno='100')
    select dname, loc from dept;
    
    hive (default)> select * from dept_partition_by;
    OK
    dept_partition_by.ame   dept_partition_by.loc   dept_partition_by.deptno
    ACCOUNTING      1700    100
    RESEARCH        1800    100
    SALES   1900    100
    OPERATIONS      1700    100
    Time taken: 1.324 seconds, Fetched: 4 row(s)
    
    // 设置非严格模式，不设置会报错
    set hive.exec.dynamic.partition.mode=nonstrict
    
    // 动态分区数据插入
    // 在Hive3中`partition(deptno)`可以省略
    // 在Hive3中`partition(deptno)`省略的情况下，可以不设置为非严格模式，因为默认这种写法就会先去设置非严格模式再设置回来
    // 动态分区的列必须放在最后，必须，如果是二级分区的话，需要按照分区的顺序
    insert into table dept_partition_by partition(deptno)
    select dname, loc, deptno from dept;
    
    // 查看分区
    hive (default)> show partitions dept_partition_by;
    OK
    partition
    deptno=10
    deptno=100
    deptno=20
    deptno=30
    deptno=40
    Time taken: 1.075 seconds, Fetched: 5 row(s)

## 分桶表 ##

分区提供一个隔离数据和优化查询的便利方式。不过,并非所有的数据集都可形成合理的分区。对于一张表或者分区,Hive 可以进一步组织成桶,也就是更为细粒度的数据范围划分。

分桶是将数据集分解成更容易管理的若干部分的另一个技术。

**分区针对的是数据的存储路径;分桶针对的是数据文件。**

数据准备

1001,ss1
    1002,ss2
    1003,ss3
    1004,ss4
    1005,ss5
    1006,ss6
    1007,ss7
    1008,ss8
    1009,ss9
    1010,ss1
    1011,ss11
    1012,ss12
    1013,ss13
    1014,ss14
    1015,ss15
    1016,ss16

创建分桶，分桶字段必须是表中字段

create table stu_buck(id int, name string)
    clustered by(id)
    into 4 buckets
    row format delimited fields terminated by ',';

// 查看桶的个数
    desc formatted stu_buck;

导入数据

load data inpath '/opt/module/hive/data/stu.txt' into table stu_buck;
    
    // 查询数据
    hive (default)> select * from stu_buck;
    OK
    stu_buck.id     stu_buck.name
    1016    ss16
    1012    ss12
    1008    ss8
    1004    ss4
    1009    ss9
    1005    ss5
    1001    ss1
    1013    ss13
    1010    ss1
    1002    ss2
    1006    ss6
    1014    ss14
    1003    ss3
    1011    ss11
    1007    ss7
    1015    ss15
    Time taken: 1.031 seconds, Fetched: 16 row(s)

分桶规则:  
根据结果可知: Hive 的分桶采用对分桶字段的值进行哈希,然后除以桶的个数求余的方式决定该条记录存放在哪个桶当中。

即4,8,12,16放在一个桶。。。结果就是根据分桶字段与桶个数求余的方式进行分桶的。

分桶表操作需要注意的事项:

(1)reduce 的个数设置为-1,让 Job 自行决定需要用多少个 reduce 或者将 reduce 的个数设置为大于等于分桶表的桶数

(2)从 hdfs 中 load 数据到分桶表中,避免本地文件找不到问题

(3)不要使用本地模式

insert 方式将数据导入分桶表

hive(default)>insert into table stu_buck select * from student_insert;

## 抽样查询 ##

对于非常大的数据集,有时用户需要使用的是一个具有代表性的查询结果而不是全部结果。Hive 可以通过对表进行抽样来满足这个需求。

语法: TABLESAMPLE(BUCKET x OUT OF y)

x表示从第几份开始找数据，y表示将所有的数据分成多少份

// 查询表 stu_buck 中的数据。
    hive (default)> select * from stu_buck tablesample(bucket 1 out of 4 on id);
    OK
    stu_buck.id     stu_buck.name
    1016    ss16
    1004    ss4
    1009    ss9
    1002    ss2
    1003    ss3
    Time taken: 0.941 seconds, Fetched: 5 row(s)
    
    // 注意:x 的值必须小于等于 y 的值,否则
    FAILED: SemanticException [Error 10061]: Numerator should not be bigger
    than denominator in sample clause for table stu_buck

[fbb7516e4db248c981657eee7dcc16ca.png]: /images/20220829/5568896cd807477aa13552cba19f4641.png
[watermark_type_ZmFuZ3poZW5naGVpdGk_shadow_10_text_aHR0cHM6Ly9ibG9nLmNzZG4ubmV0L2NsZWFybHhq_size_16_color_FFFFFF_t_70]: /images/20220829/dd2f543e1bf2415fabd8314f126a275d.png